dev-vcs/mercurial: Version bumps to 5.2.2

Update also 9999

Closes: https://bugs.gentoo.org/701920
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Cédric Krier <cedk@gentoo.org>

6 files changed, 238 insertions, 58 deletions

diff --git a/dev-vcs/mercurial/Manifest b/dev-vcs/mercurial/Manifest
index 38d572328a69..c4c2fbabd1a3 100644
--- a/dev-vcs/mercurial/Manifest
+++ b/dev-vcs/mercurial/Manifest
@@ -3,3 +3,4 @@ DIST mercurial-4.9.1.tar.gz 7076867 BLAKE2B 8cedc66a8ddffc543a8849bbc98ebfc9ed61
 DIST mercurial-4.9.tar.gz 7075692 BLAKE2B ed11442e0cd5b27f47394ed1c15016930556d5cdc59ab18f1e0d5371e434eb752b68d3d9f6dd34ed9c63df62a646223e86c6c5178775d9b856eed5df65677900 SHA512 59a5467cebb51f17cce7bcada37f8d85906493ab2e3d443ceeae2c6598fb69d2d59f1e99c73bd08345c5f90501a7bae0d70e04c770ea7653ec30648e591c97fb
 DIST mercurial-5.0.2.tar.gz 7202797 BLAKE2B 7059efa2cf80c433ec25748c7c49ae0caa688363f5ef2983e0adf39a0a691ea99aaf4a090ebeda11b89e74263c548289cca3f82f40d77efbf925e12231b341cc SHA512 8b328e2e5a2896b690492d75c055bb13cd76df6efb087ef770f60ead86e30f7d952cb3ca82a696c0c5ce7039c319bd0fc9b448a52c079653622760317d5bb315
 DIST mercurial-5.1.2.tar.gz 7286238 BLAKE2B 0dcb2556e568e222da628bcfeceba56df8ab04f123f79add1953ce13bbf51e5cb0733fa72d5cff00250aaf0e3bfae5c52cc5cd72c1b6aa1fccb6820fce5a7018 SHA512 a8ce9d9220a5ddf452264801f06e81fe1e699ff700d085e3f82c6877910c6ef0e594203590f198b7b9e31c9a1ed627c8fa2a3a1513d0c5087cf775835a78c408
