1 files changed, 81 insertions, 0 deletions
diff --git a/dev-libs/libdnet/libdnet-1.14-r2.ebuild b/dev-libs/libdnet/libdnet-1.14-r2.ebuild
new file mode 100644
index 000000000000..068ca755f136
--- /dev/null
+++ b/dev-libs/libdnet/libdnet-1.14-r2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+AT_M4DIR="config"
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_OPTIONAL=1
+inherit autotools distutils-r1
+
+DESCRIPTION="simplified, portable interface to several low-level networking routines"
+HOMEPAGE="https://github.com/ofalk/libdnet"
+SRC_URI="https://github.com/ofalk/${PN}/archive/${P}.tar.gz"
+LICENSE="LGPL-2"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="python test"
+
+DEPEND="
+	python? ( ${PYTHON_DEPS} )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	python? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+"
+RESTRICT="test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+DOCS=( README.md THANKS )
+S="${WORKDIR}/${PN}-${P}"
+PATCHES=(
+	"${FILESDIR}/${PN}-1.14-ndisc.patch"
+	"${FILESDIR}/${PN}-1.14-strlcpy.patch"
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's/libcheck.a/libcheck.so/g' \
+		-e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
+		configure.ac || die
+	sed -i \
+		-e 's|-L$libdir ||g' \
+		dnet-config.in || die
+	sed -i \
+		-e '/^SUBDIRS/s|python||g' \
+		Makefile.am || die
+
+	eautoreconf
+
+	if use python; then
+		cd python
+		distutils-r1_src_prepare
+	fi
+}
+
+src_configure() {
+	econf --disable-static $(use_with python)
+}
+
+src_compile() {
+	default
+	if use python; then
+		cd python
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	default
+	if use python; then
+		cd python
+		unset DOCS
+		distutils-r1_src_install
+	fi
+	find "${D}" -name '*.la' -delete || die
+}