media-sound/gnome-music: Version bump to 44.0

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index 998e14c1c400..6f3f1606df1f 100644
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1 +1,2 @@
 DIST gnome-music-42.1.tar.xz 1652976 BLAKE2B 6a6f6249a0ae61895feeaf658e6d4b0b217ed198e2137edf2f8acdf03f8b9f0b35adf19c74d34d360f3a5d8f1e4b0c3a4004f4b14444c7ebe7b7327d94d86284 SHA512 4feb02459a010c83c66bde12d73be648e9e482117bda88ae2e44e93b59ac7c0b80522e8e4d7ccb38954465d7c012975521b0764f0a42dbecef737fe64d3c3bf1
+DIST gnome-music-44.0.tar.xz 1662928 BLAKE2B 3d9abcff6d4a220582974675c2966316259d01d0e34e805e8a9b6899f8ba44b5e70e7613c522c01bb831e0c966eb9181e7714b3226401453b34210a1322d81de SHA512 42985d13de8df838cd6beab8edc0d7c1a66c0018dbfcac2551779964194782efd2c6c6bc79c10e3bd1f8eb0a73cb783b51440338d7ff025e4e42d9196b78a847
diff --git a/media-sound/gnome-music/gnome-music-44.0.ebuild b/media-sound/gnome-music/gnome-music-44.0.ebuild
new file mode 100644
index 000000000000..76cf33a37407
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-44.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music https://gitlab.gnome.org/GNOME/gnome-music/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.67.1:2
+	>=net-libs/gnome-online-accounts-3.35.90[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	>=gui-libs/gtk-4.5.0:4[introspection]
+	>=gui-libs/libadwaita-1.2:1=[introspection]
+	>=media-libs/libmediaart-1.9.1:2.0[introspection]
+	net-libs/libsoup:3.0[introspection]
+	app-misc/tracker:3=[introspection(+)]
+	>=x11-libs/pango-1.44:=
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.36.1:3[cairo,${PYTHON_USEDEP}]
+		>=dev-python/pycairo-1.14.0[${PYTHON_USEDEP}]
+	')
+	>=media-libs/grilo-0.3.15-r1:0.3[introspection]
+	>=media-plugins/grilo-plugins-0.3.16:0.3[tracker]
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${DEPEND}
+	|| (
+		app-misc/tracker-miners:3[gstreamer]
+		app-misc/tracker-miners:3[ffmpeg]
+	)
+	x11-libs/libnotify[introspection]
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/grilo-plugins:0.3[tracker]
+	x11-misc/xdg-user-dirs
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	python_setup
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"/usr/bin/gnome-music
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}