Bump to 2.2.0. Many thanks to Alessio Cassibba for the ebuilds. Part of #265510

Package-Manager: portage-2.2_rc30/cvs/Linux x86_64

5 files changed, 273 insertions, 5 deletions

diff --git a/app-emulation/virtualbox-modules/ChangeLog b/app-emulation/virtualbox-modules/ChangeLog
index a25b3acf3f3a..c86df9d4385f 100644
--- a/app-emulation/virtualbox-modules/ChangeLog
+++ b/app-emulation/virtualbox-modules/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/virtualbox-modules
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.33 2009/03/05 20:17:22 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.34 2009/04/18 16:24:46 patrick Exp $
+
+*virtualbox-modules-2.2.0 (18 Apr 2009)
+
+  18 Apr 2009; Patrick Lauer <patrick@gentoo.org>
+  +virtualbox-modules-2.2.0.ebuild:
+  Bump to 2.2.0. Many thanks to Alessio Cassibba for the ebuilds. Part of
+  #265510
 
   05 Mar 2009; Patrick Lauer <patrick@gentoo.org>
   +files/virtualbox-modules-2.6.29_rc.patch:
diff --git a/app-emulation/virtualbox-modules/virtualbox-modules-2.2.0.ebuild b/app-emulation/virtualbox-modules/virtualbox-modules-2.2.0.ebuild
new file mode 100644
index 000000000000..20edeb0d1a56
--- /dev/null
+++ b/app-emulation/virtualbox-modules/virtualbox-modules-2.2.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-2.2.0.ebuild,v 1.1 2009/04/18 16:24:46 patrick Exp $
+
+# XXX: the tarball here is just the kernel modules split out of the binary
+#      package that comes from virtualbox-bin
+
+EAPI=2
+
+inherit eutils linux-mod
+
+MY_P=vbox-kernel-module-src-${PV}
+DESCRIPTION="Kernel Modules for Virtualbox"
+HOMEPAGE="http://www.virtualbox.org/"
+SRC_URI="http://gentoo.zerodev.it/files/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="!=app-emulation/virtualbox-ose-9999"
+
+S=${WORKDIR}
+
+BUILD_TARGETS="all"
+BUILD_TARGET_ARCH="${ARCH}"
+MODULE_NAMES="vboxdrv(misc:${S}) vboxnetflt(misc:${S})"
+
+pkg_setup() {
+	linux-mod_pkg_setup
+	BUILD_PARAMS="KERN_DIR=${KV_DIR} KERNOUT=${KV_OUT_DIR}"
+	enewgroup vboxusers
+}
+
+src_install() {
+	linux-mod_src_install
+
+	# udev rule for vboxdrv
+	dodir /etc/udev/rules.d
+	echo 'KERNEL=="vboxdrv", GROUP="vboxusers" MODE=660' >> "${D}/etc/udev/rules.d/60-virtualbox.rules"
+}
+
+pkg_postinst() {
+	linux-mod_pkg_postinst
+	elog "Starting with the 2.1 release a new kernel module was added,"
+	elog "be sure to load all the needed modules."
+	elog ""
+	elog "Please add \"vboxdrv\" and \"vboxnetflt\" to:"
+	elog "/etc/modules.autoload.d/kernel-${KV_MAJOR}.${KV_MINOR}"
+	elog ""
+}
diff --git a/app-emulation/virtualbox-ose/ChangeLog b/app-emulation/virtualbox-ose/ChangeLog
index 7d78e8527ec1..cfc3492c3502 100644
--- a/app-emulation/virtualbox-ose/ChangeLog
+++ b/app-emulation/virtualbox-ose/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.14 2009/03/22 13:36:43 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.15 2009/04/18 16:25:22 patrick Exp $
+
+*virtualbox-ose-2.2.0 (18 Apr 2009)
+
+  18 Apr 2009; Patrick Lauer <patrick@gentoo.org>
+  +virtualbox-ose-2.2.0.ebuild, virtualbox-ose-9999:
+  Bump to 2.2.0. Many thanks to Alessio Cassibba for the ebuilds. Part of
+  #265510
 
   22 Mar 2009; Patrick Lauer <patrick@gentoo.org>
   virtualbox-ose-2.1.4-r2.ebuild:
