Version bump.

Package-Manager: portage-2.2_rc8/cvs/Linux 2.6.26.2 x86_64

3 files changed, 160 insertions, 5 deletions

diff --git a/app-emulation/wine/ChangeLog b/app-emulation/wine/ChangeLog
index 0b98a9500a4a..7f74ba27ffa9 100644
--- a/app-emulation/wine/ChangeLog
+++ b/app-emulation/wine/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/wine
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.223 2008/08/16 15:16:26 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.224 2008/08/22 19:20:08 vapier Exp $
+
+*wine-1.1.3 (22 Aug 2008)
+
+  22 Aug 2008; Mike Frysinger <vapier@gentoo.org> +wine-1.1.3.ebuild:
+  Version bump.
 
 *wine-1.1.2 (16 Aug 2008)
 
diff --git a/app-emulation/wine/Manifest b/app-emulation/wine/Manifest
index fbf9c605df36..f0878a131bdb 100644
--- a/app-emulation/wine/Manifest
+++ b/app-emulation/wine/Manifest
@@ -51,6 +51,7 @@ DIST wine-1.0.tar.bz2 13981030 RMD160 1dbfa38e54e7d6269ad4110f22b2791393fd3b59 S
 DIST wine-1.1.0.tar.bz2 14016982 RMD160 688feb6967fb27906372d80dbdfc5882344ad0e1 SHA1 171d6541521d4579c7eaa1b7d751d674c64fdecb SHA256 e079cec1eb8bbcfb176674a0ab2454bb2b2d1b16e518a02a66eaaa6c4e1a3607
 DIST wine-1.1.1.tar.bz2 14114338 RMD160 8d4f41617ccc6de17528e634d2b96e5478f7dea3 SHA1 e9da2b63b9d29c3ddd4ac0c02353579d4ee3b12c SHA256 9f6e66ef5139d9b6850ec6dccb1200441a82b17e73dc9c62e53cc417e4670cd7
 DIST wine-1.1.2.tar.bz2 14077780 RMD160 6d7a55809f38bab8401c2009b7d5170975038754 SHA1 664df57d33fc831b7e07a9a3c1f58df6337a9db3 SHA256 1ef9a07afe9057ff467e80e7cd1bccaf0f5d86618ed5094b85af4aeb6a3323b4
+DIST wine-1.1.3.tar.bz2 14305946 RMD160 890d6eac933ca590856121576a837e057a6e26a5 SHA1 c380d53a5f6a95c4e27dbf4f473facb2d349c522 SHA256 d64763829b38f4c8804b809a3130d1a525d062a33802e46dff33f60f159ac71f
 DIST wine_gecko-0.1.0.cab 5746895 RMD160 61f85ee39e96f88783541460d2fce31db7cc0183 SHA1 c16f1072dc6b0ced20935662138dcf019a38cd56 SHA256 4ef0bffa49a9abc86f74257aa8d7f5db806e8e8bd780149244149aa3f9292d10
 EBUILD wine-0.9.40.ebuild 3293 RMD160 843021a014a7cd2e6e1eb15aeb1b60ca1a835993 SHA1 818bea52e2d5d8550a571f46fc52a565cb52bb95 SHA256 d7ac7c56e87ea80fe1848842cd716c3242a10c9ff3843bb777d93c05fc756f3d
 EBUILD wine-0.9.41.ebuild 3293 RMD160 89e5be8adf5adccf7ddd8d80ff434c989c057579 SHA1 6e13664240ae0b1f4a28ff6db4d1e197def73be2 SHA256 119e0e15c1b8682dac82d1c040010bb4d6f1d7759b4ab5f181b70d84c0b6d1f4
