kde-plasma/plasma-firewall: 5.27.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index cd87bcad47d7..49811f14db9a 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.26.5.tar.xz 358560 BLAKE2B 5a5a15045414879bc155eafdec60941ba62559129cad5eb6b026e98973fa39ca7169e599190e04de5f9a7097727a98283e810f046265da122fd35f87c2be3659 SHA512 cd9ec0eef5511cab11211aac2ed14b593638386d41ce6e378053699418ac8c4698aa42d637763dae56668a794d1f877213a328dee86fe7777b909b3932bfb755
 DIST plasma-firewall-5.26.90.tar.xz 361920 BLAKE2B b432338c5b64462527f3a72f7fe742a196de64a7f082d8b2afed4cf71e44e22450cf814c1ea802b14f6552ace5e08c93fd1d9fcc9bb6c5f2397272580d190ac2 SHA512 1c2aa823914add54ddd1e57d14442a670964b086abfb5698776e5c48c93e6a7cd4be29d6c625e1254977aa835cbc1c9eceb1a697a38868da9beffa2426319d87
+DIST plasma-firewall-5.27.0.tar.xz 361776 BLAKE2B d7166983b071a976fed9aa09910c72e036bb1a737ea9c189a614007f77312e27246d1862c4462b1f72d02bf631ea0932446cb651fee8fb8f21f646ed905446b3 SHA512 fa493ed2ea25bd94731771506f9041ac2f67ab91f92516122d837da228ca56e6a4fb1c6043b5a2e8155962d6dd1f777f46623733d5d551d7712670eb6914532c
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.27.0.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.27.0.ebuild
new file mode 100644
index 000000000000..8d777543eabd
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.27.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{9..11} )
+KFMIN=5.102.0
+QTMIN=5.15.7
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}