Fixes to properly work with seamonkey, and make compile with -gtkhtml

Package-Manager: portage-2.1.2_pre1-r4

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-util/mono-tools/mono-tools-1.1.17-r1.ebuild b/dev-util/mono-tools/mono-tools-1.1.17-r1.ebuild
new file mode 100644
index 000000000000..dadbaab4162f
--- /dev/null
+++ b/dev-util/mono-tools/mono-tools-1.1.17-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/mono-tools/mono-tools-1.1.17-r1.ebuild,v 1.1 2006/10/29 04:58:50 latexer Exp $
+
+inherit eutils mono multilib autotools
+
+DESCRIPTION="Set of useful Mono related utilities"
+HOMEPAGE="http://www.mono-project.com/"
+SRC_URI="http://www.go-mono.com/sources/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gtkhtml seamonkey"
+
+RDEPEND="dev-lang/mono
+		 >=dev-util/monodoc-${PV}
+		 =dev-dotnet/gtk-sharp-2*
+		 =dev-dotnet/glade-sharp-2*
+		 =dev-dotnet/gconf-sharp-2*
+		 gtkhtml? ( =dev-dotnet/gtkhtml-sharp-2* )
+		 seamonkey? ( =dev-dotnet/gecko-sharp-0.11* )
+		 !seamonkey? ( =dev-dotnet/gtkhtml-sharp-2* )"
+DEPEND="${RDEPEND}
+		sys-devel/gettext"
+
+# Parallel build unfriendly
+MAKEOPTS="${MAKEOPTS} -j1"
+
+pkg_setup() {
+	if ! use gtkhtml && ! use seamonkey ; then
+		einfo "No browser selected, defaulting to gtkhtml"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	# Make the browser optional
+	epatch ${FILESDIR}/${PN}-1.1.17-html-renderer-fixes.diff
+
+	# Install all our .dlls under $(libdir), not $(prefix)/lib
+	if [ $(get_libdir) != "lib" ] ; then
+		sed -i -e 's:$(prefix)/lib:$(libdir):'                    \
+			${S}/{asn1view/gtk,docbrowser,gnunit/src}/Makefile.am \
+		|| die "sed failed"
+
+		sed -i -e 's:$prefix/lib:@libdir@:' \
+			${S}/docbrowser/monodoc.in      \
+		|| die "sed failed"
+	fi
+
+	eautoreconf
+}
+
+src_compile() {
+	local myconf="$(use_enable gtkhtml) $(use_enable seamonkey mozilla)"
+
+	if ! use gtktml && ! use seamonkey ; then
+		myconf="--enable-gtkhtml --disable-mozilla"
+	fi
+
+	econf ${myconf} || die "configure failed"
+	emake || die "make failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc ChangeLog README
+}