sys-fs/btrfs-progs: bump up to 4.7

Package-Manager: portage-2.3.0_p23

3 files changed, 96 insertions, 1 deletions

diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 892131030e46..77e0920e8dfc 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -15,3 +15,4 @@ DIST btrfs-progs-v4.5.1.tar.xz 1183872 SHA256 eef87b2d0e231656afbffab35718c79a77
 DIST btrfs-progs-v4.5.2.tar.xz 1189928 SHA256 aefb8914f72926706b54e5619a36c9b95ebb0283ba6bb032cdc3a3dfe2f81227 SHA512 4c73f90265ea1791651e83d3fa8b0515d39f3fe0a61665501ee16a0c343792efb39d84b4b4747757faacf451c77a0f88b85d9aa9fc83917571b9f1e6e9f2fafe WHIRLPOOL b2455dbe38ccf74ca4c3c3fc1808e18ca3033ec92beafa77509ab88e7fc71eb4b2d0e41e63a63dbdad3e5cd0770a1d64e065a07080359d8088680389a6d0c983
 DIST btrfs-progs-v4.5.3.tar.xz 1207344 SHA256 e6e79608d81ccda62ad877c20e4d0868dc68e570ba42f4c94e66bf5e8ee0ebd3 SHA512 7bb15728577cdc56773e87583196ed36e15a4c417f03816e8a101506070e667b8e51f66fcf98095ddc20c9ce10da0b78de1171e9c8a6cb20a4811fd35d508961 WHIRLPOOL c938f35d4ec74beeb41e8ab56632bb33c7500f283cef3d59ff97494ab957be9f2e309feb80e383c29417ba78d7e2a89704faf6fe2558a06852944790f434172c
 DIST btrfs-progs-v4.6.1.tar.xz 1281240 SHA256 4ed15ccd0fa730c13e52fb930141a0d3f300f2bb34cb1366b32d093eaaa18919 SHA512 7bdf350a3051326f495e1694e11b27b830dce219ddbb0a805f1916f5deecdbd5332c3cd8abe36296832e196eee45e4cdc4695e99e186a51b85ec8b9f6ff5381d WHIRLPOOL d7c06549947278002c4de91f47b2b85d93a714bf1e984ce2b4d7321bcb8b0a11dd60cd84e070c382f61e67e919d3cbc88a723aaa5ab42806ecbe65ae01c4ae34
+DIST btrfs-progs-v4.7.tar.xz 1287004 SHA256 1a5fdab01c21661e39b0d596f64c8ea164d77147f7084e428e1e71da2b2999cf SHA512 7ddcf0d620311f6ed90de0f7eb07e3f338d4ed281137d41d357748c640b03601b4903cf7266180d9a1c8d33acbee66c6eb44f595da28e8f4a470b763e7303741 WHIRLPOOL 2eaa35dedd445cec202dbdfe1c062c81feef6d56d6653e9d51895c7fdb7fe8410dfda489a365f34a0ab4e76288fb7735775fd231a297f9786b3cbd8dc4b125c9
diff --git a/sys-fs/btrfs-progs/btrfs-progs-4.7.ebuild b/sys-fs/btrfs-progs/btrfs-progs-4.7.ebuild
new file mode 100644
index 000000000000..7f648be159bf
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-4.7.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit bash-completion-r1
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+	MY_PV=v${PV}
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+else
+	WANT_LIBTOOL=none
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://repo.or.cz/btrfs-progs-unstable/devel.git"
+	EGIT_BRANCH="devel"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert static static-libs"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+	dev-libs/lzo:2=
+	sys-apps/util-linux:0=[static-libs(+)?]
+	sys-libs/zlib:0=
+	convert? (
+		sys-fs/e2fsprogs:0=
+		sys-libs/e2fsprogs-libs:0=
+	)
+"
+DEPEND="${RDEPEND}
+	convert? ( sys-apps/acl )
+	>=app-text/asciidoc-8.6.0
+	app-text/docbook-xml-dtd:4.5
+	app-text/xmlto
+	static? (
+		dev-libs/lzo:2[static-libs(+)]
+		sys-apps/util-linux:0[static-libs(+)]
+		sys-libs/zlib:0[static-libs(+)]
+		convert? (
+			sys-fs/e2fsprogs:0[static-libs(+)]
+			sys-libs/e2fsprogs-libs:0[static-libs(+)]
+		)
+	)
+"
+
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+=" sys-devel/gnuconfig"
+fi
+
+src_prepare() {
+	default
+	if [[ ${PV} == 9999 ]]; then
+		eautoreconf
+		mkdir config || die
+		local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+		[[ -e ${automakedir} ]] || die "Could not locate automake directory"
+		ln -s "${automakedir}"/install-sh config/install-sh || die
+		ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess config/config.guess || die
+		ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub config/config.sub || die
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/sbin
+		$(use_enable convert)
+		$(use_enable elibc_glibc backtrace)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake V=1 all $(usev static)
+}
+
+src_install() {
+	local makeargs=(
+		$(usex static-libs '' 'libs_static=')
+		$(usex static install-static '')
+	)
+	emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+	newbashcomp btrfs-completion btrfs
+}
diff --git a/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild b/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
index d7b329150fbb..7f648be159bf 100644
--- a/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
+++ b/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
@@ -40,7 +40,7 @@ RDEPEND="
 "
 DEPEND="${RDEPEND}
 	convert? ( sys-apps/acl )
-	app-text/asciidoc
+	>=app-text/asciidoc-8.6.0
 	app-text/docbook-xml-dtd:4.5
 	app-text/xmlto
 	static? (