Move the config file generation to src_compile for most people to make binpkgs easier to deploy.

Package-Manager: portage-2.2.0_alpha51/cvs/Linux x86_64

1 files changed, 84 insertions, 0 deletions

diff --git a/app-misc/ca-certificates/ca-certificates-20110502-r2.ebuild b/app-misc/ca-certificates/ca-certificates-20110502-r2.ebuild
new file mode 100644
index 000000000000..425ba1c81d9f
--- /dev/null
+++ b/app-misc/ca-certificates/ca-certificates-20110502-r2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ca-certificates-20110502-r2.ebuild,v 1.1 2011/09/02 17:47:17 vapier Exp $
+
+EAPI="2"
+
+inherit eutils
+
+DESCRIPTION="Common CA Certificates PEM files"
+HOMEPAGE="http://packages.debian.org/sid/ca-certificates"
+SRC_URI="mirror://debian/pool/main/c/${PN}/${PN}_${PV}+nmu1_all.deb"
+
+LICENSE="MPL-1.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+DEPEND="|| ( >=sys-apps/coreutils-6.10-r1 sys-apps/mktemp sys-freebsd/freebsd-ubin )"
+RDEPEND="${DEPEND}
+	dev-libs/openssl
+	sys-apps/debianutils"
+
+S=${WORKDIR}
+
+pkg_setup() {
+	# For the conversion to having it in CONFIG_PROTECT_MASK,
+	# we need to tell users about it once manually first.
+	[[ -f /etc/env.d/98ca-certificates ]] \
+		|| ewarn "You should run update-ca-certificates manually after etc-update"
+}
+
+src_unpack() {
+	unpack ${A}
+	unpack ./data.tar.gz
+	rm -f control.tar.gz data.tar.gz debian-binary
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-20090709-root.patch
+}
+
+src_compile() {
+	(
+	echo "# Automatically generated by ${CATEGORY}/${PF}"
+	echo "# $(date -u)"
+	echo "# Do not edit."
+	cd "${S}"/usr/share/ca-certificates
+	find * -name '*.crt' | LC_ALL=C sort
+	) > "${S}"/etc/ca-certificates.conf
+
+	"${S}"/usr/sbin/update-ca-certificates --root "${S}"
+}
+
+src_install() {
+	cp -pPR * "${D}"/ || die
+
+	mv "${D}"/usr/share/doc/{ca-certificates,${PF}} || die
+	prepalldocs
+
+	echo 'CONFIG_PROTECT_MASK="/etc/ca-certificates.conf"' > 98ca-certificates
+	doenvd 98ca-certificates
+}
+
+pkg_postinst() {
+	if [ -d "${ROOT}/usr/local/share/ca-certificates" ] ; then
+		# if the user has local certs, we need to rebuild again
+		# to include their stuff in the db.
+		# However it's too overzealous when the user has custom certs in place.
+		# --fresh is to clean up dangling symlinks
+		"${ROOT}"/usr/sbin/update-ca-certificates --root "${ROOT}"
+	fi
+
+	local c badcerts=0
+	for c in $(find -L "${ROOT}"etc/ssl/certs/ -type l) ; do
+		ewarn "Broken symlink for a certificate at $c"
+		badcerts=1
+	done
+	if [ $badcerts -eq 1 ]; then
+		ewarn "You MUST remove the above broken symlinks"
+		ewarn "Otherwise any SSL validation that use the directory may fail!"
+		ewarn "To batch-remove them, run:"
+		ewarn "find -L ${ROOT}etc/ssl/certs/ -type l -exec rm {} +"
+	fi
+}