1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
DESCRIPTION="A performance data analyzer for nagios"
HOMEPAGE="http://www.pnp4nagios.org/"
SRC_URI="mirror://sourceforge/${PN}/PNP-0.6/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
IUSE="apache2 icinga icinga2 +nagios"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
REQUIRED_USE="^^ ( icinga icinga2 nagios )"
# Some things (sync mode, for one) are broken with nagios-4.x, but since
# nagios-3.x has been end-of-life'd, we don't have much choice here but
# to accept it.
DEPEND="
dev-lang/php:*[filter,gd,json,simplexml,xml,zlib]
net-analyzer/rrdtool[graph,perl]
icinga? ( net-analyzer/icinga )
icinga2? ( net-analyzer/icinga2 )
nagios? ( net-analyzer/nagios-core )"
# A list of modules used in our Apache config file.
APACHE_MODS="apache2_modules_alias," # "Alias" directive
APACHE_MODS+="apache2_modules_authz_core," # "Require" directive
APACHE_MODS+="apache2_modules_rewrite" # "RewriteEngine" and friends
RDEPEND="${DEPEND}
virtual/perl-Getopt-Long
virtual/perl-Time-HiRes
media-fonts/dejavu
apache2? ( >=www-servers/apache-2.4[${APACHE_MODS}] )"
PATCHES=( "${FILESDIR}/${PN}-0.6.14-makefile.patch" )
src_configure() {
local var_dir user_group
if use icinga; then
var_dir=/var/lib/icinga
user_group=icinga
elif use icinga2; then
var_dir=/var/lib/icinga2
user_group=icinga
else
# Thanks to REQUIRED_USE, "use nagios" is the only other case.
var_dir=/var/nagios
user_group=nagios
fi
econf \
--sysconfdir="${EPREFIX}"/etc/pnp \
--datarootdir="${EPREFIX}"/usr/share/pnp \
--with-perfdata-dir="${EPREFIX}"${var_dir}/perfdata \
--with-nagios-user=${user_group} \
--with-nagios-group=${user_group} \
--with-perfdata-logfile="${EPREFIX}"${var_dir}/perfdata.log \
--with-perfdata-spool-dir="${EPREFIX}"/var/spool/pnp
}
src_compile() {
# The default target just shows a help
emake all
}
src_install() {
# Don't use INSTALL_OPTS because they set insecure permissions on
# all of /etc/pnp (https://github.com/lingej/pnp4nagios/issues/140).
emake INSTALL_OPTS="" DESTDIR="${D}" install install-config
einstalldocs
newinitd "${FILESDIR}"/npcd.initd npcd
rm "${ED%/}/usr/share/pnp/install.php" || \
die "unable to remove ${ED%/}/usr/share/pnp/install.php"
# Fix CVE-2012-3457 (Gentoo bug 430358)
fperms o-rwx /etc/pnp/process_perfdata.cfg
if use apache2 ; then
insinto "${APACHE_MODULES_CONFDIR}"
newins "${FILESDIR}"/98_pnp4nagios-2.4.conf 98_pnp4nagios.conf
# This one file isn't world-readable, but it should be group-
# readable. Give it to the "apache" group to let the web
# server read it.
fowners :apache /etc/pnp/process_perfdata.cfg
fi
}
pkg_postinst() {
elog "To enable the pnp4nagios web front-end, please visit"
elog "${EROOT%/}/etc/conf.d/apache2 and add \"-D PNP -D PHP\""
elog "to APACHE2_OPTS. Then pnp4nagios will be available at,"
elog
elog " http://localhost/pnp4nagios"
elog
}
|
GitWeb