1 files changed, 49 insertions, 0 deletions
diff --git a/app-containers/docker-compose/docker-compose-2.17.2.ebuild b/app-containers/docker-compose/docker-compose-2.17.2.ebuild
new file mode 100644
index 000000000000..a8e67ae22e10
--- /dev/null
+++ b/app-containers/docker-compose/docker-compose-2.17.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2018-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit bash-completion-r1 go-module
+MY_PV=${PV/_/-}
+
+DESCRIPTION="Multi-container orchestration for Docker"
+HOMEPAGE="https://github.com/docker/compose"
+SRC_URI="https://github.com/docker/compose/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" https://dev.gentoo.org/~williamh/dist/${P}-deps.tar.xz"
+
+LICENSE="Apache-2.0"
+SLOT="2"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND=">=app-containers/docker-cli-23.0.0"
+
+S="${WORKDIR}/compose-${MY_PV}"
+
+src_prepare() {
+	default
+	# do not strip
+	sed -i -e 's/-s -w//' Makefile || die
+}
+
+src_compile() {
+	emake VERSION=v${PV}
+}
+
+src_test() {
+	emake test
+}
+
+src_install() {
+	exeinto /usr/libexec/docker/cli-plugins
+	doexe bin/build/docker-compose
+	dodoc README.md
+}
+
+pkg_postinst() {
+	ewarn
+	ewarn "docker-compose 2.x is a sub command of docker"
+	ewarn "Use 'docker compose' from the command line instead of"
+	ewarn "'docker-compose'"
+	ewarn "If you need to keep 1.x around, please run the following"
+	ewarn "command before your next --depclean"
+	ewarn "# emerge --noreplace docker-compose:0"
+}