games-fps/prboom-plus: Bump to version 2.5.1.5.4540.1

The non-free USE flag is removed because non-free assets are no longer
provided in the source tarball. The png USE flag is removed since
sdl2-image provides that functionality now. The sdl-image and sdl-mixer
USE flags are renamed to sdl2-image and sdl2-mixer respectively to match
the use of the matching SDL2 libraries now.

Closes: https://bugs.gentoo.org/703610
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: William Breathitt Gray <vilhelm.gray@gmail.com>
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

4 files changed, 77 insertions, 75 deletions

diff --git a/games-fps/prboom-plus/Manifest b/games-fps/prboom-plus/Manifest
index 74314aab3b53..c1490c8fbdb3 100644
--- a/games-fps/prboom-plus/Manifest
+++ b/games-fps/prboom-plus/Manifest
@@ -1 +1 @@
-DIST prboom-plus-2.5.1.4.tar.gz 3007237 BLAKE2B 3dce8aad6fb521d13cf3e6b48a261f010b545bafa853860b284be0d0772f65b4fa0bfa965f7cb1869cc0d0eb21a4237e1873d08ff56d439cb3eed00f82bf12fb SHA512 625b75c5fe663bb3ba54bcd90f914ad7461c0860448f6f179180de26bea0a4d766739c50f96a8245687bc213742ec53bf6ffa26cde09772b3ae0bba91662213e
+DIST prboom-plus-2.5.1.5.4540.1.tar.xz 1023228 BLAKE2B 5b1c6aa80516cef4ced73701b640a261188c6eed818a204ef19f183061c0456f4af70dc8b466c240f5c8985903fe4daf0fed42cd32b47849c02b6c890fa807f0 SHA512 9fe207a395d92305dd3b89a38bc1376de6bd2a7bb29d454da42aea03a4ded82b49033d482d97c76377cbd1ecb7d8a65c9e0948af81ecd4e10bd49b0bad791bbc
diff --git a/games-fps/prboom-plus/metadata.xml b/games-fps/prboom-plus/metadata.xml
index 9ea5253b83db..555818481506 100644
--- a/games-fps/prboom-plus/metadata.xml
+++ b/games-fps/prboom-plus/metadata.xml
@@ -2,7 +2,15 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<longdescription lang="en">
-		PrBoom+ is a Doom source port developed from the original PrBoom project.
+		PrBoom+ is an enhanced source port of the classic 3D first-person
+		shooter game Doom, first released by id Software in 1993. It uses the
+		Simple Direct Media layer (SDL) library and features an optional OpenGL
+		renderer. It is based on PrBoom, MBF and LxDoom, which in turn are based
+		on TeamTNT's Boom, a freely available port of Doom for DOS.
+
+		In addition to PrBoom's features, PrBoom+ offers uncapped framerate,
+		variable gamespeed, re-record, walkcam, chasecam, full mouselook, FOV,
+		and other features without loss of compatibility with the original Doom.
 	</longdescription>
 	<maintainer type="person">
 		<email>vilhelm.gray@gmail.com</email>
@@ -20,14 +28,12 @@
 		<flag name="dumb">Enable support for various tracker-style music formats via <pkg>media-libs/dumb</pkg></flag>
 		<flag name="fluidsynth">Enable support for MIDI via <pkg>media-sound/fluidsynth</pkg></flag>
 		<flag name="net">Enable support for network play</flag>
-		<flag name="non-free">Enable non-free components</flag>
 		<flag name="portmidi">Enable support for MIDI via <pkg>media-libs/portmidi</pkg></flag>
-		<flag name="sdl-image">Enable support for high-resolution texture support via <pkg>media-libs/sdl-image</pkg></flag>
-		<flag name="sdl-mixer">Enable support for MIDI via <pkg>media-libs/sdl-mixer</pkg></flag>
+		<flag name="sdl2-image">Enable support for high-resolution texture support via <pkg>media-libs/sdl2-image</pkg></flag>
+		<flag name="sdl2-mixer">Enable support for MIDI via <pkg>media-libs/sdl2-mixer</pkg></flag>
 	</use>
 	<upstream>
-		<bugs-to>https://sourceforge.net/p/prboom-plus/bugs</bugs-to>
+		<bugs-to>https://bugs.debian.org/prboom-plus</bugs-to>
 		<doc lang="en">https://prboom-plus.sourceforge.net</doc>
-		<remote-id type="sourceforge">prboom-plus</remote-id>
 	</upstream>
 </pkgmetadata>
