media-video/libva-utils: fixed dependencies, minor other fixes

1. While it is declared that libva-utils are backward compatible with
the older version of libva, it is not truth. Let's require similar
version of libva as dependency. Bug: https://bugs.gentoo.org/743835
2. Xext, Xfixes and libdrm are not required anymore starting from
version 2.7.1 of libva-utils. Dropped.
3. Sometimes the upstream publishes tarballs with generated
'configure'. Let's use it.

Closes: https://bugs.gentoo.org/743835
Signed-off-by: Karlson2k (Evgeny Grin) <k2k@narod.ru>
Closes: https://github.com/gentoo/gentoo/pull/18943
Signed-off-by: Sam James <sam@gentoo.org>

4 files changed, 175 insertions, 11 deletions

diff --git a/media-video/libva-utils/Manifest b/media-video/libva-utils/Manifest
index 112c788b2114..312608ca7c04 100644
--- a/media-video/libva-utils/Manifest
+++ b/media-video/libva-utils/Manifest
@@ -1,3 +1,4 @@
 DIST libva-utils-2.4.0.tar.bz2 1030271 BLAKE2B b57947f9bd63f34b27a403484ae6b66e750f854dd87c8448afb3d361581d83b20a5ffd8d7e22c9dbf5fae6f7ff3fd62d70cc248b29a862066ff10928629e4d11 SHA512 c5c674179ed589968fd296a7e33dd57a3476c237d8e15258938b364051d501e156c22b41b98fe59d6bc36805495a934dee602ec9e9bb5350c72aa65d3d300ff6
 DIST libva-utils-2.8.0.tar.bz2 1037112 BLAKE2B 9168d7d489e1574d970e9e3a270946de522a4063b80c4cafe38cc6917b99deb6394570592d3ed29a0ff7b92f819b9bbc9eb2a8f3b70077625a2714f70ee1959e SHA512 b3412349234ad2923953296674926ee7cb33c43ce17df8942f751789f0208064a4557ca16e1a5878a4e1b35e5bbbd415a9c9f182ffb24e589ac4757e990576b5
 DIST libva-utils-2.9.1.tar.gz 1198337 BLAKE2B 58f5a6a537c68eed74aec5dc8f1c4b5a0431062d1d9803d8ccb1e5c3b534edf4f91288009d5940a0ddab49beeadae92bf361bec0bee8a3214f04f3c6767b0992 SHA512 39d79d4eed1fc0890fbf89d5689d4f01f704d3c71b4986e0eaf4c4a2f836cc36338d0a01630092a31b740588426398d0381eae1dc0302b0df94859d9161d8378
