net-misc/remmina: bump to 1.4.5

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 98 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index ad44f07a4685..6658e4d48144 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,2 +1,3 @@
 DIST Remmina-v1.4.3.tar.gz 1705751 BLAKE2B 4d49b5d5da4017cc1870a5e37a73db767862997cffdd58b080ab5707eeb293eed7e756ca974a4f4922bb9417e94610fe07b1e774f5ad7e269e797362ff264e83 SHA512 9f555f9ff60e2a136f6379a0f2828d091aa972dcff7ebd09eaf1834dc10f506d218e5cb6856c17f625c1040a11240da2ed5ebe9f4fe32a083494cfcbbdef1a41
 DIST Remmina-v1.4.4.tar.gz 1786300 BLAKE2B b4e13a34319c74f1fc935b1b72307e1dbc74d868e23f6b626e4477ca1253e52c0ba70270862c8e6e8fbfc8f7591a27b9319c41b398d4e1cf01339eb778a677b3 SHA512 2264a2d0f6ba65fbb46a2a8cc0a5c2ccd2f562e737b03cc393e7bed811d6437e76792ce3ec5013b48c9b068a58cf92081a49d05bd9be6781960e8db7e4569e35
+DIST Remmina-v1.4.5.tar.gz 1787506 BLAKE2B 095a01cca168daaef9ef59ff5adb9bb475467e8e8c42cac74a1a605627b09aa7246aa941b514b0de29739516aa988148f377040ed8629df3d5b17f0b1158cf76 SHA512 fec07b488db8d438aa6a0263e13557c10f1401a81b3371a2da03a1037d51f8e58e88652a15c6d6ce9e02535ef93ed0f9c5b674ab5efab430380f4b7dd57c4d9d
diff --git a/net-misc/remmina/remmina-1.4.5.ebuild b/net-misc/remmina/remmina-1.4.5.ebuild
new file mode 100644
index 000000000000..485866aee596
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.5.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake eutils xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="appindicator crypt cups examples gnome-keyring kwallet libressl nls spice ssh rdp telepathy vnc webkit zeroconf"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libsodium:=
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129
+		<net-misc/freerdp-3
+		cups? ( net-print/cups:= ) )
+	gnome-keyring? ( app-crypt/libsecret )
+	kwallet? ( kde-frameworks/kwallet )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( || ( >=net-dns/avahi-0.8-r2[dbus,gtk] <net-dns/avahi-0.8-r2[dbus,gtk3] ) )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	cmake_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex appindicator)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}