@@ -83,13 +84,14 @@ EBUILD wine-1.0_rc5.ebuild 3773 RMD160 5c4872ff9dfb66b22c7099709d41be31713d4fd6
 EBUILD wine-1.1.0.ebuild 3771 RMD160 fff04e33c76f5afb81a3ab7fbd2ee0219b292c94 SHA1 17a44563701599393efc5e4de369a8626deddb35 SHA256 9d480bc4d33f70b09e5a77604ed54c70d62ba7f303d737b7e82097a71246f073
 EBUILD wine-1.1.1.ebuild 3773 RMD160 5a38f025df9d6cf23710d3b0a7c0826e1931b475 SHA1 d99cb9bfb6efa7dd7e2468a837a1e1ef18ca3ba4 SHA256 a1a5fe53d7902cb8efd2c09428987a1877ab20ee616ae4d9499e59a76491ce64
 EBUILD wine-1.1.2.ebuild 3773 RMD160 8dbd03583d43319a39322c9a9dd0fd05b20aac1d SHA1 e8f11895a21248b0ccdd90e4c7ce4e2cdbfa1e36 SHA256 55d153447bf6730ec8561555998a4a5ffcce4b4422309394d62149200c689c8e
+EBUILD wine-1.1.3.ebuild 3773 RMD160 24749f74b756d8c6ea11b1f9b5949f573814a466 SHA1 e28e3f3c739d1217230fd8509f2436f058352c9a SHA256 a0fb8641774d51b9d43ad6cd8d0838bbd9e5d9344ad2d34a15a0237c9962eab3
 EBUILD wine-9999.ebuild 3721 RMD160 57824e46ba6ac5a11c9698c8957a5bc0d1211546 SHA1 ece114f6e5ee37a45bac61521da9b0c5349d077e SHA256 3533ffe5bc2b497ede11cb97623d97682184a53e3b229317be109c3cf5b53b14
-MISC ChangeLog 40459 RMD160 83e2a2fdec4c65776a0fde68561a7f0d23c1b667 SHA1 5040fcbddefb2f8486a38f4d7830e08dce6920fa SHA256 5d371aeec264656a4617cb63286358d50b08f2f4ac3c6aa63579c981a334d5f8
+MISC ChangeLog 40573 RMD160 c55d55fa21722eda3003218c6f2092891fb85a79 SHA1 5102e66f648f4c15da8683cd4e7612e187bded51 SHA256 2cf213a9f29ba79bf4a9b9a19ab48873bc76ca84c115cbaecea1da6ee48a1672
 MISC metadata.xml 886 RMD160 b95fced5f442faad3f40d49ced406da725f208e1 SHA1 3648fc60a651e2456aaa8bf6c3a8e1fd04210113 SHA256 d0cd1b3c6c538b0c5ade5f820e1982373d6f3376ff698fcff234bce6202877eb
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.9 (GNU/Linux)
 
-iEYEARECAAYFAkim71IACgkQ67wieSYcaxcorACggxzCmb3g9E+dskbtZ4O3iz8S
-eEkAn1Gz/Sp1XJJ4ym+B6tX4cyb9PfNn
-=DqCn
+iEYEARECAAYFAkivEXAACgkQ67wieSYcaxc4YQCgv7bM+IGzoeSkaEhE4FPQixxr
+mQ4AnivSgb/KHKSgi7IqBiUM4zOaTBdj
+=8o33
 -----END PGP SIGNATURE-----
