Add the latest 21.5 beta version from the xemacs overlay.

Package-Manager: portage-2.1.6.13/cvs/Linux x86_64

1 files changed, 256 insertions, 0 deletions

diff --git a/app-editors/xemacs/xemacs-21.5.29-r2.ebuild b/app-editors/xemacs/xemacs-21.5.29-r2.ebuild
new file mode 100644
index 000000000000..90c54d272f64
--- /dev/null
+++ b/app-editors/xemacs/xemacs-21.5.29-r2.ebuild
@@ -0,0 +1,256 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/xemacs/xemacs-21.5.29-r2.ebuild,v 1.1 2009/07/07 18:26:50 graaff Exp $
+
+# Note: xemacs currently does not work with a hardened profile. If you
+# want to use xemacs on a hardened profile then compile with the
+# -nopie flag in CFLAGS or help fix bug #75028.
+
+EAPI="2"
+
+export WANT_AUTOCONF="2.5"
+inherit eutils flag-o-matic multilib
+
+DESCRIPTION="highly customizable open source text editor and application development system"
+HOMEPAGE="http://www.xemacs.org/"
+SRC_URI="http://ftp.xemacs.org/xemacs-21.5/${P}.tar.gz
+	http://www.malfunction.de/afterstep/files/NeXT_XEmacs.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="alsa debug eolconv esd gif gpm pop postgres ldap xface nas dnd X jpeg tiff png mule motif freewnn canna xft xim athena neXt Xaw3d gdbm berkdb"
+
+X_DEPEND="x11-libs/libXt x11-libs/libXmu x11-libs/libXext x11-misc/xbitmaps"
+
+RDEPEND="
+	berkdb? ( sys-libs/db )
+	gdbm? ( >=sys-libs/gdbm-1.8.3 )
+	>=sys-libs/zlib-1.1.4
+	>=dev-libs/openssl-0.9.6
+	>=media-libs/audiofile-0.2.3
+	gpm? ( >=sys-libs/gpm-1.19.6 )
+	postgres? ( >=virtual/postgresql-base-7.2 )
+	ldap? ( net-nds/openldap )
+	alsa? ( media-libs/alsa-lib )
+	esd? ( media-sound/esound )
+	nas? ( media-libs/nas )
+	X? ( $X_DEPEND !Xaw3d? ( !neXt? ( x11-libs/libXaw ) ) )
+	dnd? ( x11-libs/dnd )
+	motif? ( >=x11-libs/openmotif-2.1.30 )
+	athena? ( x11-libs/libXaw )
+	Xaw3d? ( x11-libs/Xaw3d )
+	xft? ( media-libs/freetype x11-libs/libXrender >=media-libs/fontconfig-2.5.0 )
+	neXt? ( x11-libs/neXtaw )
+	xface? ( media-libs/compface )
+	tiff? ( media-libs/tiff )
+	png? ( =media-libs/libpng-1.2* )
+	jpeg? ( media-libs/jpeg )
+	canna? ( app-i18n/canna )
+	freewnn? ( app-i18n/freewnn )
+	>=sys-libs/ncurses-5.2"
+
+DEPEND="${RDEPEND}
+	>=app-admin/eselect-emacs-1.2"
+
+PDEPEND="app-xemacs/xemacs-base
+	mule? ( app-xemacs/mule-base )"
+
+src_unpack() {
+	default_src_unpack
+
+	use neXt && unpack NeXT_XEmacs.tar.gz
+}
+
+src_prepare() {
+	cd "${S}"
+
+	# Fix security issue in vcdiff script
+	epatch "${FILESDIR}"/${P}-vcdiff.patch
+
+	# Fix problem caused by improper optimization with GCC 4.1.2 on x86
+	# (and possibly other arches, but only confirmed on x86). See
+	# http://tracker.xemacs.org/XEmacs/its/issue354 for the upstream
+	# bug.
+	epatch "${FILESDIR}"/${P}-optimization-bug.patch
+
+	# Fix for security bug #275397.
+	epatch "${FILESDIR}"/${P}-large-images.patch
+
+	use neXt && cp "${WORKDIR}"/NeXT.XEmacs/xemacs-icons/* "${S}"/etc/toolbar/
+}
+
+src_configure() {
+	local myconf=""
+
+	if use X; then
+
+		myconf="${myconf} --with-widgets=athena"
+		myconf="${myconf} --with-dialogs=athena"
+		myconf="${myconf} --with-menubars=lucid"
+		myconf="${myconf} --with-scrollbars=lucid"
+		if use motif ; then
+			myconf="--with-widgets=motif"
+			myconf="${myconf} --with-dialogs=motif"
+			myconf="${myconf} --with-scrollbars=motif"
+			myconf="${myconf} --with-menubars=lucid"
+		fi
+		if use athena or use Xaw3d ; then
+			myconf="--with-scrollbars=athena"
+		fi
+
+		if use Xaw3d; then
+			myconf="${myconf} --with-athena=3d"
+		elif use neXt; then
+			myconf="${myconf} --with-athena=next"
+		else
+			myconf="${myconf} --with-athena=xaw"
+		fi
+
+		use dnd && myconf="${myconf} --with-dragndrop --with-offix"
+
+		myconf="${myconf} $(use_with tiff )"
+		myconf="${myconf} $(use_with png )"
+		myconf="${myconf} $(use_with jpeg )"
+		myconf="${myconf} $(use_with xface )"
+
+		use xft && myconf="${myconf} --with-xft=emacs,tabs,menubars,gauges" ||
+			myconf="${myconf} --with-xft=no"
+
+	else
+		myconf="${myconf}
+			--without-x
+			--without-xpm
+			--without-dragndrop
+			--with-xft=no
+			--with-gif=no"
+	fi
+
+	if use mule ; then
+		myconf="${myconf} --with-mule"
+
+		if use xim ; then
+			if use motif ; then
+				myconf="${myconf} --with-xim=motif"
+			else
+				myconf="${myconf} --with-xim=xlib"
+			fi
+		else
+			myconf="${myconf} --with-xim=no"
+		fi
+
+		myconf="${myconf} $(use_with canna )"
+		myconf="${myconf} $(use_with freewnn wnn )"
+	fi
+
+	# This determines the type of sounds we are playing
+	local soundconf="native"
+
+	# This determines how these sounds should be played
+	use nas	&& soundconf="${soundconf},nas"
+	use esd && soundconf="${soundconf},esd"
+	use alsa && soundconf="${soundconf},alsa"
+
+	myconf="${myconf} --with-sound=${soundconf}"
+
+	if use gdbm || use berkdb ; then
+		if use gdbm ; then
+			mydb="gdbm"
+			# We have GDBM in a non-standard location
+			append-flags "-I/usr/include/gdbm"
+		fi
+
+		use berkdb && mydb="${mydb},berkdb"
+
+		myconf="${myconf} --with-database=${mydb}"
+	else
+		myconf="${myconf} --without-database"
+	fi
+
+	use debug && myconf="${myconf} --with-optimization=no --with-debug" ||
+		myconf="${myconf} --with-optimization=yes"
+
+	econf ${myconf} \
+		$(use_with gif ) \
+		$(use_with gpm ) \
+		$(use_with postgres postgresql ) \
+		$(use_with ldap ) \
+		$(use_with eolconv file-coding ) \
+		$(use_with pop ) \
+		--prefix=/usr \
+		--with-ncurses \
+		--with-msw=no \
+		--with-mail-locking=flock \
+		--with-site-lisp=yes \
+		--with-site-modules=yes \
+		--with-newgc \
+		--enable-option-checking=no \
+		--with-last-packages=/usr/lib/xemacs \
+		|| die "configuration failed"
+}
+
+src_install() {
+	emake prefix="${D}"/usr \
+		mandir="${D}"/usr/share/man/man1 \
+		infodir="${D}"/usr/share/info \
+		libdir="${D}"/usr/$(get_libdir) \
+		datadir="${D}"/usr/share \
+		install gzip-el || die
+
+	# Rename some applications installed in bin so that it is clear
+	# which application installed them and so that conflicting
+	# packages (emacs) can't clobber the actual applications.
+	# Addresses bug #62991.
+	for i in b2m ctags etags rcs-checkin ; do
+		mv "${D}"/usr/bin/${i} "${D}"/usr/bin/${i}-xemacs || die "mv ${i} failed"
+	done
+
+	# rename man pages
+	for i in ctags etags; do
+		mv "${D}"/usr/share/man/man1/${i}{,-xemacs}.1 || die "mv ${i}.1 failed"
+	done
+
+	# install base packages directories
+	dodir /usr/lib/xemacs/xemacs-packages/
+	dodir /usr/lib/xemacs/site-packages/
+	dodir /usr/lib/xemacs/site-modules/
+	dodir /usr/lib/xemacs/site-lisp/
+
+	if use mule;
+	then
+		dodir /usr/lib/xemacs/mule-packages
+	fi
+
+	# remove extraneous info files
+	cd "${D}"/usr/share/info
+	rm -f dir info.info texinfo* termcap* standards*
+
+	cd "${S}"
+	dodoc CHANGES-* ChangeLog INSTALL Installation PROBLEMS README*
+
+	insinto /usr/share/pixmaps
+	newins "${S}"/etc/${PN}-icon.xpm ${PN}.xpm
+
+	insinto /usr/share/applications
+	doins "${FILESDIR}"/${PN}.desktop
+}
+
+pkg_postinst() {
+	eselect emacs update ifunset
+
+	einfo "If you are upgrading from XEmacs 21.4 you should note the following"
+	einfo "incompatibilities:"
+	einfo "- Mule-UCS is no longer supported due to proper UTF-8 support in XEmacs 21.5"
+	einfo "- The X resource class has changed from Emacs to XEmacs,"
+	einfo "  settings in your .Xdefaults file should be updated accordingly."
+
+	if use xft;
+	then
+	  einfo "You have enabled Xft font support. Xft requires font names to be provided"
+	  einfo "in a different way, so you may need to adjust your .Xdefaults accordingly."
+	fi
+}
+
+pkg_postrm() {
+	eselect emacs update ifunset
+}