dev-python/hatchling: Bump to 1.3.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index 0e99c9cad0f1..657c2ff33ef5 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -3,3 +3,4 @@ DIST hatch-hatchling-v0.25.0.tar.gz 216944 BLAKE2B 298f284bc05bbba6c463d4c22ddbb
 DIST hatch-hatchling-v1.0.0.tar.gz 216365 BLAKE2B cb6b648d103c7e9848b1a15cd62aaf3ab39c458f83f6c56cf039a136b39ae6c59ba487c36860582f98fb1ede6b3c2dab148b023499b5e4a30de9d063379118c3 SHA512 e16b0c53705fe090713f40d661e4ac9a4d0c2ae22f9193fcbaa1eb4ba146a36642b5e188574ad00b6ddd06c60537db0eba18fe9f2676cc988effc9d74e0dffc4
 DIST hatch-hatchling-v1.1.0.tar.gz 216865 BLAKE2B 82d168d518b84c26033d81002b22eb347a2b0c2abb26b79ef4aacaa3804924348e090c4d87b728e80a30bfacf7d8634be6c6f35d3cfcb95fd9e1ff50d35d4595 SHA512 062773f8f1d472602ba589022ec56a7d3dc4068ae66ec5e773912a793524649f73effe7b61c76f5a1cf6b264d2499d8d8660efcc0189f9bbbf60b4b948740dc5
 DIST hatch-hatchling-v1.2.0.tar.gz 216988 BLAKE2B b8f0fd0286075bb58e3ae875232c35cc5307582930ce03e8564c818d95f96be13f8bfbda950fe14257ab639b87a58fdd9f13fd5f024b70b5d16d12242a7ddeb4 SHA512 08bbaf8a9315d8e5a69ff09bf3121d9fdc7559e214c25203b61248e8c09b283076e3235261194cabc135f1eb0d6fa3ad1a9c1c9e02de45bcb7d9f3515b4246f6
+DIST hatch-hatchling-v1.3.0.tar.gz 219864 BLAKE2B 146c839cb41f32f2afadbb17816ec9171755b62bacaf59dd96e33d1105d8fe104a98baf7ff54f3bd296e4c0dcceb72dd42d54c7676946f41fd49bbfa6ba505de SHA512 03caa35a05332f55ac235a87d9549c201a564896cb409625efdfd25fee8a0c110a753bafcc93da1c602752bb965b599e81e8106d24a26503abb01a8f90457aed
diff --git a/dev-python/hatchling/hatchling-1.3.0.ebuild b/dev-python/hatchling/hatchling-1.3.0.ebuild
new file mode 100644
index 000000000000..2f99efcc7213
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.3.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{8..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/editables-0.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	epytest tests/backend
+}