1 files changed, 80 insertions, 0 deletions
diff --git a/app-office/texstudio/texstudio-3.1.2-r1.ebuild b/app-office/texstudio/texstudio-3.1.2-r1.ebuild
new file mode 100644
index 000000000000..36805ea1f9ec
--- /dev/null
+++ b/app-office/texstudio/texstudio-3.1.2-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop qmake-utils xdg
+
+MY_PV="${PV/_/}"
+DESCRIPTION="Free cross-platform LaTeX editor (fork from texmakerX)"
+HOMEPAGE="https://www.texstudio.org https://github.com/texstudio-org/texstudio"
+SRC_URI="https://github.com/texstudio-org/texstudio/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~ppc64 x86"
+IUSE="video"
+
+DEPEND="
+	app-text/hunspell:=
+	app-text/poppler:=[qt5]
+	>=dev-libs/quazip-0.7.3-r1:0=
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtscript:5
+	dev-qt/qtsingleapplication[qt5(+),X]
+	dev-qt/qtsvg:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXext
+	video? ( >=media-libs/phonon-4.11.0 )
+"
+RDEPEND="
+	${DEPEND}
+	app-text/ghostscript-gpl
+	app-text/psutils
+	media-libs/netpbm
+	virtual/latex-base
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.5-quazip1.patch" # TODO: upstream
+)
+
+src_prepare() {
+	xdg_src_prepare
+
+	if has_version "<dev-libs/quazip-1.0"; then
+		sed -e "/PKGCONFIG/s/quazip1-qt5/quazip/" -i ${PN}.pro || die
+	fi
+	rm -r src/quazip || die
+
+	if use video; then
+		sed "/^PHONON/s:$:true:g" -i ${PN}.pro || die
+	fi
+
+	sed -e "/qtsingleapplication.pri/s/.*/CONFIG += qtsingleapplication/" \
+		-i ${PN}.pro || die
+}
+
+src_configure() {
+	eqmake5 USE_SYSTEM_HUNSPELL=1 USE_SYSTEM_QUAZIP=1
+}
+
+src_install() {
+	local i
+	for i in 16x16 22x22 32x32 48x48 64x64 128x128; do
+		newicon -s ${i} utilities/${PN}${i}.png ${PN}.png
+	done
+
+	emake DESTDIR="${D}" INSTALL_ROOT="${ED}" install
+}