blob: 2ea6d8d5f947f2893c76d41f627d79a855a695ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
inherit eutils python-r1
DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
HOMEPAGE="http://www.libimobiledevice.org/"
SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
# While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0/4" # based on SONAME of libimobiledevice.so
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE="gnutls python static-libs"
RDEPEND=">=app-pda/libplist-1.11:=
>=app-pda/libusbmuxd-1.0.9:=
gnutls? (
dev-libs/libgcrypt:0
>=dev-libs/libtasn1-1.1
>=net-libs/gnutls-2.2.0
)
!gnutls? ( dev-libs/openssl:0 )
python? (
${PYTHON_DEPS}
app-pda/libplist[python(-),${PYTHON_USEDEP}]
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DOCS=( AUTHORS NEWS README )
BUILD_DIR="${S}_build"
src_configure() {
local ECONF_SOURCE=${S}
local myeconfargs=( $(use_enable static-libs static) )
use gnutls && myeconfargs+=( --disable-openssl )
do_configure() {
mkdir -p "${BUILD_DIR}" || die
pushd "${BUILD_DIR}" >/dev/null || die
econf "${myeconfargs[@]}" "${@}"
popd >/dev/null || die
}
do_configure --without-cython
use python && python_foreach_impl do_configure
}
src_compile() {
python_compile() {
emake -C "${BUILD_DIR}"/cython -j1 \
VPATH="${S}/cython:${native_builddir}/cython" \
imobiledevice_la_LIBADD="${native_builddir}/src/libimobiledevice.la"
}
local native_builddir=${BUILD_DIR}
pushd "${BUILD_DIR}" >/dev/null || die
emake -j1
use python && python_foreach_impl python_compile
popd >/dev/null || die
}
src_install() {
python_install() {
emake -C "${BUILD_DIR}/cython" -j1 \
VPATH="${S}/cython:${native_builddir}/cython" \
DESTDIR="${D}" install
}
local native_builddir=${BUILD_DIR}
pushd "${BUILD_DIR}" >/dev/null || die
emake -j1 DESTDIR="${D}" install
use python && python_foreach_impl python_install
popd >/dev/null || die
dodoc docs/html/*
if use python; then
insinto /usr/include/${PN}/cython
doins cython/imobiledevice.pxd
fi
prune_libtool_files --all
}
|
GitWeb