blob: 0fa5b195b500e16b2c1fdb86f9c75c3b65fe952b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/bcl.asc
inherit autotools verify-sig
DESCRIPTION="Create, destroy, resize, check, copy partitions and file systems"
HOMEPAGE="https://www.gnu.org/software/parted/"
SRC_URI="
mirror://gnu/${PN}/${P}.tar.xz
verify-sig? ( mirror://gnu/${PN}/${P}.tar.xz.sig )
"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 sparc ~x86"
IUSE="+debug device-mapper nls readline"
# util-linux for libuuid
RDEPEND="
>=sys-fs/e2fsprogs-1.27
sys-apps/util-linux
device-mapper? ( >=sys-fs/lvm2-2.02.45 )
readline? (
>=sys-libs/ncurses-5.7-r7:0=
>=sys-libs/readline-5.2:0=
)
"
DEPEND="${RDEPEND}"
BDEPEND="
nls? ( >=sys-devel/gettext-0.12.1-r2 )
verify-sig? ( >=sec-keys/openpgp-keys-bcl-20230315 )
virtual/pkgconfig
"
DOCS=(
AUTHORS BUGS ChangeLog NEWS README THANKS TODO doc/{API,FAT,USER.jp}
)
PATCHES=(
"${FILESDIR}"/${PN}-3.2-po4a-mandir.patch
"${FILESDIR}"/${PN}-3.3-atari.patch
# https://lists.gnu.org/archive/html/bug-parted/2022-02/msg00000.html
"${FILESDIR}"/${PN}-3.4-posix-printf.patch
)
# false positive
QA_CONFIG_IMPL_DECL_SKIP="MIN"
src_prepare() {
default
eautoconf
touch doc/pt_BR/Makefile.in || die
}
src_configure() {
local myconf=(
$(use_enable debug)
$(use_enable device-mapper)
$(use_enable nls)
$(use_with readline)
--disable-rpath
--disable-static
)
econf "${myconf[@]}"
}
src_install() {
default
find "${ED}" -type f -name '*.la' -delete || die
}
|
GitWeb
