blob: 15cfd6a1fe100c16133f2e213819b36a28f2d70c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..10} pypy3 )
PYTHON_REQ_USE="ssl(+),threads(+)"
inherit bash-completion-r1 distutils-r1
# setuptools & wheel .whl files are required for testing,
# the exact version is not very important.
SETUPTOOLS_WHL="setuptools-56.0.0-py3-none-any.whl"
WHEEL_WHL="wheel-0.36.2-py2.py3-none-any.whl"
DESCRIPTION="Installs python packages -- replacement for easy_install"
HOMEPAGE="
https://pip.pypa.io/en/stable/
https://pypi.org/project/pip/
https://github.com/pypa/pip/"
SRC_URI="
https://github.com/pypa/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
test? (
https://files.pythonhosted.org/packages/py3/s/setuptools/${SETUPTOOLS_WHL}
https://files.pythonhosted.org/packages/py2.py3/w/wheel/${WHEEL_WHL}
)
"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
SLOT="0"
IUSE="test vanilla"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/setuptools-39.2.0[${PYTHON_USEDEP}]
"
BDEPEND="
${RDEPEND}
test? (
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/freezegun[${PYTHON_USEDEP}]
dev-python/pretend[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/scripttest[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
<dev-python/virtualenv-20[${PYTHON_USEDEP}]
' python3_{7..9})
dev-python/werkzeug[${PYTHON_USEDEP}]
dev-python/wheel[${PYTHON_USEDEP}]
)
"
python_prepare_all() {
local PATCHES=(
"${FILESDIR}/${PN}-21.1-no-coverage.patch"
)
if ! use vanilla; then
PATCHES+=( "${FILESDIR}/pip-20.0.2-disable-system-install.patch" )
fi
distutils-r1_python_prepare_all
if use test; then
mkdir tests/data/common_wheels/ || die
cp "${DISTDIR}"/{${SETUPTOOLS_WHL},${WHEEL_WHL}} \
tests/data/common_wheels/ || die
fi
}
python_test() {
if [[ ${EPYTHON} == pypy* ]]; then
ewarn "Skipping tests on ${EPYTHON} since they are very broken"
return 0
fi
# virtualenv-16 doesn't support python3_10 yet is still required by pip test suite
if [[ ${EPYTHON} == "python3.10" ]]; then
ewarn "Skipping tests on ${EPYTHON} due to missing dependencies"
return 0
fi
local deselect=(
tests/functional/test_install.py::test_double_install_fail
tests/functional/test_list.py::test_multiple_exclude_and_normalization
'tests/unit/test_commands.py::test_index_group_handle_pip_version_check[False-False-True-download]'
'tests/unit/test_commands.py::test_index_group_handle_pip_version_check[False-False-True-install]'
'tests/unit/test_commands.py::test_index_group_handle_pip_version_check[False-False-True-list]'
'tests/unit/test_commands.py::test_index_group_handle_pip_version_check[False-False-True-wheel]'
tests/functional/test_install.py::test_install_pip_does_not_modify_pip_when_satisfied
# Internet
tests/functional/test_install.py::test_install_editable_with_prefix_setup_cfg
)
distutils_install_for_testing --via-root
local -x GENTOO_PIP_TESTING=1 \
PATH="${TEST_DIR}/scripts:${PATH}" \
PYTHONPATH="${TEST_DIR}/lib:${BUILD_DIR}/lib"
epytest ${deselect[@]/#/--deselect } -m "not network"
}
python_install_all() {
# Prevent dbus auto-launch
# https://bugs.gentoo.org/692178
export DBUS_SESSION_BUS_ADDRESS="disabled:"
local DOCS=( AUTHORS.txt docs/html/**/*.rst )
distutils-r1_python_install_all
COMPLETION="${T}"/completion.tmp
# 'pip completion' command embeds full $0 into completion script, which confuses
# 'complete' and causes QA warning when running as "${PYTHON} -m pip".
# This trick sets correct $0 while still calling just installed pip.
local pipcmd='import sys; sys.argv[0] = "pip"; from pip._internal.cli.main import main; sys.exit(main())'
${PYTHON} -c "${pipcmd}" completion --bash > "${COMPLETION}" || die
newbashcomp "${COMPLETION}" ${PN}
${PYTHON} -c "${pipcmd}" completion --zsh > "${COMPLETION}" || die
insinto /usr/share/zsh/site-functions
newins "${COMPLETION}" _pip
}
|
GitWeb