net-misc/trackma: new package

Closes: https://github.com/gentoo/gentoo/pull/4831

4 files changed, 144 insertions, 0 deletions

diff --git a/net-misc/trackma/Manifest b/net-misc/trackma/Manifest
new file mode 100644
index 000000000000..87c736ebb492
--- /dev/null
+++ b/net-misc/trackma/Manifest
@@ -0,0 +1 @@
+DIST trackma-0.7.3.tar.gz 142450 SHA256 c11da6157d1008a38469f1eaa0fe325230c0d4db0ba861c8a2600d5a63c08dee SHA512 73a7caa1e740e96f29edfcdfc5dbcaf26f280371c176bba69947fff37ca935d56e280a6d3e12c0a7f6283fecdad3d8e8e82c0d45a75d1962e58fdd7458630791 WHIRLPOOL 863688a495abb5e03980d1b3cae023ee24217889cb3cb528acd9339b5601c2e463e82365addb99881765331f4cb34d02d56018bd0c4d9a5c72eb1cab5413e3d3
diff --git a/net-misc/trackma/metadata.xml b/net-misc/trackma/metadata.xml
new file mode 100644
index 000000000000..70c3dfa9d170
--- /dev/null
+++ b/net-misc/trackma/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<longdescription>
+	Trackma aims to be a lightweight and simple but feature-rich program for Unix based systems for fetching, updating and using data from personal lists hosted in several media tracking websites.
+</longdescription>
+<use>
+	<flag name="cli">Enable cli version</flag>
+	<flag name="ncurses">Enable curses version</flag>
+</use>
+<maintainer type="person">
+	<email>fdsfgs@krutt.org</email>
+	<name>soredake</name>
+</maintainer>
+<maintainer type="project">
+	<email>proxy-maint@gentoo.org</email>
+	<name>Proxy Maintainers</name>
+</maintainer>
+<upstream>
+	<remote-id type="github">z411/trackma</remote-id>
+</upstream>
+</pkgmetadata>
diff --git a/net-misc/trackma/trackma-0.7.3.ebuild b/net-misc/trackma/trackma-0.7.3.ebuild
new file mode 100644
index 000000000000..ffaed1f4ad6f
--- /dev/null
+++ b/net-misc/trackma/trackma-0.7.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{3_4,3_5} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Open multi-site list manager for media tracking sites"
+HOMEPAGE="https://github.com/z411/trackma"
+SRC_URI="https://github.com/z411/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+ncurses cli gtk inotify qt5"
+REQUIRED_USE="|| ( cli gtk ncurses qt5 )"
+
+DEPEND="ncurses? ( dev-python/urwid[${PYTHON_USEDEP}] )
+	gtk? (
+		dev-python/pygobject:3[${PYTHON_USEDEP},cairo]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)
+	qt5? (
+		dev-python/PyQt5[${PYTHON_USEDEP},gui,widgets]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)"
+RDEPEND="sys-process/lsof
+	inotify? ( || ( dev-python/inotifyx dev-python/pyinotify ) )
+	${DEPEND}"
+
+python_configure_all() {
+	sed -i -e '/trackma-qt4/d' "${S}/setup.py" || die
+	rm "${S}/trackma/ui/qt4ui.py" || die
+	if ! use qt5; then
+		sed -i -e '/trackma-qt/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/qtui.py" || die
+	fi
+	if ! use gtk; then
+		sed -i -e '/trackma-gtk/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/gtkui.py" || die
+	fi
+	if ! use ncurses; then
+		sed -i -e '/trackma-curses/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/curses.py" || die
+	fi
+	if ! use cli; then
+		sed -i -e '/trackma.ui.cli:main/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/cli.py" || die
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	newicon "${S}/trackma/data/icon.png" trackma.png
+	use cli && make_desktop_entry "${PN}" "${PN^} (cli)" "${PN}" "Network" "Terminal=true"
+	use ncurses && make_desktop_entry "${PN}-curses" "${PN^} (ncurses)" "${PN}" "Network" "Terminal=true"
+	use gtk && make_desktop_entry "${PN}-gtk" "${PN^} (gtk3)" "${PN}" "Network" "StartupWMClass=trackma-gtk3"
+	use qt5 && make_desktop_entry "${PN}-qt" "${PN^} (qt5)" "${PN}" "Network" "StartupWMClass=trackma-qt5"
+}
diff --git a/net-misc/trackma/trackma-9999.ebuild b/net-misc/trackma/trackma-9999.ebuild
new file mode 100644
index 000000000000..b93d9e2ed7c8
--- /dev/null
+++ b/net-misc/trackma/trackma-9999.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{3_4,3_5} )
+
+inherit distutils-r1 eutils git-r3
+
+DESCRIPTION="Open multi-site list manager for media tracking sites"
+HOMEPAGE="https://github.com/z411/trackma"
+EGIT_REPO_URI="https://github.com/z411/${PN}"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+ncurses cli gtk inotify qt5"
+REQUIRED_USE="|| ( cli gtk ncurses qt5 )"
+
+DEPEND="ncurses? ( dev-python/urwid[${PYTHON_USEDEP}] )
+	gtk? (
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)
+	qt5? (
+		dev-python/PyQt5[${PYTHON_USEDEP},gui,widgets]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)"
+RDEPEND="sys-process/lsof
+	inotify? ( || ( dev-python/inotifyx dev-python/pyinotify ) )
+	${DEPEND}"
+
+python_configure_all() {
+	sed -i -e '/trackma-qt4/d' "${S}/setup.py" || die
+	rm "${S}/trackma/ui/qt4ui.py" || die
+	if ! use qt5; then
+		sed -i -e '/trackma-qt/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/qtui.py" || die
+	fi
+	if ! use gtk; then
+		sed -i -e '/trackma-gtk/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/gtkui.py" || die
+	fi
+	if ! use ncurses; then
+		sed -i -e '/trackma-curses/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/curses.py" || die
+	fi
+	if ! use cli; then
+		sed -i -e '/trackma.ui.cli:main/d' "${S}/setup.py" || die
+		rm "${S}/trackma/ui/cli.py" || die
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	newicon "${S}/trackma/data/icon.png" trackma.png
+	use cli && make_desktop_entry "${PN}" "${PN^} (cli)" "${PN}" "Network" "Terminal=true"
+	use ncurses && make_desktop_entry "${PN}-curses" "${PN^} (ncurses)" "${PN}" "Network" "Terminal=true"
+	use gtk && make_desktop_entry "${PN}-gtk" "${PN^} (gtk3)" "${PN}" "Network" "StartupWMClass=trackma-gtk3"
+	use qt5 && make_desktop_entry "${PN}-qt" "${PN^} (qt5)" "${PN}" "Network" "StartupWMClass=trackma-qt5"
+}