1 files changed, 47 insertions, 0 deletions
diff --git a/net-libs/libnftnl/libnftnl-1.1.2-r1.ebuild b/net-libs/libnftnl/libnftnl-1.1.2-r1.ebuild
new file mode 100644
index 000000000000..e64e6e551a11
--- /dev/null
+++ b/net-libs/libnftnl/libnftnl-1.1.2-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools linux-info toolchain-funcs
+
+DESCRIPTION="Netlink API to the in-kernel nf_tables subsystem"
+HOMEPAGE="https://netfilter.org/projects/nftables/"
+SRC_URI="https://netfilter.org/projects/${PN}/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0/11" # libnftnl.so version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86"
+IUSE="examples static-libs test"
+
+RDEPEND=">=net-libs/libmnl-1.0.3"
+DEPEND="virtual/pkgconfig
+	${RDEPEND}"
+
+pkg_setup() {
+	if kernel_is ge 3 13; then
+		CONFIG_CHECK="~NF_TABLES"
+		linux-info_pkg_setup
+	else
+		eerror "This package requires kernel version 3.13 or newer to work properly."
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	gen_usr_ldscript -a nftnl
+	find "${D}" -name '*.la' -delete || die "Could not rm libtool files"
+
+	if use examples; then
+		find examples/ -name 'Makefile*' -delete || die "Could not rm examples"
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}