dev-python/flask-script: rev-bump for EAPI 6 bump, py-3.5 support and simplified docs generation

Package-Manager: portage-2.3.0

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/flask-script/flask-script-2.0.5-r1.ebuild b/dev-python/flask-script/flask-script-2.0.5-r1.ebuild
new file mode 100644
index 000000000000..ca9038816fba
--- /dev/null
+++ b/dev-python/flask-script/flask-script-2.0.5-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-Script"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Flask support for writing external scripts"
+HOMEPAGE="http://packages.python.org/Flask-Script/ https://pypi.python.org/pypi/Flask-Script"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/flask-0.10.1-r1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test tests.py || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}