1 files changed, 63 insertions, 0 deletions
diff --git a/www-apps/drupal/drupal-6.37.ebuild b/www-apps/drupal/drupal-6.37.ebuild
new file mode 100644
index 000000000000..35750de6f462
--- /dev/null
+++ b/www-apps/drupal/drupal-6.37.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit webapp
+
+MY_PV=${PV:0:3}.0
+
+DESCRIPTION="PHP-based open-source platform and content management system"
+HOMEPAGE="http://drupal.org/"
+SRC_URI="http://drupal.org/files/projects/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86"
+IUSE="+mysql postgres"
+
+RDEPEND="
+	dev-lang/php[gd,pdo,postgres?,xml]
+	virtual/httpd-php
+	mysql? (
+		|| (
+			dev-lang/php[mysql]
+			dev-lang/php[mysqli]
+		)
+	)"
+
+need_httpd_cgi
+
+REQUIRED_USE="|| ( mysql postgres )"
+
+src_install() {
+	webapp_src_preinst
+
+	local docs="MAINTAINERS.txt LICENSE.txt INSTALL.txt CHANGELOG.txt INSTALL.mysql.txt INSTALL.pgsql.txt UPGRADE.txt "
+	dodoc ${docs}
+	rm -f ${docs} INSTALL COPYRIGHT.txt || die
+
+	cp sites/default/{default.settings.php,settings.php} || die
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	dodir "${MY_HTDOCSDIR}"/files
+	webapp_serverowned "${MY_HTDOCSDIR}"/files
+	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default
+	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default/settings.php
+
+	webapp_configfile "${MY_HTDOCSDIR}"/sites/default/settings.php
+	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	echo
+	ewarn "SECURITY NOTICE"
+	ewarn "If you plan on using SSL on your Drupal site, please consult the postinstall information:"
+	ewarn "\t# webapp-config --show-postinst ${PN} ${PV}"
+	echo
+}