1 files changed, 44 insertions, 0 deletions
diff --git a/sys-devel/byfl/byfl-1.4.ebuild b/sys-devel/byfl/byfl-1.4.ebuild
new file mode 100644
index 000000000000..e57a7eac468c
--- /dev/null
+++ b/sys-devel/byfl/byfl-1.4.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools-utils flag-o-matic
+
+if [ "${PV}" = "9999" ]; then
+	LLVM_VERSION="3.7.0"
+	EGIT_REPO_URI="git://github.com/losalamos/${PN^b}.git https://github.com/losalamos/${PN}.git"
+	inherit git-2
+	KEYWORDS=""
+	AUTOTOOLS_AUTORECONF=1
+else
+	LLVM_VERSION="3.7.0"
+	MY_P="${P}-llvm-${LLVM_VERSION}"
+	SRC_URI="https://github.com/losalamos/Byfl/releases/download/v${MY_P#${PN}-}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~amd64-linux"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Compiler-based Application Analysis"
+HOMEPAGE="https://github.com/losalamos/Byfl"
+
+SLOT="0"
+LICENSE="BSD"
+IUSE="hdf5 static-libs sqlite"
+
+RDEPEND="
+	>=sys-devel/clang-${LLVM_VERSION}
+	>=sys-devel/llvm-${LLVM_VERSION}
+	sys-devel/binutils:0
+	dev-lang/perl:=
+	dev-perl/Switch
+	hdf5? ( sci-libs/hdf5[cxx] )
+	sqlite? ( dev-db/sqlite:3 )"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	append-cxxflags -std=c++11
+	use sqlite || export ac_cv_lib_sqlite3_sqlite3_errstr=no
+	autotools-utils_src_configure H5CXX=$(usex hdf5 h5c++ no)
+}