kde-plasma/kde-gtk-config: Fix dependencies

Closes: https://bugs.gentoo.org/914139
Closes: https://bugs.gentoo.org/914378
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.27.8-r1.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.27.8-r1.ebuild
new file mode 100644
index 000000000000..9f484cf6ea1d
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.27.8-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Syncs KDE Plasma theme settings to GTK applications"
+HOMEPAGE="https://invent.kde.org/plasma/kde-gtk-config"
+
+LICENSE="GPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	dev-libs/glib:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	gnome-base/gsettings-desktop-schemas
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	x11-libs/gtk+:3[X]
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	x11-misc/xsettingsd
+"
+BDEPEND="dev-lang/sassc"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+}