+DIST mercurial-5.2.2.tar.gz 7333065 BLAKE2B 9cec5a6ebe4693a1b96fe268211aa2eaa06643d5b8812c427757839d5389319f0e2ff3c1ed964a56bf8a3c46f7630321abf508c61691102856dfbdbd72fed662 SHA512 875e75587ab1f1c54edd2f7198dff21e6b287425f215a9d28ef98d5359420df90ca7ef0128ec7b772c4a31dc95b1082b4d6d28f1754968a08408516ba9ec91ee
diff --git a/dev-vcs/mercurial/files/zstd.py b/dev-vcs/mercurial/files/zstd.py
new file mode 100644
index 000000000000..29ae5eacd0cf
--- /dev/null
+++ b/dev-vcs/mercurial/files/zstd.py
@@ -0,0 +1,2 @@
+from zstd import *
+from zstd import __version__
diff --git a/dev-vcs/mercurial/mercurial-5.1.2.ebuild b/dev-vcs/mercurial/mercurial-5.1.2.ebuild
index c3f5137de8f6..7ae34dee8a9e 100644
--- a/dev-vcs/mercurial/mercurial-5.1.2.ebuild
+++ b/dev-vcs/mercurial/mercurial-5.1.2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -151,6 +151,9 @@ pkg_postinst() {
 	elog "  dev-vcs/git"
 	elog "  dev-vcs/monotone"
 	elog "  dev-vcs/subversion"
+
+	elog "If you want to use bugzilla extension"
+	elog "please install dev-python/mysqlclient"
 }
 
 pkg_postrm() {
diff --git a/dev-vcs/mercurial/mercurial-5.2.2.ebuild b/dev-vcs/mercurial/mercurial-5.2.2.ebuild
new file mode 100644
index 000000000000..339f1ec904c2
--- /dev/null
+++ b/dev-vcs/mercurial/mercurial-5.2.2.ebuild
@@ -0,0 +1,168 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_6 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit bash-completion-r1 elisp-common eutils distutils-r1 flag-o-matic
+
+DESCRIPTION="Scalable distributed SCM"
+HOMEPAGE="https://www.mercurial-scm.org/"
+SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+chg emacs gpg test tk zsh-completion"
+
+BROKEN_PYTHON="
+	!~dev-python/python-3.5.0
+	!~dev-python/python-3.5.1
+	!~dev-python/python-3.5.2
+	!~dev-python/python-3.6.0
+	!~dev-python/python-3.6.1"
+
+BDEPEND="${BROKEN_PYTHON}"
+
+RDEPEND="${BROKEN_PYTHON}
+	app-misc/ca-certificates
+	dev-python/zstandard[${PYTHON_USEDEP}]
+	gpg? ( app-crypt/gnupg )
+	tk? ( dev-lang/tk )
+	zsh-completion? ( app-shells/zsh )"
+
+DEPEND="emacs? ( >=app-editors/emacs-23.1:* )
+	test? ( app-arch/unzip
+		dev-python/pygments[${PYTHON_USEDEP}] )"
+
+SITEFILE="70${PN}-gentoo.el"
+
+# Too many tests fail #608720
+RESTRICT="test"
+
+python_prepare_all() {
+	# fix up logic that won't work in Gentoo Prefix (also won't outside in
+	# certain cases), bug #362891
+	sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+	cp "${FILESDIR}/zstd.py" mercurial/
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	strip-flags -ftracer -ftree-vectorize
+	python_is_python3 || append-flags -fno-strict-aliasing
+	distutils-r1_python_compile build_ext --no-zstd
+}
+
+python_compile_all() {
+	rm -r contrib/win32 || die
+	if use chg; then
+		emake -C contrib/chg
+	fi
+	if use emacs; then
+		cd contrib || die
+		elisp-compile mercurial.el || die "elisp-compile failed!"
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install build_ext --no-zstd
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newbashcomp contrib/bash_completion hg
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		newins contrib/zsh_completion _hg
+	fi
+
+	dobin hgeditor
+	if use tk; then
+		dobin contrib/hgk
+	fi
+	python_foreach_impl python_doscript contrib/hg-ssh
+
+	if use emacs; then
+		elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+	fi
+
+	local RM_CONTRIB=( hgk hg-ssh bash_completion zsh_completion plan9 *.el )
+
+	if use chg; then
+		dobin contrib/chg/chg
+		doman contrib/chg/chg.1
+		RM_CONTRIB+=( chg )
+	fi
+
+	for f in ${RM_CONTRIB[@]}; do
+		rm -rf contrib/${f} || die
+	done
+
+	dodoc -r contrib
+	docompress -x /usr/share/doc/${PF}/contrib
+	doman doc/*.?
+	dodoc CONTRIBUTORS hgweb.cgi
+
+	insinto /etc/mercurial/hgrc.d
+	doins "${FILESDIR}/cacerts.rc"
+}
+
+src_test() {
+	pushd tests &>/dev/null || die
+	rm -rf *svn*			# Subversion tests fail with 1.5
+	rm -f test-archive*		# Fails due to verbose tar output changes
+	rm -f test-convert-baz*		# GNU Arch baz
+	rm -f test-convert-cvs*		# CVS
+	rm -f test-convert-darcs*	# Darcs
+	rm -f test-convert-git*		# git
+	rm -f test-convert-mtn*		# monotone
+	rm -f test-convert-tla*		# GNU Arch tla
+	rm -f test-largefiles*		# tends to time out
+	if [[ ${EUID} -eq 0 ]]; then
+		einfo "Removing tests which require user privileges to succeed"
+		rm -f test-convert*
+		rm -f test-lock-badness*
+		rm -f test-permissions*
+		rm -f test-pull-permission*
+		rm -f test-journal-exists*
+		rm -f test-repair-strip*
+	fi
+
+	popd &>/dev/null || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local TEST_DIR
+
+	rm -rf "${TMPDIR}"/test
+	distutils_install_for_testing
+	cd tests || die
+	"${PYTHON}" run-tests.py --verbose \
+		--tmpdir="${TMPDIR}"/test \
+		--with-hg="${TEST_DIR}"/scripts/hg \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+
+	elog "If you want to convert repositories from other tools using convert"
+	elog "extension please install correct tool:"
+	elog "  dev-vcs/cvs"
+	elog "  dev-vcs/darcs"
+	elog "  dev-vcs/git"
+	elog "  dev-vcs/monotone"
+	elog "  dev-vcs/subversion"
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/dev-vcs/mercurial/mercurial-9999.ebuild b/dev-vcs/mercurial/mercurial-9999.ebuild
index 4715bed5111f..9c47a383e79e 100644
--- a/dev-vcs/mercurial/mercurial-9999.ebuild
+++ b/dev-vcs/mercurial/mercurial-9999.ebuild
@@ -1,32 +1,42 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="threads"
+PYTHON_COMPAT=( python2_7 python3_{6..7} )
+PYTHON_REQ_USE="threads(+)"
 
 inherit bash-completion-r1 elisp-common eutils distutils-r1 mercurial flag-o-matic
 
 DESCRIPTION="Scalable distributed SCM"
 HOMEPAGE="https://www.mercurial-scm.org/"
-EHG_REPO_URI="http://selenic.com/repo/hg"
-EHG_REVISION="@"
+EHG_REPO_URI="https://www.mercurial-scm.org/repo/hg"
 
 LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS=""
 IUSE="+chg bugzilla emacs gpg test tk zsh-completion"
 
-RDEPEND="bugzilla? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+BROKEN_PYTHON="
+	!~dev-python/python-3.5.0
+	!~dev-python/python-3.5.1
+	!~dev-python/python-3.5.2
+	!~dev-python/python-3.6.0
+	!~dev-python/python-3.6.1"
+
+BDEPEND="${BROKEN_PYTHON}
+	dev-python/docutils[${PYTHON_USEDEP}]"
+
+RDEPEND="${BROKEN_PYTHON}
+	app-misc/ca-certificates
+	dev-python/zstandard[${PYTHON_USEDEP}]
 	gpg? ( app-crypt/gnupg )
 	tk? ( dev-lang/tk )
-	zsh-completion? ( app-shells/zsh )
-	app-misc/ca-certificates"
+	zsh-completion? ( app-shells/zsh )"
+
 DEPEND="emacs? ( >=app-editors/emacs-23.1:* )
 	test? ( app-arch/unzip
-		dev-python/pygments[${PYTHON_USEDEP}] )
-	dev-python/docutils[${PYTHON_USEDEP}]"
+		dev-python/pygments[${PYTHON_USEDEP}] )"
 
 SITEFILE="70${PN}-gentoo.el"
 
@@ -37,20 +47,20 @@ python_prepare_all() {
 	# fix up logic that won't work in Gentoo Prefix (also won't outside in
 	# certain cases), bug #362891
 	sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+	sed -i -e '/    hgenv =/a\' -e '    hgenv.pop("PYTHONPATH", None)' setup.py || die
+	cp "${FILESDIR}/zstd.py" mercurial/
 
 	distutils-r1_python_prepare_all
 }
 
-python_configure_all() {
+python_compile() {
 	strip-flags -ftracer -ftree-vectorize
-	# Note: make it impl-conditional if py3 is supported
-	append-flags -fno-strict-aliasing
-
-	"${PYTHON}" setup.py build_mo || die
+	python_is_python3 || append-flags -fno-strict-aliasing
+	distutils-r1_python_compile build_ext --no-zstd
 }
 
 python_compile_all() {
-	rm -r contrib/{win32,macosx} || die
+	rm -r contrib/win32 || die
 	emake doc
 	if use chg; then
 		emake -C contrib/chg
@@ -61,6 +71,10 @@ python_compile_all() {
 	fi
 }
 
+python_install() {
+	distutils-r1_python_install build_ext --no-zstd
+}
+
 python_install_all() {
 	distutils-r1_python_install_all
 
@@ -71,12 +85,10 @@ python_install_all() {
 		newins contrib/zsh_completion _hg
 	fi
 
-	rm -f doc/*.?.txt || die
-	dodoc CONTRIBUTORS doc/*.txt
-	cp hgweb*.cgi "${ED}"/usr/share/doc/${PF}/ || die
-
 	dobin hgeditor
-	dobin contrib/hgk
+	if use tk; then
+		dobin contrib/hgk
+	fi
 	python_foreach_impl python_doscript contrib/hg-ssh
 
 	if use emacs; then
@@ -84,8 +96,7 @@ python_install_all() {
 		elisp-site-file-install "${FILESDIR}"/${SITEFILE}
 	fi
 
-	local RM_CONTRIB=(hgk hg-ssh bash_completion zsh_completion wix buildrpm plan9
-	                  *.el mercurial.spec)
+	local RM_CONTRIB=( hgk hg-ssh bash_completion zsh_completion plan9 *.el )
 
 	if use chg; then
 		dobin contrib/chg/chg
@@ -94,47 +105,40 @@ python_install_all() {
 	fi
 
 	for f in ${RM_CONTRIB[@]}; do
-		rm -rf contrib/$f || die
+		rm -rf contrib/${f} || die
 	done
 
 	dodoc -r contrib
 	docompress -x /usr/share/doc/${PF}/contrib
 	doman doc/*.?
-
-	cat > "${T}/80mercurial" <<-EOF
-HG="${EPREFIX}/usr/bin/hg"
-EOF
-	doenvd "${T}/80mercurial"
+	dodoc CONTRIBUTORS hgweb.cgi
 
 	insinto /etc/mercurial/hgrc.d
 	doins "${FILESDIR}/cacerts.rc"
 }
 
 src_test() {
-	cd tests || die
-	rm -rf *svn* || die					# Subversion tests fail with 1.5
-	rm -f test-archive* || die			# Fails due to verbose tar output changes
-	rm -f test-convert-baz* || die		# GNU Arch baz
-	rm -f test-convert-cvs* || die		# CVS
-	rm -f test-convert-darcs* || die	# Darcs
-	rm -f test-convert-git* || die		# git
-	rm -f test-convert-mtn* || die		# monotone
-	rm -f test-convert-tla* || die		# GNU Arch tla
-	rm -f test-doctest* || die			# doctest always fails with python 2.5.x
-	rm -f test-largefiles* || die		# tends to time out
+	pushd tests &>/dev/null || die
+	rm -rf *svn*			# Subversion tests fail with 1.5
+	rm -f test-archive*		# Fails due to verbose tar output changes
+	rm -f test-convert-baz*		# GNU Arch baz
+	rm -f test-convert-cvs*		# CVS
+	rm -f test-convert-darcs*	# Darcs
+	rm -f test-convert-git*		# git
+	rm -f test-convert-mtn*		# monotone
+	rm -f test-convert-tla*		# GNU Arch tla
+	rm -f test-largefiles*		# tends to time out
 	if [[ ${EUID} -eq 0 ]]; then
 		einfo "Removing tests which require user privileges to succeed"
-		rm -f test-command-template* || die	# Test is broken when run as root
-		rm -f test-convert* || die			# Test is broken when run as root
-		rm -f test-lock-badness* || die		# Test is broken when run as root
-		rm -f test-permissions* || die		# Test is broken when run as root
-		rm -f test-pull-permission* || die	# Test is broken when run as root
-		rm -f test-clone-failure* || die
-		rm -f test-journal-exists* || die
-		rm -f test-repair-strip* || die
+		rm -f test-convert*
+		rm -f test-lock-badness*
+		rm -f test-permissions*
+		rm -f test-pull-permission*
+		rm -f test-journal-exists*
+		rm -f test-repair-strip*
 	fi
 
-	cd .. || die
+	popd &>/dev/null || die
 	distutils-r1_src_test
 }
 
diff --git a/dev-vcs/mercurial/metadata.xml b/dev-vcs/mercurial/metadata.xml
index 37d1b32ccb33..691021c6b56f 100644
--- a/dev-vcs/mercurial/metadata.xml
+++ b/dev-vcs/mercurial/metadata.xml
@@ -1,11 +1,13 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <!-- maintainer-needed -->
-  <use>
-    <flag name="chg">Support Mercurial command server client</flag>
-    <flag name="bugzilla">Support bugzilla integration.</flag>
-    <flag name="gpg">Support signing with GnuPG.</flag>
-    <flag name="tk">Install dev-lang/tk for hgk script.</flag>
-  </use>
+	<maintainer type="person">
+		<email>cedk@gentoo.org</email>
+	</maintainer>
+	<use>
+		<flag name="chg">Support Mercurial command server client</flag>
+		<flag name="bugzilla">Support bugzilla integration.</flag>
+		<flag name="gpg">Support signing with GnuPG.</flag>
+		<flag name="tk">Install dev-lang/tk for hgk script.</flag>
+	</use>
 </pkgmetadata>