media-gfx/graphicsmagick: add 1.3.37

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 150 insertions, 7 deletions

diff --git a/media-gfx/graphicsmagick/Manifest b/media-gfx/graphicsmagick/Manifest
index 097ae8445d3c..559dac8e96a3 100644
--- a/media-gfx/graphicsmagick/Manifest
+++ b/media-gfx/graphicsmagick/Manifest
@@ -1 +1,2 @@
 DIST GraphicsMagick-1.3.36.tar.xz 5600712 BLAKE2B 069ab4f9bb5beea3321860bf8e43c8a1b51ab102054e92486375209a86fd3c1c1fb44d4b2c43a65c78f36e9f37e09316fe77b4f261bfb0af3b2c2a86ff8b5aa5 SHA512 27ed5fcbfb0303436bdcb0f11d18257a967d471251b51e633e2c655b0a7e5ed01f61a61f9702cc7d4c02714e005ac18ca9ba0f690c0580e41d07947a03c5cbb4
+DIST GraphicsMagick-1.3.37.tar.xz 5623688 BLAKE2B d6d5c8a07ec2aa2e60399887fa788751104c6917af295bb5a7bb1281d4a547462dd76cdde98f09cc00322bc3d7c89258dcd9d50506cfcec47a606efd90163b2a SHA512 971e05480a65eb99ff3c0d874675bcbffc24eafec1cacd03f5ef410ae014f82329f3590393100927f753feb183be1105fe0cfc5b0f775a30b0e6dc0c6b8a77af
diff --git a/media-gfx/graphicsmagick/graphicsmagick-1.3.37.ebuild b/media-gfx/graphicsmagick/graphicsmagick-1.3.37.ebuild
new file mode 100644
index 000000000000..981796d97f33
--- /dev/null
+++ b/media-gfx/graphicsmagick/graphicsmagick-1.3.37.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_P=${P/graphicsm/GraphicsM}
+DESCRIPTION="Collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.graphicsmagick.org/ http://hg.code.sf.net/p/graphicsmagick/code/"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit mercurial
+	EHG_REPO_URI="http://hg.code.sf.net/p/${PN}/code"
+else
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV%.*}"
+
+IUSE="bzip2 +cxx debug dynamic-loading fpx imagemagick jbig jpeg lcms lzma"
+IUSE+=" openmp perl png postscript q16 q32 static-libs svg threads tiff truetype"
+IUSE+=" webp wmf X zlib"
+
+RDEPEND="dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	fpx? ( media-libs/libfpx )
+	imagemagick? ( !media-gfx/imagemagick )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	lzma? ( app-arch/xz-utils )
+	perl? ( dev-lang/perl:= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	svg? ( dev-libs/libxml2 )
+	tiff? ( media-libs/tiff:0 )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+	)
+	webp? ( media-libs/libwebp:= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libSM
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.36-flags.patch
+	"${FILESDIR}"/${PN}-1.3.19-perl.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local depth=8
+	use q16 && depth=16
+	use q32 && depth=32
+
+	local openmp=disable
+	if use openmp && tc-has-openmp ; then
+		openmp=enable
+	fi
+
+	local myeconfargs=(
+		--${openmp}-openmp
+		--enable-largefile
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable debug prof)
+		$(use_enable debug gcov)
+		$(use_enable imagemagick magick-compat)
+		$(use_with threads)
+		$(use_with dynamic-loading modules)
+		--with-quantum-depth=${depth}
+		--without-frozenpaths
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options=INSTALLDIRS=vendor
+		$(use_with bzip2 bzlib)
+		$(use_with postscript dps)
+		$(use_with fpx)
+		$(use_with jbig)
+		$(use_with webp)
+		$(use_with jpeg)
+		--without-jp2
+		$(use_with lcms lcms2)
+		$(use_with lzma)
+		$(use_with png)
+		$(use_with tiff)
+		$(use_with truetype ttf)
+		$(use_with wmf)
+		--with-fontpath="${EPREFIX}"/usr/share/fonts
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts
+		$(use_with svg xml)
+		$(use_with zlib)
+		$(use_with X x)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	use perl && emake perl-build
+}
+
+src_test() {
+	unset DISPLAY # some perl tests fail when DISPLAY is set
+
+	default
+}
+
+src_install() {
+	default
+
+	if use perl ; then
+		emake -C PerlMagick DESTDIR="${D}" install
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die
+}
diff --git a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
index 900a55abda11..903411326261 100644
--- a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
+++ b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
@@ -8,8 +8,6 @@ inherit autotools toolchain-funcs
 MY_P=${P/graphicsm/GraphicsM}
 DESCRIPTION="Collection of tools and libraries for many image formats"
 HOMEPAGE="http://www.graphicsmagick.org/ http://hg.code.sf.net/p/graphicsmagick/code/"
-LICENSE="MIT"
-SLOT="0/${PV%.*}"
 
 if [[ ${PV} == "9999" ]] ; then
 	inherit mercurial
@@ -17,15 +15,18 @@ if [[ ${PV} == "9999" ]] ; then
 else
 	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
 	S="${WORKDIR}/${MY_P}"
+
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
 fi
 
-IUSE="bzip2 +cxx debug dynamic-loading fpx imagemagick jbig jpeg lcms lzma
-	openmp perl png postscript q16 q32 static-libs svg threads tiff truetype
-	webp wmf X zlib"
+LICENSE="MIT"
+SLOT="0/${PV%.*}"
+
+IUSE="bzip2 +cxx debug dynamic-loading fpx imagemagick jbig jpeg lcms lzma"
+IUSE+=" openmp perl png postscript q16 q32 static-libs svg threads tiff truetype"
+IUSE+=" webp wmf X zlib"
 
-RDEPEND="
-	dev-libs/libltdl:0
+RDEPEND="dev-libs/libltdl:0
 	bzip2? ( app-arch/bzip2 )
 	fpx? ( media-libs/libfpx )
 	imagemagick? ( !media-gfx/imagemagick )
@@ -58,6 +59,7 @@ PATCHES=(
 
 src_prepare() {
 	default
+
 	eautoreconf
 }
 
@@ -106,16 +108,19 @@ src_configure() {
 		$(use_with zlib)
 		$(use_with X x)
 	)
+
 	econf "${myeconfargs[@]}"
 }
 
 src_compile() {
 	default
+
 	use perl && emake perl-build
 }
 
 src_test() {
 	unset DISPLAY # some perl tests fail when DISPLAY is set
+
 	default
 }