1 files changed, 113 insertions, 0 deletions
diff --git a/gnome-base/librsvg/librsvg-2.54.1.ebuild b/gnome-base/librsvg/librsvg-2.54.1.ebuild
new file mode 100644
index 000000000000..656e02c638ae
--- /dev/null
+++ b/gnome-base/librsvg/librsvg-2.54.1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_EAUTORECONF=yes # for patching configure.ac
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gnome2 multilib-minimal python-any-r1 rust-toolchain vala
+
+DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
+HOMEPAGE="https://wiki.gnome.org/Projects/LibRsvg https://gitlab.gnome.org/GNOME/librsvg"
+
+LICENSE="LGPL-2+"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+IUSE="gtk-doc +introspection +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="test" # Lots of issues on 32bit builds, 64bit build seems to get into an infinite compilation sometimes, etc.
+
+RDEPEND="
+	>=x11-libs/cairo-1.16.0[glib,svg,${MULTILIB_USEDEP}]
+	>=media-libs/freetype-2.9:2[${MULTILIB_USEDEP}]
+	>=x11-libs/gdk-pixbuf-2.20:2[introspection?,${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.50.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/harfbuzz-2.0.0:=[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
+	>=x11-libs/pango-1.48.11[${MULTILIB_USEDEP}]
+
+	introspection? ( >=dev-libs/gobject-introspection-0.10.8:= )
+"
+DEPEND="${RDEPEND}
+	>=virtual/rust-1.56[${MULTILIB_USEDEP}]
+	${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/docutils[${PYTHON_USEDEP}]')
+	gtk-doc? ( dev-util/gi-docgen )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+
+	dev-libs/gobject-introspection-common
+	dev-libs/vala-common
+"
+# dev-libs/gobject-introspection-common, dev-libs/vala-common needed by eautoreconf
+
+QA_FLAGS_IGNORED="
+	usr/bin/rsvg-convert
+	usr/lib.*/librsvg.*
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-build-Add-enable-gtk-doc-flag.patch
+)
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	local myconf=(
+		--disable-static
+		--disable-debug
+		$(multilib_native_use_enable gtk-doc)
+		$(multilib_native_use_enable introspection)
+		$(multilib_native_use_enable vala)
+		--enable-pixbuf-loader
+	)
+
+	if ! multilib_is_native_abi; then
+		myconf+=(
+			# Set the rust target, which can differ from CHOST
+			RUST_TARGET="$(rust_abi)"
+			# RUST_TARGET is only honored if cross_compiling, but non-native ABIs aren't cross as
+			# far as C parts and configure auto-detection are concerned as CHOST equals CBUILD
+			cross_compiling=yes
+		)
+	fi
+
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure "${myconf[@]}"
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/html doc/html || die
+	fi
+}
+
+multilib_src_compile() {
+	gnome2_src_compile
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name '*.la' -delete || die
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PF}/Rsvg-2.0 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	multilib_foreach_abi gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	multilib_foreach_abi gnome2_pkg_postrm
+}