media-libs/sdl-pango/sdl-pango-0.1.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit autotools

DESCRIPTION="connect the text rendering engine of GNOME to SDL"
HOMEPAGE="https://sdlpango.sourceforge.net/"
SRC_URI="mirror://sourceforge/sdlpango/SDL_Pango-${PV}.tar.gz
	http://zarb.org/~gc/t/SDL_Pango-0.1.2-API-adds.patch"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc sparc x86"
IUSE="static-libs"

RDEPEND="x11-libs/pango
	media-libs/libsdl[video]"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S="${WORKDIR}/SDL_Pango-${PV}"

PATCHES=(
	"${FILESDIR}/SDL_Pango-0.1.2-fedora-c99.patch"
)

src_unpack() {
	unpack SDL_Pango-${PV}.tar.gz
}

src_prepare() {
	default
	eapply -p0 "${DISTDIR}"/SDL_Pango-0.1.2-API-adds.patch
	eautoreconf
}

src_configure() {
	econf $(use_enable static-libs static)
}

src_install() {
	default
	if ! use static-libs ; then
		find "${ED}" -name "*.a" -delete || die
	fi
	find "${ED}" -name "*.la" -delete || die
}