gnome-extra/cinnamon-control-center: add 5.8.2

Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/gnome-extra/cinnamon-control-center/Manifest b/gnome-extra/cinnamon-control-center/Manifest
index cc722d1a215b..f97119ba2dda 100644
--- a/gnome-extra/cinnamon-control-center/Manifest
+++ b/gnome-extra/cinnamon-control-center/Manifest
@@ -1 +1,2 @@
 DIST cinnamon-control-center-5.6.1.tar.gz 3874429 BLAKE2B 53344aead6c5e31eeadf70e26a2ae61db930e595b5e546ac08b57029c924e4105d126fe6a27cd3ef7d4a59b51f83e0790dfaf815d9a3addfa5c496eab82d4537 SHA512 8679cc3afab77605b5e949e58cacb55782fca0ebc41991de7421b12fcd6c85991b6e4f5c70611753724ff47ea4eb39339ea4cea29e3f4e3399d9141fe4c80c7f
+DIST cinnamon-control-center-5.8.2.tar.gz 3820570 BLAKE2B 3bc009e696c7d469b2a2e15aecc62f290e26d08f65400418666e4a5564a3a113107996326e1edec93a45e9cb935ea96946e385376fe7f1b4b1185425bb4d4964 SHA512 b7b726659ca712a81c8b52bf514c8f061f5146a4728a3f2172ac5658b947e3e72c3194513ac815efaa727664e03ce2684d8d491bfcf0f6e91ea4566d832e86a2
diff --git a/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.8.2.ebuild b/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.8.2.ebuild
new file mode 100644
index 000000000000..dfa98300ab79
--- /dev/null
+++ b/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.8.2.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit meson gnome2-utils python-any-r1 xdg virtualx
+
+DESCRIPTION="Cinnamons's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-control-center"
+SRC_URI="https://github.com/linuxmint/cinnamon-control-center/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+IUSE="+colord input_devices_wacom +networkmanager +modemmanager gnome-online-accounts systemd test"
+REQUIRED_USE="modemmanager? ( networkmanager )"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+RESTRICT="test"
+
+COMMON_DEPEND="
+	app-accessibility/at-spi2-core:2
+	>=dev-libs/glib-2.44.0:2
+	>=gnome-base/libgnomekbd-3.0.0:0=
+	>=gnome-extra/cinnamon-desktop-5.8:0=
+	>=gnome-extra/cinnamon-menus-5.8
+	media-libs/fontconfig
+	>=sys-auth/polkit-0.103
+	>=sys-power/upower-0.99.8:=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=dev-libs/libgudev-232
+	>=x11-libs/libnotify-0.7.3
+	x11-libs/cairo
+	x11-libs/libX11
+	>=x11-libs/libxklavier-5.1:=
+	x11-libs/pango
+
+	colord? ( >=x11-misc/colord-0.1.14:0= )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7:=
+		>=x11-libs/libXi-1.2 )
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.2.0
+		>=net-libs/libnma-1.8.34
+		>=net-misc/networkmanager-1.2.0[modemmanager?]
+
+		modemmanager? ( >=net-misc/modemmanager-0.7:= )
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.18.0:=
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+
+	colord? ( >=gnome-extra/gnome-color-manager-3 )
+	input_devices_wacom? ( gnome-extra/cinnamon-settings-daemon[input_devices_wacom] )
+	systemd? ( >=sys-apps/systemd-31 )
+	!systemd? ( app-admin/openrc-settingsd )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-text/iso-codes
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang meson_install_schemas.py
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord color)
+		$(meson_use modemmanager)
+		$(meson_use networkmanager)
+		$(meson_use gnome-online-accounts onlineaccounts)
+		$(meson_use input_devices_wacom wacom)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}