games-rpg/kqlives: migrate to lua-single.eclass

Upstream autoconf scripts only looks for Lua 5.0 and 5.1 (in that order)
so only add lua5-1 to LUA_COMPAT.

Closes: https://bugs.gentoo.org/show_bug.cgi?id=752699
Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/games-rpg/kqlives/kqlives-0.99-r100.ebuild b/games-rpg/kqlives/kqlives-0.99-r100.ebuild
new file mode 100644
index 000000000000..30186ea2a594
--- /dev/null
+++ b/games-rpg/kqlives/kqlives-0.99-r100.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-1 )
+
+inherit autotools desktop lua-single
+
+MY_P=${P/lives}
+
+DESCRIPTION="A console-style role playing game"
+HOMEPAGE="http://kqlives.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cheats nls"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	>=gnome-base/libglade-2.4
+	media-libs/allegro:0
+	>=media-libs/dumb-2.0.3[allegro]
+	>=x11-libs/gtk+-2.8:2
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}/${P}_autoconf.patch"	# Fix #597790
+	"${FILESDIR}/${P}_dumb2.patch"		# >=media-libs/dumb-2.0.3 support
+	"${FILESDIR}/${P}_gcc10.patch"		# Fix #661422
+)
+
+src_prepare() {
+	default
+	mv debian/{kq,${PN}}.6 || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable cheats) \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+	doicon "${FILESDIR}"/${PN}.xpm
+	make_desktop_entry ${PN} KqLives ${PN}
+}