dev-python/ipykernel: Bump to 6.25.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 0347746d957c..8395f902cba2 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1 +1,2 @@
 DIST ipykernel-6.24.0.tar.gz 154452 BLAKE2B d9ff81dd2f4cc989fd8356d3f02451158dde49fd83076fd7fa42f002b095cc87f296f2deb34fdc1becbbc0391385466dc21d167ab22167a0bd6d1d561bb19427 SHA512 555ed0d6df7a4d82bb5db63718c320e1628b8d5691e831eae041ac78400be6935793b258c219815fd070cbad29e869897111add6958308db55ea03843a536393
+DIST ipykernel-6.25.0.tar.gz 155658 BLAKE2B f14afaf28ec82473fa0b7c33a281ebd91fd5d93b0e00bd838046b8f591f12bca64fed8514e97ce59ba20b78940bdd7afad93ef9a59656795de97e80ff46e8339 SHA512 7cd2d3cbb2c83ca165798dc830aae096ce3391535ef604f257c4c79357ebd1c7f7e95c6952e1fb95d1a460ccb5b1bf88396f984b6462986b3e73a4453dd33b52
diff --git a/dev-python/ipykernel/ipykernel-6.25.0.ebuild b/dev-python/ipykernel/ipykernel-6.25.0.ebuild
new file mode 100644
index 000000000000..e5ef5178d17a
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.25.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-20[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		ipykernel/tests/test_debugger.py::test_attach_debug
+		ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+		ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_set_breakpoints
+		ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+		ipykernel/tests/test_debugger.py::test_copy_to_globals
+		# hangs?
+		ipykernel/tests/test_eventloop.py::test_tk_loop
+		# doesn't like pyside2?
+		ipykernel/tests/test_eventloop.py::test_qt_enable_gui
+	)
+
+	virtx distutils-r1_src_test
+}