diff --git a/app-emulation/wine/wine-1.1.3.ebuild b/app-emulation/wine/wine-1.1.3.ebuild
new file mode 100644
index 000000000000..56ed39901f65
--- /dev/null
+++ b/app-emulation/wine/wine-1.1.3.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/wine-1.1.3.ebuild,v 1.1 2008/08/22 19:20:08 vapier Exp $
+
+EAPI="1"
+
+inherit eutils flag-o-matic multilib
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://source.winehq.org/git/wine.git"
+	inherit git
+	SRC_URI=""
+else
+	MY_P="${PN}-${PV/_/-}"
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+	S=${WORKDIR}/${MY_P}
+fi
+
+DESCRIPTION="free implementation of Windows(tm) on Unix"
+HOMEPAGE="http://www.winehq.org/"
+SRC_URI="${SRC_URI}
+	gecko? ( mirror://sourceforge/wine/wine_gecko-0.1.0.cab )"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
+IUSE="alsa cups dbus esd +gecko hal jack jpeg lcms ldap nas ncurses +opengl oss samba scanner xml +X"
+RESTRICT="test" #72375
+
+RDEPEND=">=media-libs/freetype-2.0.0
+	media-fonts/corefonts
+	ncurses? ( >=sys-libs/ncurses-5.2 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	dbus? ( sys-apps/dbus )
+	hal? ( sys-apps/hal )
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXrandr
+		x11-libs/libXi
+		x11-libs/libXmu
+		x11-libs/libXxf86vm
+		x11-apps/xmessage
+	)
+	alsa? ( media-libs/alsa-lib )
+	esd? ( media-sound/esound )
+	nas? ( media-libs/nas )
+	cups? ( net-print/cups )
+	opengl? ( virtual/opengl )
+	jpeg? ( media-libs/jpeg )
+	ldap? ( net-nds/openldap )
+	lcms? ( media-libs/lcms )
+	samba? ( >=net-fs/samba-3.0.25 )
+	xml? ( dev-libs/libxml2 dev-libs/libxslt )
+	scanner? ( media-gfx/sane-backends )
+	amd64? (
+		X? (
+			>=app-emulation/emul-linux-x86-xlibs-2.1
+			>=app-emulation/emul-linux-x86-soundlibs-2.1
+		)
+		>=sys-kernel/linux-headers-2.6
+	)"
+DEPEND="${RDEPEND}
+	X? (
+		x11-proto/inputproto
+		x11-proto/xextproto
+		x11-proto/xf86vidmodeproto
+	)
+	sys-devel/bison
+	sys-devel/flex"
+
+pkg_setup() {
+	use alsa || return 0
+	if ! built_with_use --missing true media-libs/alsa-lib midi ; then
+		eerror "You must build media-libs/alsa-lib with USE=midi"
+		die "please re-emerge media-libs/alsa-lib with USE=midi"
+	fi
+}
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		git_src_unpack
+	else
+		unpack ${MY_P}.tar.bz2
+	fi
+	cd "${S}"
+
+	sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in || die
+	epatch "${FILESDIR}"/wine-gentoo-no-ssp.patch #66002
+	sed -i '/^MimeType/d' tools/wine.desktop || die #117785
+}
+
+config_cache() {
+	local h ans="no"
+	use $1 && ans="yes"
+	shift
+	for h in "$@" ; do
+		[[ ${h} == *.h ]] \
+			&& h=header_${h} \
+			|| h=lib_${h}
+		export ac_cv_${h//[:\/.]/_}=${ans}
+	done
+}
+
+src_compile() {
+	export LDCONFIG=/bin/true
+	use esd     || export ac_cv_path_ESDCONFIG=""
+	use scanner || export ac_cv_path_sane_devel="no"
+	config_cache jack jack/jack.h
+	config_cache cups cups/cups.h
+	config_cache alsa alsa/asoundlib.h sys/asoundlib.h asound:snd_pcm_open
+	config_cache nas audio/audiolib.h audio/soundlib.h
+	config_cache xml libxml/parser.h libxslt/pattern.h libxslt/transform.h
+	config_cache ldap ldap.h lber.h
+	config_cache dbus dbus/dbus.h
+	config_cache hal hal/libhal.h
+	config_cache jpeg jpeglib.h
+	config_cache oss sys/soundcard.h machine/soundcard.h soundcard.h
+	config_cache lcms lcms.h
+
+	strip-flags
+
+	use amd64 && multilib_toolchain_setup x86
+
+	#	$(use_enable amd64 win64)
+	econf \
+		--sysconfdir=/etc/wine \
+		$(use_with ncurses curses) \
+		$(use_with opengl) \
+		$(use_with X x) \
+		|| die "configure failed"
+
+	emake -j1 depend || die "depend"
+	emake all || die "all"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc ANNOUNCE AUTHORS ChangeLog DEVELOPERS-HINTS README
+	if use gecko ; then
+		insinto /usr/share/wine/gecko
+		doins "${DISTDIR}"/wine_gecko-*.cab || die
+	fi
+}
+
+pkg_postinst() {
+	elog "~/.wine/config is now deprecated.  For configuration either use"
+	elog "winecfg or regedit HKCU\\Software\\Wine"
+}