+DIST libva-utils-2.9.1.tar.bz2 1037281 BLAKE2B 862b52ae8b1552e1150fadff9e45371e7065bf1c1fc9244a5ad0466a3109d56e9f3dd4d937f7474e6df2eaf806e93d520b1f2a986a0aa6bad7328f89d458706b SHA512 6573a2aa4844c10fd34fb5ed6edded33e15e65b7bd55d437da45a22dd5ef2116a3f137966433d986177705d544e6ea9a2a6582f49bb2eca6756970f341283d35
diff --git a/media-video/libva-utils/libva-utils-2.8.0-r1.ebuild b/media-video/libva-utils/libva-utils-2.8.0-r1.ebuild
new file mode 100644
index 000000000000..9c75a569bdb2
--- /dev/null
+++ b/media-video/libva-utils/libva-utils-2.8.0-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/libva-utils"
+fi
+
+if [[ ${PV} = 2.8.0 ]]; then
+	AUTOCONFIGURED="true"
+else
+	AUTOCONFIGURED="false"
+fi
+
+if ! ${AUTOCONFIGURED}; then
+	inherit autotools
+fi
+
+DESCRIPTION="Collection of utilities and tests for VA-API"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+if [[ ${PV} != *9999* ]] ; then
+	if ${AUTOCONFIGURED}; then
+		SRC_URI="https://github.com/intel/libva-utils/releases/download/${PV}/${P}.tar.bz2"
+	else
+		SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	fi
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+drm test wayland X"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="|| ( drm wayland X )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	>=x11-libs/libva-${PV}:=[drm?,wayland?,X?]
+	wayland? ( >=dev-libs/wayland-1.0.6 )
+	X? ( >=x11-libs/libX11-1.6.2 )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( NEWS )
+
+src_prepare() {
+	default
+	sed -e 's/-Werror//' -i test/Makefile.am || die
+	if ${AUTOCONFIGURED}; then
+		sed -e 's/-Werror//' -i test/Makefile.in || die
+		touch ./configure || die
+	else
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable drm)
+		$(use_enable test tests)
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	[[ ${PV} = *9999* ]] && DOCS+=( CONTRIBUTING.md README.md )
+	default
+}
diff --git a/media-video/libva-utils/libva-utils-2.9.1-r1.ebuild b/media-video/libva-utils/libva-utils-2.9.1-r1.ebuild
new file mode 100644
index 000000000000..bae5e011ad5e
--- /dev/null
+++ b/media-video/libva-utils/libva-utils-2.9.1-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/libva-utils"
+fi
+
+if [[ ${PV} = 2.9.1 ]]; then
+	AUTOCONFIGURED="true"
+else
+	AUTOCONFIGURED="false"
+fi
+
+if ! ${AUTOCONFIGURED}; then
+	inherit autotools
+fi
+
+DESCRIPTION="Collection of utilities and tests for VA-API"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+if [[ ${PV} != *9999* ]] ; then
+	if ${AUTOCONFIGURED}; then
+		SRC_URI="https://github.com/intel/libva-utils/releases/download/${PV}/${P}.tar.bz2"
+	else
+		SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	fi
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+drm test wayland X"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="|| ( drm wayland X )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	>=x11-libs/libva-2.9.0:=[drm?,wayland?,X?]
+	wayland? ( >=dev-libs/wayland-1.0.6 )
+	X? ( >=x11-libs/libX11-1.6.2 )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( NEWS )
+
+src_prepare() {
+	default
+	sed -e 's/-Werror//' -i test/Makefile.am || die
+	if ${AUTOCONFIGURED}; then
+		sed -e 's/-Werror//' -i test/Makefile.in || die
+		touch ./configure || die
+	else
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable drm)
+		$(use_enable test tests)
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	[[ ${PV} = *9999* ]] && DOCS+=( CONTRIBUTING.md README.md )
+	default
+}
diff --git a/media-video/libva-utils/libva-utils-9999.ebuild b/media-video/libva-utils/libva-utils-9999.ebuild
index 61b1748bbee5..bae5e011ad5e 100644
--- a/media-video/libva-utils/libva-utils-9999.ebuild
+++ b/media-video/libva-utils/libva-utils-9999.ebuild
@@ -7,13 +7,26 @@ if [[ ${PV} = *9999* ]] ; then # Live ebuild
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/intel/libva-utils"
 fi
-inherit autotools
+
+if [[ ${PV} = 2.9.1 ]]; then
+	AUTOCONFIGURED="true"
+else
+	AUTOCONFIGURED="false"
+fi
+
+if ! ${AUTOCONFIGURED}; then
+	inherit autotools
+fi
 
 DESCRIPTION="Collection of utilities and tests for VA-API"
 HOMEPAGE="https://01.org/linuxmedia/vaapi"
 if [[ ${PV} != *9999* ]] ; then
-	SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+	if ${AUTOCONFIGURED}; then
+		SRC_URI="https://github.com/intel/libva-utils/releases/download/${PV}/${P}.tar.bz2"
+	else
+		SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	fi
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
 fi
 
 LICENSE="MIT"
@@ -27,14 +40,9 @@ BDEPEND="
 	virtual/pkgconfig
 "
 DEPEND="
-	>=x11-libs/libva-2.0.0:=[drm?,wayland?,X?]
-	drm? ( >=x11-libs/libdrm-2.4 )
+	>=x11-libs/libva-2.9.0:=[drm?,wayland?,X?]
 	wayland? ( >=dev-libs/wayland-1.0.6 )
-	X? (
-		>=x11-libs/libX11-1.6.2
-		>=x11-libs/libXext-1.3.2
-		>=x11-libs/libXfixes-5.0.1
-	)
+	X? ( >=x11-libs/libX11-1.6.2 )
 "
 RDEPEND="${DEPEND}"
 
@@ -43,7 +51,12 @@ DOCS=( NEWS )
 src_prepare() {
 	default
 	sed -e 's/-Werror//' -i test/Makefile.am || die
-	eautoreconf
+	if ${AUTOCONFIGURED}; then
+		sed -e 's/-Werror//' -i test/Makefile.in || die
+		touch ./configure || die
+	else
+		eautoreconf
+	fi
 }
 
 src_configure() {