sys-fs/btrfs-progs: add 6.2.2, wire up tests

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 172 insertions, 4 deletions

diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 14940f3e52ec..6bfcc261f7cd 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -4,3 +4,4 @@ DIST btrfs-progs-v6.1.1.tar.xz 2329864 BLAKE2B f3f15829af88f83cdabca30b61dd0e53f
 DIST btrfs-progs-v6.1.2.tar.xz 2329940 BLAKE2B d2c86b0077e0269353ac70d948b948dd2984beec0e4225529adb0099a9cfe5d778a893bedc822168141ce29679f66500e32bdf3af8973bef5696657685ebf712 SHA512 0b02502f9f0902b7db04817fcfbaa4f6155035d47dd908c4c1faa86e4677e302d069756bb0935db7c88f0859c0f9ef87975b2777be7ad7f4d2389d2e95c1ff82
 DIST btrfs-progs-v6.1.3.tar.xz 2333984 BLAKE2B 71543f5be282a289fbc92f78b89b25e4162c3cbd2d3cf2e8564791f86c6f933f61c03ba93aeca029689be6284988ff35a47f25a6523f15be47f3e7ce9b5c0c4b SHA512 7c40d8bc3fcef0b2a7bf4be7d52923015b5b11c3f14bfc550ffa95a47d673f640b7deb840fee22fb7cc2743b6098fb12b5caea586fbf0972a1bc9a7606f3f375
 DIST btrfs-progs-v6.2.1.tar.xz 2415064 BLAKE2B 8ea7d9815e34c569dd82e53dc1f982c820265521708c7c41dc587646362b300edf938e940b52508e301874269ea5ebb96605f4a1046d096678257463ced53b03 SHA512 2a485d8c8b3091af27e91751cabe61306388526de3c1c51543708888ddee1bb26ebfe70c3b4cd6686b173d313c98c30168fee18723dadc7b4c00e10c502da169
+DIST btrfs-progs-v6.2.2.tar.xz 2437300 BLAKE2B b3d0de668baf771ff08c59d20407525be841b06747b771efc013b0c2d1d24ed03caf472b7c9b03499f60140f6f84e2edbcb690cba503a7eb8037af038de79d52 SHA512 967e1c1a6b956a4e11a794aad090d1cf370fd98e4186525ccfbbbc9ae3f2bb66ace1d684730f93c558403b7ac1c991aec3d04d07548b19ee1516352a069431db
diff --git a/sys-fs/btrfs-progs/btrfs-progs-6.2.2.ebuild b/sys-fs/btrfs-progs/btrfs-progs-6.2.2.ebuild
new file mode 100644
index 000000000000..c1f11dd5dd51
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-6.2.2.ebuild
@@ -0,0 +1,164 @@
+# Copyright 2008-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit bash-completion-r1 python-single-r1 udev
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+	MY_PV="v${PV/_/-}"
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
+
+	if [[ ${PV} != *_rc* ]] ; then
+		KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	fi
+
+	S="${WORKDIR}"/${PN}-${MY_PV}
+else
+	EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
+	EGIT_BRANCH="devel"
+	WANT_LIBTOOL="none"
+	inherit autotools git-r3
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org https://btrfs.readthedocs.io/en/latest/"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert python +man reiserfs static static-libs udev +zstd"
+# Could support it with just !systemd => eudev, see mdadm, but let's
+# see if someone asks for it first.
+REQUIRED_USE="static? ( !udev )"
+
+# Tries to mount repaired filesystems
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/lzo:2=
+	sys-apps/util-linux:=[static-libs(+)?]
+	sys-libs/zlib:=
+	convert? (
+		sys-fs/e2fsprogs:=
+		reiserfs? (
+			>=sys-fs/reiserfsprogs-3.6.27
+		)
+	)
+	python? ( ${PYTHON_DEPS} )
+	udev? ( virtual/libudev:= )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	>=sys-kernel/linux-headers-5.10
+	convert? ( sys-apps/acl )
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/setuptools[${PYTHON_USEDEP}]
+		')
+	)
+	static? (
+		dev-libs/lzo:2[static-libs(+)]
+		sys-apps/util-linux:0[static-libs(+)]
+		sys-libs/zlib:0[static-libs(+)]
+		convert? (
+			sys-fs/e2fsprogs[static-libs(+)]
+			reiserfs? (
+				>=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+			)
+		)
+		zstd? ( app-arch/zstd[static-libs(+)] )
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	man? ( dev-python/sphinx )
+"
+
+if [[ ${PV} == 9999 ]]; then
+	BDEPEND+=" sys-devel/gnuconfig"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999 ]]; then
+		AT_M4DIR="m4" eautoreconf
+
+		mkdir config || die
+		local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+		[[ -e ${automakedir} ]] || die "Could not locate automake directory"
+
+		ln -s "${automakedir}"/install-sh config/install-sh || die
+		ln -s "${BROOT}"/usr/share/gnuconfig/config.guess config/config.guess || die
+		ln -s "${BROOT}"/usr/share/gnuconfig/config.sub config/config.sub || die
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/sbin
+
+		--enable-lzo
+		--disable-experimental
+		$(use_enable convert)
+		$(use_enable man documentation)
+		$(use_enable elibc_glibc backtrace)
+		$(use_enable python)
+		$(use_enable static-libs static)
+		$(use_enable udev libudev)
+		$(use_enable zstd)
+
+		# Could support libgcrypt, libsodium, libkcapi
+		--with-crypto=builtin
+		--with-convert=ext2$(usex reiserfs ',reiserfs' '')
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake V=1 all $(usev static)
+}
+
+src_test() {
+	emake -j1 -C tests V=1 test
+
+	if use python ; then
+		cd libbtrfsutil/python || die
+
+		local -x LD_LIBRARY_PATH="${S}:libbtrfsutil/python:${LD_LIBRARY_PATH}"
+		${EPYTHON} -m unittest tests/test_*.py || die
+	fi
+}
+
+src_install() {
+	local makeargs=(
+		$(usex python install_python '')
+		$(usex static install-static '')
+	)
+
+	emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+
+	newbashcomp btrfs-completion btrfs
+
+	use python && python_optimize
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
diff --git a/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild b/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
index 14332b1b7112..c1f11dd5dd51 100644
--- a/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
+++ b/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
@@ -52,7 +52,8 @@ RDEPEND="
 	udev? ( virtual/libudev:= )
 	zstd? ( app-arch/zstd:= )
 "
-DEPEND="${RDEPEND}
+DEPEND="
+	${RDEPEND}
 	>=sys-kernel/linux-headers-5.10
 	convert? ( sys-apps/acl )
 	python? (
@@ -73,8 +74,10 @@ DEPEND="${RDEPEND}
 		zstd? ( app-arch/zstd[static-libs(+)] )
 	)
 "
-BDEPEND="virtual/pkgconfig
-	man? ( dev-python/sphinx )"
+BDEPEND="
+	virtual/pkgconfig
+	man? ( dev-python/sphinx )
+"
 
 if [[ ${PV} == 9999 ]]; then
 	BDEPEND+=" sys-devel/gnuconfig"
@@ -129,7 +132,7 @@ src_compile() {
 }
 
 src_test() {
-	default
+	emake -j1 -C tests V=1 test
 
 	if use python ; then
 		cd libbtrfsutil/python || die