www-misc/buku: add 4.7

Signed-off-by: John Helmert III <ajak@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/www-misc/buku/Manifest b/www-misc/buku/Manifest
index 535588ada185..d274f0444203 100644
--- a/www-misc/buku/Manifest
+++ b/www-misc/buku/Manifest
@@ -1 +1,2 @@
 DIST buku-4.6.tar.gz 491809 BLAKE2B 82597b845c56dadf1cc6973d1f3ce6cc4970230d08ac700cf286a8c41420144fb1f42817ab808041600ab8414d96f3a3883c1bd8fbe89f29570d877a495dcd96 SHA512 1c46006d8c950811493a8c11453d51557cac3f6346ea28d66dcb2ae3e4c52727af7349b4b6ea088f9c08a7e9d09e3a4d80679b41497b6cd0844d811f81c9811a
+DIST buku-4.7.tar.gz 495773 BLAKE2B 193849333bae9436573d596285f56b17b1b69c4352acbd883d0a82ed3645a7888a509f36ee33fa29526bd3d429e482ef8f43a0e1fd8def7d499f48afd9adba17 SHA512 f5e8984638d2fadeb1227f6ed9015c17fc46f490b6dc3ede7b66db79489cc96c9a8e3426f4722503a7e5a918d874813cf4f1462c4a32ea247e8c581e34555c07
diff --git a/www-misc/buku/buku-4.7.ebuild b/www-misc/buku/buku-4.7.ebuild
new file mode 100644
index 000000000000..e27904a3d54b
--- /dev/null
+++ b/www-misc/buku/buku-4.7.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Powerful command-line bookmark manager"
+HOMEPAGE="https://github.com/jarun/buku"
+SRC_URI="https://github.com/jarun/${PN}/archive/v$(ver_cut 1-2).tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/beautifulsoup4-4.6.0[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/py-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-4.2[${PYTHON_USEDEP}]
+		>=dev-python/vcrpy-4.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Remove support for bukuserver - complex depgraph which isn't all
+	# sufficiently packaged in Gentoo
+	sed -ie '/console_scripts/s/,.*/]/' setup.py || die
+	sed -ie 's/.*bukuserver.*//' tests/test_views.py || die
+	sed -ie 's/.*flask.*//' tests/test_views.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr/share/zsh/site-functions
+	doins auto-completion/zsh/_*
+
+	newbashcomp auto-completion/bash/buku-completion.bash "${PN}"
+
+	doman buku.1
+}
+
+python_test() {
+	local skipped_tests=(
+		# Disable tests related to bukuserver
+		tests/test_setup.py::test_bukuserver_requirement
+		tests/test_views.py::test_bmv_create_form
+		tests/test_views.py::test_bookmark_model_view
+		tests/test_views.py::test_load_firefox_database
+		tests/test_views.py::test_tag_model_view_get_list
+		tests/test_views.py::test_tag_model_view_get_list_empty_db
+
+		# Broken with network-sandbox
+		tests/test_buku.py::test_network_handler_with_url
+		tests/test_bukuDb.py::TestBukuDb::test_tnyfy_url
+		tests/test_bukuDb.py::test_add_rec_exec_arg
+		tests/test_bukuDb.py::test_load_firefox
+		tests/test_bukuDb.py::test_print_db
+		tests/test_bukuDb.py::test_print_rec
+		tests/test_bukuDb.py::test_refreshdb
+
+		# Hard to debug sandbox issue - these pass when run outside portage
+		# There also appears to be some state issue between these, because
+		# skipping one can result in a later one failing.
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-True-False]
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-False-True]
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-False-False]
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-True-True]
+	)
+
+	# tests/test_server.py is bukuserver tests, ignore it
+	pytest -p no:verbose-parametrize -v --ignore tests/test_server.py ${skipped_tests[@]/#/--deselect } || die "Tests failed with ${EPYTHON}"
+}