blob: 7171e97dec6a744d296c31312a08feef55f0ea8f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-{1..4} luajit )
inherit lua-single toolchain-funcs
DESCRIPTION="An IMAP mail filtering utility"
HOMEPAGE="https://github.com/lefcha/imapfilter"
SRC_URI="https://github.com/lefcha/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
REQUIRED_USE="${LUA_REQUIRED_USE}"
RDEPEND="
dev-libs/openssl:0=
dev-libs/libpcre2
${LUA_DEPS}"
DEPEND="${RDEPEND}"
DOCS="AUTHORS NEWS README samples/*"
src_prepare() {
default
sed -i -e "/^PREFIX/s:/usr/local:${EPREFIX}/usr:" \
-e "/^MANDIR/s:man:share/man:" \
-e "/^CFLAGS/s:CFLAGS =:CFLAGS +=:" \
-e "/^CFLAGS/s/-O//" \
src/Makefile || die
}
src_compile() {
emake \
CC="$(tc-getCC)" \
LDFLAGS="${LDFLAGS}" \
INCDIRS="$(lua_get_CFLAGS)" \
LIBLUA="$(lua_get_LIBS)"
}
src_install() {
default
doman doc/imapfilter.1 doc/imapfilter_config.5
}
|
GitWeb