diff --git a/app-emulation/virtualbox-ose/virtualbox-ose-2.2.0.ebuild b/app-emulation/virtualbox-ose/virtualbox-ose-2.2.0.ebuild
new file mode 100644
index 000000000000..2e465e6608b4
--- /dev/null
+++ b/app-emulation/virtualbox-ose/virtualbox-ose-2.2.0.ebuild
@@ -0,0 +1,202 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-2.2.0.ebuild,v 1.1 2009/04/18 16:25:22 patrick Exp $
+
+EAPI=2
+
+inherit eutils fdo-mime flag-o-matic linux-info pax-utils qt4 toolchain-funcs
+
+if [[ ${PV} == "9999" ]] ; then
+	# XXX: should finish merging the -9999 ebuild into this one ...
+	ESVN_REPO_URI="http://www.virtualbox.org/svn/vbox/trunk"
+	inherit linux-mod subversion
+else
+	MY_P=VirtualBox-${PV}-OSE
+	SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"
+	S=${WORKDIR}/${MY_P/-OSE/_OSE}
+fi
+
+DESCRIPTION="Software family of powerful x86 virtualization"
+HOMEPAGE="http://www.virtualbox.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+additions alsa +hal headless pulseaudio python +qt4 sdk vboxwebsrv"
+
+RDEPEND="!app-emulation/virtualbox-bin
+	~app-emulation/virtualbox-modules-${PV}
+	dev-libs/libIDL
+	>=dev-libs/libxslt-1.1.19
+	!headless? (
+		qt4? ( || ( ( x11-libs/qt-gui x11-libs/qt-core ) =x11-libs/qt-4.3*:4 ) )
+		x11-libs/libXcursor
+		media-libs/libsdl[X,video]
+		x11-libs/libXt
+	)"
+DEPEND="${RDEPEND}
+	>=dev-util/kbuild-0.1.5-r1
+	>=dev-lang/yasm-0.6.2
+	sys-devel/bin86
+	sys-devel/dev86
+	sys-power/iasl
+	media-libs/libpng
+	sys-libs/libcap
+	alsa? ( >=media-libs/alsa-lib-1.0.13 )
+	hal? ( sys-apps/hal )
+	pulseaudio? ( media-sound/pulseaudio )
+	python? ( >=dev-lang/python-2.3 )
+	vboxwebsrv? ( >=net-libs/gsoap-2.7.9f )"
+RDEPEND="${RDEPEND}
+	additions? ( ~app-emulation/virtualbox-ose-additions-${PV} )
+	sys-apps/usermode-utilities
+	net-misc/bridge-utils"
+
+pkg_setup() {
+	if ! use headless && ! use qt4 ; then
+		einfo "No USE=\"qt4\" selected, this build will not include"
+		einfo "any Qt frontend."
+	elif use headless && use qt4 ; then
+		einfo "You selected USE=\"headless qt4\", defaulting to"
+		einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
+	fi
+}
+
+src_prepare() {
+	# Remove shipped binaries (kBuild,yasm), see bug #232775
+	rm -rf kBuild/bin tools
+
+	# Disable things unused or split into separate ebuilds
+	sed -e "s/MY_LIBDIR/$(get_libdir)/" \
+		"${FILESDIR}"/${PN}-2-localconfig > LocalConfig.kmk || die
+}
+
+src_configure() {
+	local myconf
+	use alsa       || myconf="${myconf} --disable-alsa"
+	use pulseaudio || myconf="${myconf} --disable-pulse"
+	use python     || myconf="${myconf} --disable-python"
+	use hal        || myconf="${myconf} --disable-dbus"
+	use vboxwebsrv && myconf="${myconf} --enable-webservice"
+	if ! use headless ; then
+		use qt4 || myconf="${myconf} --disable-qt4"
+	else
+		myconf="${myconf} --build-headless"
+	fi
+	# not an autoconf script
+	./configure \
+		--with-gcc="$(tc-getCC)" \
+		--with-g++="$(tc-getCXX)" \
+		--disable-kmods \
+		${myconf} \
+		|| die "configure failed"
+}
+
+src_compile() {
+	source ./env.sh
+
+	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
+	# and strip all flags
+	strip-flags
+
+	MAKE="kmk" emake \
+		TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
+		TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
+		TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
+		TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
+		TOOL_YASM_AS=yasm KBUILD_PATH="${S}/kBuild" \
+		all || die "kmk failed"
+}
+
+src_install() {
+	cd "${S}"/out/linux.*/release/bin || die
+
+	# Create configuration files
+	insinto /etc/vbox
+	newins "${FILESDIR}/${PN}-2-config" vbox.cfg
+
+	# Set the right libdir
+	sed -i \
+		-e "s/MY_LIBDIR/$(get_libdir)/" \
+		"${D}"/etc/vbox/vbox.cfg || die "vbox.cfg sed failed"
+
+	# Symlink binaries to the shipped wrapper
+	exeinto /usr/$(get_libdir)/${PN}
+	newexe "${FILESDIR}/${PN}-2-wrapper" "VBox" || die
+	fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBox
+	fperms 0750 /usr/$(get_libdir)/${PN}/VBox
+
+	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxManage
+	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxVRDP
+	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxHeadless
+	dosym /usr/$(get_libdir)/${PN}/VBoxTunctl /usr/bin/VBoxTunctl
+
+	# Install binaries and libraries
+	insinto /usr/$(get_libdir)/${PN}
+	doins -r components || die
+
+	if use sdk ; then
+		doins -r sdk || die
+	fi
+
+	if use vboxwebsrv ; then
+		doins vboxwebsrv || die
+		fowners root:vboxusers /usr/$(get_libdir)/${PN}/vboxwebsrv
+		fperms 0750 /usr/$(get_libdir)/${PN}/vboxwebsrv
+		dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/vboxwebsrv
+		newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
+		newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
+	fi
+
+	for each in VBox{Manage,SVC,XPCOMIPCD,Tunctl} *so *r0 *gc ; do
+		doins $each || die
+		fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
+		fperms 0750 /usr/$(get_libdir)/${PN}/${each}
+	done
+
+	if ! use headless ; then
+		for each in VBox{SDL,Headless} ; do
+			doins $each || die
+			fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
+			fperms 4750 /usr/$(get_libdir)/${PN}/${each}
+			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/${each}
+		done
+
+		dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxSDL
+
+		if use qt4 ; then
+			doins VirtualBox || die
+			fowners root:vboxusers /usr/$(get_libdir)/${PN}/VirtualBox
+			fperms 4750 /usr/$(get_libdir)/${PN}/VirtualBox
+			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VirtualBox
+
+			dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VirtualBox
+		fi
+
+		newicon	"${S}"/src/VBox/Frontends/VirtualBox/images/OSE/VirtualBox_32px.png ${PN}.png
+		domenu "${FILESDIR}"/${PN}.desktop
+	else
+		doins VBoxHeadless || die
+		fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxHeadless
+		fperms 4750 /usr/$(get_libdir)/${PN}/VBoxHeadless
+		pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VBoxHeadless
+	fi
+
+	insinto /usr/share/${PN}
+	doins -r nls
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	if ! use headless ; then
+		elog "To launch VirtualBox just type: \"VirtualBox\""
+	fi
+	elog "You must be in the vboxusers group to use VirtualBox."
+	elog ""
+	elog "The lastest user manual is available for download at:"
+	elog "http://download.virtualbox.org/virtualbox/${PV}/UserManual.pdf"
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}
diff --git a/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild b/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild
index b916388f1240..679ef1b7a870 100644
--- a/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild
+++ b/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild,v 1.5 2008/12/18 12:47:58 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-9999.ebuild,v 1.6 2009/04/18 16:25:22 patrick Exp $
 
 EAPI=1
 
@@ -28,7 +28,7 @@ RDEPEND="!app-emulation/virtualbox-bin
 		media-libs/libsdl
 		x11-libs/libXt )"
 DEPEND="${RDEPEND}
-	dev-util/kbuild
+	>dev-util/kbuild-0.1.5
 	>=dev-lang/yasm-0.6.2
 	sys-devel/bin86
 	sys-devel/dev86