media-video/obs-studio: add version 25.0.7

Closes: https://bugs.gentoo.org/718958
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/15488
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 146 insertions, 0 deletions

diff --git a/media-video/obs-studio/Manifest b/media-video/obs-studio/Manifest
index 4adfe3fd3958..651a017c7532 100644
--- a/media-video/obs-studio/Manifest
+++ b/media-video/obs-studio/Manifest
@@ -1,2 +1,3 @@
 DIST obs-studio-24.0.5.tar.gz 7901198 BLAKE2B 79c9712f3523114a70e0df3e0631c19067fd7ead5fd9031123dd4c82d9b92dee69473fb51a495f938430540505a5cf45258eeee01d61a7aaa6654255fee14aca SHA512 99be46046b70597474f25a85036ebe5a2f704eef47c77bc27e2ba8890b877da346ff6008c5922d7a83a4cead9df7214c6a3be885430693e609a42d9d06fedfaf
 DIST obs-studio-25.0.3.tar.gz 8367286 BLAKE2B c87025f57fd2907f01c9b53464ba7174db2e19295bfd030aa8ad21356ef76d934bf9929c92c024f9ed9b96aa29a2e89dd08670baed94d2f4808f23533eec09c7 SHA512 16974bb1fbc54f3239dd92491186e608c14e209a77c485993db5815b50f2d7fd2462168377d7c254ad01c02a7daf30131efd9d2a8fe801628a0856f16e76cee0
+DIST obs-studio-25.0.7.tar.gz 8368980 BLAKE2B 7a31a33f9939392ea340126ccafa24b6fef16412a97dbed224e38aefbfa64d86274a4d033ee09b40458a4f82f4be56df4efa15784ff40f4ab4edb40027a4613e SHA512 a76a5cfe878210427e5cc934b44e1876726b788e8e4f1d439118e5b84f29ae03fb287d9e7264cccaa5b3f7ac2cc177f3f10e3682d261941e927ec0f36dc65066
diff --git a/media-video/obs-studio/obs-studio-25.0.7.ebuild b/media-video/obs-studio/obs-studio-25.0.7.ebuild
new file mode 100644
index 000000000000..33ca63777c33
--- /dev/null
+++ b/media-video/obs-studio/obs-studio-25.0.7.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit cmake-utils python-single-r1 xdg-utils
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
+	EGIT_SUBMODULES=()
+else
+	SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Software for Recording and Streaming Live Video Content"
+HOMEPAGE="https://obsproject.com"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+alsa fdk imagemagick jack luajit nvenc pulseaudio python speex +ssl truetype v4l vlc"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+	luajit? ( dev-lang/swig )
+	python? ( dev-lang/swig )
+"
+DEPEND="
+	>=dev-libs/jansson-2.5
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	media-libs/x264
+	media-video/ffmpeg:=[x264]
+	net-misc/curl
+	sys-apps/dbus
+	sys-libs/zlib
+	virtual/udev
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXfixes
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	alsa? ( media-libs/alsa-lib )
+	fdk? ( media-libs/fdk-aac:= )
+	imagemagick? ( media-gfx/imagemagick:= )
+	jack? ( virtual/jack )
+	luajit? ( dev-lang/luajit:2 )
+	nvenc? (
+		|| (
+			<media-video/ffmpeg-4[nvenc]
+			>=media-video/ffmpeg-4[video_cards_nvidia]
+		)
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	python? ( ${PYTHON_DEPS} )
+	speex? ( media-libs/speexdsp )
+	ssl? ( net-libs/mbedtls:= )
+	truetype? (
+		media-libs/fontconfig
+		media-libs/freetype
+	)
+	v4l? ( media-libs/libv4l )
+	vlc? ( media-video/vlc:= )
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local libdir=$(get_libdir)
+	local mycmakeargs=(
+		-DDISABLE_ALSA=$(usex !alsa)
+		-DDISABLE_FREETYPE=$(usex !truetype)
+		-DDISABLE_JACK=$(usex !jack)
+		-DDISABLE_LIBFDK=$(usex !fdk)
+		-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
+		-DDISABLE_SPEEXDSP=$(usex !speex)
+		-DDISABLE_V4L2=$(usex !v4l)
+		-DDISABLE_VLC=$(usex !vlc)
+		-DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
+		-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
+		-DUNIX_STRUCTURE=1
+		-DWITH_RTMPS=$(usex ssl)
+	)
+
+	if [ "${PV}" != "9999" ]; then
+		mycmakeargs+=(
+			-DOBS_VERSION_OVERRIDE=${PV}
+		)
+	fi
+
+	if use luajit || use python; then
+		mycmakeargs+=(
+			-DDISABLE_LUA=$(usex !luajit)
+			-DDISABLE_PYTHON=$(usex !python)
+			-DENABLE_SCRIPTING=yes
+		)
+	else
+		mycmakeargs+=( -DENABLE_SCRIPTING=no )
+	fi
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! use alsa && ! use pulseaudio; then
+		elog
+		elog "For the audio capture features to be available,"
+		elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
+		elog "be enabled."
+		elog
+	fi
+
+	if ! has_version "sys-apps/dbus"; then
+		elog
+		elog "The 'sys-apps/dbus' package is not installed, but"
+		elog "could be used for disabling hibernating, screensaving,"
+		elog "and sleeping.  Where it is not installed,"
+		elog "'xdg-screensaver reset' is used instead"
+		elog "(if 'x11-misc/xdg-utils' is installed)."
+		elog
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}