x11-terms/qterminal: add dev-qt/qtbase[X] dependency

Reportedly fails to build without this.

Also sync 9999 with ::qt.

Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

2 files changed, 51 insertions, 10 deletions

diff --git a/x11-terms/qterminal/qterminal-2.0.0-r1.ebuild b/x11-terms/qterminal/qterminal-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..14dfb83303be
--- /dev/null
+++ b/x11-terms/qterminal/qterminal-2.0.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Qt-based multitab terminal emulator"
+HOMEPAGE="https://lxqt-project.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2 GPL-2+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND=">=dev-util/lxqt-build-tools-2.0.0"
+DEPEND="
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets,X]
+	x11-libs/libX11
+	~x11-libs/qtermwidget-${PV}:=
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/x11-terms/qterminal/qterminal-9999.ebuild b/x11-terms/qterminal/qterminal-9999.ebuild
index 7e969e772422..14dfb83303be 100644
--- a/x11-terms/qterminal/qterminal-9999.ebuild
+++ b/x11-terms/qterminal/qterminal-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -8,12 +8,12 @@ inherit cmake xdg-utils
 DESCRIPTION="Qt-based multitab terminal emulator"
 HOMEPAGE="https://lxqt-project.org/"
 
-if [[ ${PV} = *9999* ]]; then
+if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
 else
 	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+	KEYWORDS="~amd64"
 fi
 
 LICENSE="GPL-2 GPL-2+"
@@ -21,16 +21,11 @@ SLOT="0"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
-BDEPEND=">=dev-util/lxqt-build-tools-0.13.0"
+BDEPEND=">=dev-util/lxqt-build-tools-2.0.0"
 DEPEND="
-	>=dev-qt/qtcore-5.15:5
-	>=dev-qt/qtdbus-5.15:5
-	>=dev-qt/qtgui-5.15:5
-	>=dev-qt/qtwidgets-5.15:5
-	>=dev-qt/qtx11extras-5.15:5
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets,X]
 	x11-libs/libX11
 	~x11-libs/qtermwidget-${PV}:=
-	test? ( dev-qt/qttest:5 )
 "
 RDEPEND="${DEPEND}"