x11-terms/guake: add 3.9.0

Closes: https://bugs.gentoo.org/889900
Closes: https://bugs.gentoo.org/890259
Signed-off-by: Michael Corvinus <voron1@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/28953
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/x11-terms/guake/Manifest b/x11-terms/guake/Manifest
index 43fe2c1115aa..a4d5a0939e61 100644
--- a/x11-terms/guake/Manifest
+++ b/x11-terms/guake/Manifest
@@ -1 +1,2 @@
 DIST guake-3.8.5.gh.tar.gz 1112897 BLAKE2B 221e6a388c3a5904cd20a762e6a669e30b59a742a550e5c2a411534c3b0730c7622f42c67fdc72785fac199c432a297beb9fb53be2b5e2b7545a5b03c2b8b545 SHA512 40605fadb3a0149ea488a7e93f1b7e4f5250f62fe058292f2c02f03f837f22e13171b28c4a9d1a14c2e4897c0066a683cae547e03862397310bc650d149181fb
+DIST guake-3.9.0.gh.tar.gz 1118696 BLAKE2B 0c9fdcc5ff11d2f7263154594060a2145cefe678410cebb562dfd355a375019870a240ba4fb3868e69fdb5cf5bf49e73c3c5c2a1acef00251f68feebd8efdeba SHA512 d90e8a12285cd7488fe1132dc5af05d5eccec19a43ae98202631a15d12dfd21c3bda542e5f31ec409481d987a1bd013892c9343e7a74405a784e530efbd83503
diff --git a/x11-terms/guake/guake-3.9.0.ebuild b/x11-terms/guake/guake-3.9.0.ebuild
new file mode 100644
index 000000000000..16d94ee8b450
--- /dev/null
+++ b/x11-terms/guake/guake-3.9.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit distutils-r1 gnome2-utils plocale virtualx xdg
+
+PLOCALES="ca cs de el es fa fi fr gl hr hu id it ja ko nb nl pa pl pt_BR ru sv tr uk zh_CN zh_TW"
+
+DESCRIPTION="Drop-down terminal for GNOME"
+HOMEPAGE="http://guake-project.org/"
+SRC_URI="https://github.com/Guake/guake/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="utempter"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]')
+	dev-libs/keybinder:3[introspection]
+	x11-libs/libnotify[introspection]
+	x11-libs/libwnck:3[introspection]
+	x11-libs/vte:2.91[introspection]
+	utempter? ( sys-libs/libutempter )"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools_scm[${PYTHON_USEDEP}]
+		test? (
+			dev-python/pyfakefs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+		)')
+	dev-libs/glib:2
+	gnome-base/gsettings-desktop-schemas
+	sys-devel/gettext"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV} # needed with github's tarball
+
+	local po=($(plocale_get_locales disabled))
+	po=("${po[@]/%/.po}")
+	(( ! ${#po[@]} )) || rm "${po[@]/#/po/}" || die
+
+	emake PREFIX="${EPREFIX}"/usr prepare-install # paths.py.in -> paths.py
+}
+
+python_test() {
+	# - uses /usr/bin/bash if SHELL is not exported
+	SHELL=${SHELL} virtx epytest
+}
+
+python_install() {
+	# use right schema/data dirs, done here so tests don't use the system's
+	sed -e "/^SCHEMA_DIR/s|=.*|= \"${EPREFIX}/usr/share/glib-2.0/schemas\"|" \
+		-e "/def get_default_data_dir/{n;s|=.*|= \"${EPREFIX}/usr/share/guake\"|}" \
+		-i "${BUILD_DIR}/install$(python_get_sitedir)"/guake/paths.py || die
+	python_optimize "${BUILD_DIR}/install$(python_get_sitedir)"/guake/paths.py
+
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install-{locale,schemas}
+
+	dodoc NEWS.rst README.rst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}