kde-apps/spectacle: 21.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/kde-apps/spectacle/Manifest b/kde-apps/spectacle/Manifest
index 7ddd892cdba1..ee48aa3a33c8 100644
--- a/kde-apps/spectacle/Manifest
+++ b/kde-apps/spectacle/Manifest
@@ -1,2 +1,3 @@
 DIST spectacle-20.12.3.tar.xz 1170540 BLAKE2B 865c4f7a2b8a3edf727f551c64ce35847a880023773b72531ea324addf5f0ac327261a87e35cdea6ec1f7eb4b75d2f8b86c3d1b7fc7719959623653ebe542a93 SHA512 4749916ff1557d89c3a8aeae06ce2da4e3f5bbbc3495a588209d797453b265447a857266889a81178f33b12631f6ec29be7a65a3f98f27de604c198e997795dc
 DIST spectacle-21.04.2.tar.xz 1174904 BLAKE2B 42a6c58d27f405623264704574afc1143097e76fd0c8a4379b1c78db42ba66881dd592d948f5a55803e5cf8902a137a9dad2ffecb295d21bdf55b9cc369a7b1a SHA512 0fe6ca8b820b9d63edea5a43934a49fdcb091c0f744873cb6b04bdc773f1f8b64bbdf585013b0ef048d5a3752a04978d4328909b44ee9c82206a0df39d7a014c
+DIST spectacle-21.04.3.tar.xz 1175024 BLAKE2B 00d5ca9bf905b889e1ebbd510efc7d86571533e53206c5c65130d8b018d9e1941e283b698baab497928c6e3255d067ae6b4fde279945c0d56ed7ab7e9f226e83 SHA512 86af85d322c8d1231c4c47edaf886077dcfd1b20a33d6022ef5a8a543261e3d9f8c7b33957140d32f346c3dbaa87e13c9bed25b391771185468b4994e7ca3841
diff --git a/kde-apps/spectacle/spectacle-21.04.3.ebuild b/kde-apps/spectacle/spectacle-21.04.3.ebuild
new file mode 100644
index 000000000000..aae20e31f195
--- /dev/null
+++ b/kde-apps/spectacle/spectacle-21.04.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Screenshot capture utility"
+HOMEPAGE="https://apps.kde.org/spectacle/"
+
+LICENSE="LGPL-2+ handbook? ( FDL-1.3 ) kipi? ( GPL-2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+annotate kipi share"
+
+# TODO: Qt5Svg leaking from media-libs/kimageannotator
+DEPEND="
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	x11-libs/libxcb
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	annotate? ( >=media-libs/kimageannotator-0.4.1 )
+	kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-21.04.0-implicit-dep.patch" ) # bug 785403
+
+src_prepare() {
+	ecm_src_prepare
+	# Unnecessary with >=media-libs/kimageannotator-0.4.0
+	sed -e "/find_package\s*(\s*X11/d" -e "/find_package\s*(\s*kColorPicker/d" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package annotate kImageAnnotator)
+		$(cmake_use_find_package kipi KF5Kipi)
+		$(cmake_use_find_package share KF5Purpose)
+	)
+	ecm_src_configure
+}