sys-kernel/gentoo-kernel-bin: bump to 5.11.19 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 7458dff89a6c..1af903321225 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -87,6 +87,7 @@ DIST gentoo-kernel-5.11.18-1.amd64.xpak 65852667 BLAKE2B 29ddd550bd6cfec25809c53
 DIST gentoo-kernel-5.11.18-1.arm64.xpak 59841788 BLAKE2B 8f954d6986e3d4d1c7a7f9f44f39d8817fb01bffd933ecf7124432f9626e5a6d77cdee800d9147e49334c2920f6149ef4cc8e4120709cff8ba61463dc953504d SHA512 f83a415929c3195c7dcc85df311fc2b4b10083d9f5ebbc1098cf489efd9eee8418b540b342b84b7fee6323d5e4d84cad9c83cb0179a7caf84c62fff8ca667c30
 DIST gentoo-kernel-5.11.18-1.x86.xpak 57632889 BLAKE2B 449dfd81cb72441bb85baa686f3ac6c17f54febd6ad8a48b9c16ee7c3821dc2fc0a5e44480fdec74fb28cf345864a72c4493335d23ffa4735cd7735a1cc9fc93 SHA512 564e98fc485c43b65aa3a1a6e40b30d03ea8927a2588ee82d9f890704db7d51002400c59b75455366e2d86dd59ccbec74f18d1ef5e906bbd2a084f22b66f3d30
 DIST gentoo-kernel-5.11.19-1.amd64.xpak 65896925 BLAKE2B 7bad7ad368668bf79b5ac630b4e9bedfee4c81d7a27459fac002d5d4cb40496922f134bf41a2c479a184b64fbda0da6eb45e37724b1c6e29ebb56e3838b81052 SHA512 56c49da22f0a7c8870e7a57e2bdced8eba2b0295ffe7e3a5977b22e39fa43000077cccdad893643a0abb9a82aa9f57a32a8a47873839d549627cbba435b3010b
+DIST gentoo-kernel-5.11.19-1.arm64.xpak 59764011 BLAKE2B 719a3282547c4980ae5b1980be86e4a0b7f881577aee11fec21dcd374b1b89303d0cd6f9528b373a48a61ce0d5bbc6304ca2302a038e81e1bccb34b6d3af2139 SHA512 8b526f37e6d444d43e0b39936b6fa6e644d986794333bb33381fcdb6d78d3e9343ba4353ad558955eee4ce15c777bc2c13224851254fa84868d8e16a29d0243e
 DIST gentoo-kernel-5.11.19-1.x86.xpak 57672197 BLAKE2B 6df796e0b3ea63700742825665e4c5703290b00d2fc205b46e01a6da1609c4d44bb4e8a9c8c7631bfa85da76c93ea3eb01f16aa1614440bac55f466ba2f0e15f SHA512 a2106657d40dad990a7034c5fb0a13e2cd16025a88e3dcac861f5bd16f755e2268b1b8622c6be293fda457dfb5e20583db9f56d792d7fe679f3e7f2c65d6396d
 DIST gentoo-kernel-5.4.109-1.amd64.xpak 61197533 BLAKE2B d192b84c8e00a992256d44bce33975e29f7ae330a62a5902df14ca08ac5222c3bdbcb1ac27df36db615deecd7af7e264842c2aa358e4cc54e830f3507f5ad034 SHA512 33f192621fa3aa692e7b77897e57e50c7af81cb3ba6a40fd090bdafb5ed7b83dc83438028fc6999723e7f82a22635462746a92ced5439f136c56e0559c85b945
 DIST gentoo-kernel-5.4.109-1.arm64.xpak 56430663 BLAKE2B 6079b762ab5cdeb0c745a1a030e4a3af36883588c88dcb8c8cd811aa47d7cbaebc573b152f01fed451dbbfda1ec89ed400270e6fda4e3e1df1aec497b3f7815a SHA512 2d29230577255473618d698363af8c7ef8dd9dd3dcaeaec8fc8802e453838d2c1685e001a6ceb784f6c6ab77fb2b991366e213fec9c45b5763a3a5f57674cef7
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.19-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.19-r1.ebuild
new file mode 100644
index 000000000000..2760e617c656
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.19-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}