dev-libs/ktextaddons: Add missing dependency

Upstream commit e34f4809e67bbad3f261f78a1455bbdaaf424e83

Closes: https://bugs.gentoo.org/904435
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-libs/ktextaddons/ktextaddons-1.1.1-r1.ebuild b/dev-libs/ktextaddons/ktextaddons-1.1.1-r1.ebuild
new file mode 100644
index 000000000000..f557b3280eaa
--- /dev/null
+++ b/dev-libs/ktextaddons/ktextaddons-1.1.1-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_DESIGNERPLUGIN="true"
+ECM_QTHELP="true"
+ECM_TEST="true"
+KFMIN=5.103.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Various text handling addons"
+HOMEPAGE="https://invent.kde.org/libraries/ktextaddons"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-2+"
+SLOT="5"
+IUSE="speech"
+
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/qtkeychain:=[qt5(+)]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package speech Qt5TextToSpeech)
+	)
+	ecm_src_configure
+}