net-analyzer/gvm-libs: add 22.9.1

Signed-off-by: Giuseppe Foti <foti.giuseppe@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/36734
Signed-off-by: Florian Schmaus <flow@gentoo.org>

2 files changed, 113 insertions, 0 deletions

diff --git a/net-analyzer/gvm-libs/Manifest b/net-analyzer/gvm-libs/Manifest
index 19c9c6ddd694..6af3eeab1e2f 100644
--- a/net-analyzer/gvm-libs/Manifest
+++ b/net-analyzer/gvm-libs/Manifest
@@ -1,2 +1,3 @@
 DIST gvm-libs-22.8.0.tar.gz 310304 BLAKE2B ed880ca924d5f9c6d376c1b6b0711adecb095b0b79c565da6d62bf53d71ef0f49892263dc7e28e08841d33db0c480d691f4d4d95b3883d4f0751088fcf0b1d90 SHA512 5daa9157399fc8cf52cdfbdfeffe5e10a282cbe2f7b8eb6a3fefb202984f9df3bca91ef80d1d9d1bf37307cc475bd41d4b64b4f1ad0644975b295b6f32b294a6
 DIST gvm-libs-22.9.0.tar.gz 314119 BLAKE2B 481ca7a977647a53ef21079b054ed1294c0ce081693abe373dc9bb241725a141c11ab54a4eb2716b7543c678400ca933f9611d9a6615c4d39a9877a8cb40406a SHA512 39049d0eea3cca632ed25f3a807d03568213cf0daac4e7ab8d088458212e76db881644421dd44a2b34f6490eab35c171339e52e6b4ba4204ff2d9b7422578876
+DIST gvm-libs-22.9.1.tar.gz 314228 BLAKE2B 117ddf5824f0a1f5788695074fa5044b21b5dcfb8d6235a9f423174fa76d9262f361371d1f6807e88979ce49cafab64f5aa9fd1d2e855395bfa103bf6b121ec8 SHA512 b06c21ced89dc9f14dd19b256b57af910f4d7e585bf9c90fb7e3c3497bb429294e3ffb64dc6ee710e8b3beeb4ca9ac6aecb9d5e4b25f0f9761fa0c9f18a8dfd1
diff --git a/net-analyzer/gvm-libs/gvm-libs-22.9.1.ebuild b/net-analyzer/gvm-libs/gvm-libs-22.9.1.ebuild
new file mode 100644
index 000000000000..445a62fcabeb
--- /dev/null
+++ b/net-analyzer/gvm-libs/gvm-libs-22.9.1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs
+
+DESCRIPTION="Greenbone Vulnerability Management (GVM) libraries"
+HOMEPAGE="https://www.greenbone.net https://github.com/greenbone/gvm-libs/"
+SRC_URI="https://github.com/greenbone/gvm-libs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ldap test radius"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-user/gvm
+	>=app-crypt/gpgme-1.7.0:=
+	>=dev-libs/glib-2.42:2
+	>=dev-libs/hiredis-0.10.1:=
+	dev-libs/libgcrypt:=
+	dev-libs/libgpg-error
+	>=dev-libs/libxml2-2.0:2
+	>=net-libs/gnutls-3.2.15:=
+	net-libs/libnet:1.1
+	net-libs/libpcap
+	>=net-libs/libssh-0.6.0:=
+	>=sys-apps/util-linux-2.25.0
+	sys-libs/libxcrypt:=
+	>=sys-libs/zlib-1.2.8
+	net-libs/paho-mqtt-c:1.3
+	ldap? ( net-nds/openldap:= )
+	radius? ( net-dialup/freeradius-client )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-vcs/git
+	app-alternatives/yacc
+	app-alternatives/lex
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen[dot]
+		app-text/xmltoman
+		app-text/htmldoc
+		dev-perl/CGI
+		dev-perl/SQL-Translator
+	)
+	test? ( dev-libs/cgreen )
+"
+
+src_prepare() {
+	cmake_src_prepare
+	# QA-Fix | Remove -Werror compiler flag | Bug: #909558
+	sed -i -e "s/-Werror//" "${S}"/CMakeLists.txt || die
+	# QA-Fix | Remove doxygen warnings for !CLANG
+	if use doc; then
+		if ! tc-is-clang; then
+		   local f
+		   for f in doc/*.in; do
+			sed -i \
+				-e "s*CLANG_ASSISTED_PARSING = NO*#CLANG_ASSISTED_PARSING = NO*g" \
+				-e "s*CLANG_OPTIONS*#CLANG_OPTIONS*g" \
+				"${f}" || die "couldn't disable CLANG parsing"
+		   done
+		fi
+	fi
+
+	#Remove tests that doesn't work in the network sandbox
+	if use test; then
+		sed -i 's/add_test (networking-test networking-test)/ /g' base/CMakeLists.txt || die
+		sed -i 's/add_test (util-test util-test)/ /g' boreas/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+		"-DGVM_RUN_DIR=${EPREFIX}/var/lib/gvm"
+		"-DBUILD_TESTS=$(usex test)"
+		"-DBUILD_WITH_RADIUS=$(usex radius)"
+		"-DBUILD_WITH_LDAP=$(usex ldap)"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use doc; then
+		cmake_build -C "${BUILD_DIR}" doc
+		cmake_build doc-full -C "${BUILD_DIR}" doc
+	fi
+	cmake_build rebuild_cache
+	if use test; then
+		cmake_build tests
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${BUILD_DIR}"/doc/generated/html/. )
+	fi
+	cmake_src_install
+
+	# Set proper permissions on required files/directories
+	keepdir /var/lib/gvm
+	if ! use prefix; then
+		fowners -R gvm:gvm /var/lib/gvm
+	fi
+}