diff --git a/games-fps/prboom-plus/prboom-plus-2.5.1.4.ebuild b/games-fps/prboom-plus/prboom-plus-2.5.1.4.ebuild
deleted file mode 100644
index aab17006b4b1..000000000000
--- a/games-fps/prboom-plus/prboom-plus-2.5.1.4.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 2019-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools desktop xdg
-
-DESCRIPTION="A Doom source port developed from the original PrBoom project"
-HOMEPAGE="https://prboom-plus.sourceforge.net"
-# We are using a github mirror here because the upstream tarball is missing the
-# free dog assets; we should update SRC_URI to point to the upstream tarball
-# once the free assets are present as expected
-#SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
-SRC_URI="https://github.com/coelckers/prboom-plus/archive/f96f891d068dcc5ec52ed91056b46d27e9a8462d.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2+
-	non-free? ( freedist )
-	!non-free? ( BSD )"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="dumb fluidsynth mad net non-free +opengl pcre +png portmidi sdl-image +sdl-mixer vorbis"
-REQUIRED_USE="sdl-image? ( opengl )"
-
-DEPEND="
-	media-libs/libsdl[opengl?,joystick,sound,video]
-	dumb? ( media-libs/dumb )
-	fluidsynth? ( media-sound/fluidsynth:= )
-	mad? ( media-libs/libmad )
-	net? ( media-libs/sdl-net )
-	sdl-image? ( media-libs/sdl-image )
-	pcre? ( dev-libs/libpcre:3 )
-	png? ( media-libs/libpng:0= )
-	portmidi? ( media-libs/portmidi )
-	sdl-mixer? ( media-libs/sdl-mixer[midi] )
-	vorbis? ( media-libs/libvorbis )"
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/prboom-plus-f96f891d068dcc5ec52ed91056b46d27e9a8462d/prboom2"
-PATCHES="${FILESDIR}/${P}-Remove-nonstandard-gamesdir-variable.patch"
-
-src_prepare() {
-	xdg_src_prepare
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		--disable-cpu-opt \
-		$(use_enable non-free nonfree-graphics) \
-		$(use_enable opengl gl) \
-		$(use_with dumb) \
-		$(use_with fluidsynth) \
-		$(use_with mad) \
-		$(use_with net) \
-		$(use_with pcre) \
-		$(use_with png) \
-		$(use_with portmidi) \
-		$(use_with sdl-image image) \
-		$(use_with sdl-mixer mixer) \
-		$(use_with vorbis vorbisfile) \
-		--with-waddir="${EPREFIX}/usr/share/doom"
-}
-
-src_install() {
-	default
-	newicon ICONS/prboom-plus.svg ${PN}.svg
-	make_desktop_entry "${PN}" "PrBoom+"
-}
diff --git a/games-fps/prboom-plus/prboom-plus-2.5.1.5.4540.1.ebuild b/games-fps/prboom-plus/prboom-plus-2.5.1.5.4540.1.ebuild
new file mode 100644
index 000000000000..3e0833b7215c
--- /dev/null
+++ b/games-fps/prboom-plus/prboom-plus-2.5.1.5.4540.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg
+
+MY_PV=$(ver_rs 4 "+svn" 5 "+dfsg")
+MY_P=${PN}-${MY_PV}
+DESCRIPTION="An enhanced clone of the classic first-person shooter Doom"
+HOMEPAGE="https://prboom-plus.sourceforge.net"
+SRC_URI="http://deb.debian.org/debian/pool/main/p/prboom-plus/${PN}_${MY_PV}.orig.tar.xz -> ${P}.tar.xz"
+
+LICENSE="GPL-2+ BSD BSD-with-disclosure LGPL-2.1+ MIT public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dumb fluidsynth mad net +opengl +pcre portmidi sdl2-image +sdl2-mixer vorbis"
+REQUIRED_USE="sdl2-image? ( opengl )"
+
+DEPEND="
+	media-libs/libsdl2[opengl?,joystick,sound,video]
+	dumb? ( media-libs/dumb )
+	fluidsynth? ( media-sound/fluidsynth:= )
+	mad? ( media-libs/libmad )
+	net? ( media-libs/sdl2-net )
+	pcre? ( dev-libs/libpcre:3 )
+	portmidi? ( media-libs/portmidi )
+	sdl2-image? ( media-libs/sdl2-image )
+	sdl2-mixer? ( media-libs/sdl2-mixer[midi] )
+	vorbis? ( media-libs/libvorbis )"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}
+PATCHES=(
+	"${FILESDIR}/${PN}-2.5.1.4-Remove-nonstandard-gamesdir-variable.patch"
+)
+
+src_prepare() {
+	xdg_src_prepare
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-cpu-opt \
+		--disable-nonfree-graphics \
+		$(use_enable opengl gl) \
+		$(use_with dumb) \
+		$(use_with fluidsynth) \
+		$(use_with mad) \
+		$(use_with net) \
+		$(use_with pcre) \
+		$(use_with portmidi) \
+		$(use_with sdl2-image image) \
+		$(use_with sdl2-mixer mixer) \
+		$(use_with vorbis vorbisfile) \
+		--with-waddir="${EPREFIX}/usr/share/doom"
+}
+
+src_install() {
+	default
+	doicon ICONS/${PN}.svg
+	domenu ICONS/${PN}.desktop
+}