dev-python/trio: add 0.23.1

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 77 insertions, 0 deletions

diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index 04ce3c5edd4b..16e68b5c9c1b 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1,2 +1,3 @@
 DIST trio-0.22.2.gh.tar.gz 536949 BLAKE2B f469f306d826d110defabf14956bdfe390a0f36da16da7e6e0426573cc9faf8943514b67a22fa44463c35f1e02c61c4aa3fd8da6bc408339a77367953fc62be0 SHA512 c3f08b8a1a37c0a06e520c7c5cf6ab5ffa2366c0e8599ae831e896e79bb144ee13ea426c8e6d8278f4620eae15c3c3af6c46c8b4526147336e30050bbf111120
 DIST trio-0.23.0.gh.tar.gz 585629 BLAKE2B e8d3432dd199cf6f4fa174a92696e08d0ff2a75d783ec65c217a8049cba1132821503f783b85a89f629ca39b9278711af76df5431cd14ba319fc8654585a16cc SHA512 01fab7447f7e8cde3223077ef45a788d67df8348a44325c72209f14b48f4c8510de17fc88e8c02921568274907e79599061894a12987db76e33f84dd040c5e81
+DIST trio-0.23.1.gh.tar.gz 585734 BLAKE2B 07a03f9ddd26f4e69bda651bc0821bb02895a244400cc5ec829b82e027304722248f7cf608bad8afb928e54736034349d736ca1aaa40b470cbbc3c1a74e3c77c SHA512 e7348cefb364689060c32987120c50081c677531fb4082a68956c431112b9966af6db09ebdca036980af660e48c2bc8addd05b58d62678d45ed7ffa1ce862dcc
diff --git a/dev-python/trio/trio-0.23.1.ebuild b/dev-python/trio/trio-0.23.1.ebuild
new file mode 100644
index 000000000000..4704db8dd458
--- /dev/null
+++ b/dev-python/trio/trio-0.23.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc9[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/immutables \
+	dev-python/sphinxcontrib-trio \
+	dev-python/sphinx-rtd-theme \
+	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# these tests require internet access
+		trio/tests/test_ssl.py
+		trio/tests/test_highlevel_ssl_helpers.py
+		# requires isort
+		trio/_tests/tools/test_gen_exports.py
+	)
+
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		trio/tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+
+		# incompatible ipython version?
+		trio/_core/tests/test_multierror.py::test_ipython_exc_handler
+	)
+	if [[ ${EPYTHON} == python3.12 ]]; then
+		EPYTEST_DESELECT+=(
+			trio/_core/_tests/test_run.py::test_nursery_cancel_doesnt_create_cyclic_garbage
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p trio._tests.pytest_plugin -m "not redistributors_should_skip"
+}