dev-qt/qtmultimedia: 5.15.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-qt/qtmultimedia/Manifest b/dev-qt/qtmultimedia/Manifest
index 0e636b8cdee4..61b9b8dd7b65 100644
--- a/dev-qt/qtmultimedia/Manifest
+++ b/dev-qt/qtmultimedia/Manifest
@@ -1,2 +1,4 @@
 DIST qtmultimedia-5.15.4-gentoo-kde-1.tar.xz 1324 BLAKE2B 8080e8f35ae0dab394bac10b9e4db8ff1afdd98cd91cd0a513873bf78b675a69af908e7a6c1adc7a9f75176a3a1901d66c15ca56c7c631bcf69318c3ba0e235c SHA512 414874aedfeaa1abc2da4440c404cd26364de5de060b8c148d7883122abe82d47bc8c013ca5fcf9f6c0d8cd98d686ebcd100da6b945bcd530a5511c376cd2051
+DIST qtmultimedia-5.15.5-gentoo-kde-1.tar.xz 1324 BLAKE2B d29d8102e6fd55f2c2f6037e292a3c4039c7532fb63c34cc19fbedc8cf3f8082c6d75debd1617a5d29fcdf5b8c7a7fef35f103c9179f980986b646dae9ff867b SHA512 7b37f0db1de002f2cbaad6852edcf772dd0220f81d9dd836b3c1266df7eb49ec40d3eba6d3ccaf68f621c8e93b2812e2d882291fb2f07d0b80e4c9975a408cdc
 DIST qtmultimedia-everywhere-opensource-src-5.15.4.tar.xz 3833720 BLAKE2B bd381125280527eee7b5cec117c3d4c64ce2000b459effc1d912e5209d57bd88baf547967d61eefc94adf3f8aa85e3caf010b7ca9f7551b29182a90f483c5cfd SHA512 bb0ada7560093b89751b5b3c0e1a573de215a388d621d356bc3c0e1acfffc2d696230c67b7a7cef037b18c4da900c7eb3d315bd2e73ce12f9aedd0e340399117
+DIST qtmultimedia-everywhere-opensource-src-5.15.5.tar.xz 3832656 BLAKE2B 6098fe14344ed03dbfcbb2db429c431a47282bbbb89602742be2fe44ef063ceb98322bb576eeb559a649b24f142cd5e21b652fed8c96814b8e3b8b0a66b51fe9 SHA512 f798ffe0a32bc9f16f584b7a322c321dc2ef62c18395987ffce1f7f6cac10722c6f1166c64a1fda9877f3970a8e7b3ef8b7d9763af4c59ff313adc6081a7acfb
diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.15.5.ebuild b/dev-qt/qtmultimedia/qtmultimedia-5.15.5.ebuild
new file mode 100644
index 000000000000..e443245ca92e
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-5.15.5.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QT5_KDEPATCHSET_REV=1
+inherit qt5-build
+
+DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+IUSE="alsa gles2-only gstreamer openal pulseaudio qml widgets"
+
+RDEPEND="
+	=dev-qt/qtcore-${QT5_PV}*
+	=dev-qt/qtgui-${QT5_PV}*[gles2-only=]
+	=dev-qt/qtnetwork-${QT5_PV}*
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	pulseaudio? ( media-sound/pulseaudio[glib] )
+	qml? (
+		=dev-qt/qtdeclarative-${QT5_PV}*
+		gles2-only? ( =dev-qt/qtgui-${QT5_PV}*[egl] )
+		openal? ( media-libs/openal )
+	)
+	widgets? (
+		=dev-qt/qtwidgets-${QT5_PV}*[gles2-only=]
+		media-libs/libglvnd
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.15.2-no-qtopengl.patch" )
+
+src_prepare() {
+	sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
+		src/multimedia/multimedia.pro || die
+
+	qt_use_disable_config openal openal \
+		src/imports/imports.pro
+
+	qt_use_disable_mod qml quick \
+		src/src.pro \
+		src/plugins/plugins.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/gsttools/gsttools.pro \
+		src/plugins/gstreamer/common.pri
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		$(qt_use alsa)
+		$(qt_use gstreamer)
+		$(qt_use pulseaudio)
+	)
+	qt5-build_src_configure
+}