dev-db/sqlitebrowser: revbump

Closes: https://bugs.gentoo.org/855254
Closes: https://bugs.gentoo.org/913047
Signed-off-by: Mattéo Rossillol‑‑Laruelle <beatussum@protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/34420
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 89 insertions, 4 deletions

diff --git a/dev-db/sqlitebrowser/metadata.xml b/dev-db/sqlitebrowser/metadata.xml
index ed00998feb6b..1347829179ac 100644
--- a/dev-db/sqlitebrowser/metadata.xml
+++ b/dev-db/sqlitebrowser/metadata.xml
@@ -26,6 +26,12 @@
 		d'un tableur, et, de ce fait, ne pas être contraint à apprendre des
 		commandes SQL complexes.
 	</longdescription>
+	<use>
+		<flag name="sqlcipher">Allow to open and to edit databases encrypted using <pkg>dev-db/sqlcipher</pkg></flag>
+	</use>
+	<use lang="fr">
+		<flag name="sqlcipher">Permettre d'ouvrir et d'éditer des bases de données chiffrées en utilisant <pkg>dev-db/sqlcipher</pkg></flag>
+	</use>
 	<upstream>
 		<bugs-to>https://github.com/sqlitebrowser/sqlitebrowser/issues/</bugs-to>
 		<remote-id type="github">sqlitebrowser/sqlitebrowser</remote-id>
diff --git a/dev-db/sqlitebrowser/sqlitebrowser-3.12.2-r1.ebuild b/dev-db/sqlitebrowser/sqlitebrowser-3.12.2-r1.ebuild
new file mode 100644
index 000000000000..cea98af250c9
--- /dev/null
+++ b/dev-db/sqlitebrowser/sqlitebrowser-3.12.2-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="A light GUI editor for SQLite databases"
+HOMEPAGE="https://sqlitebrowser.org/"
+
+if [[ "${PV}" = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+ MPL-2.0"
+SLOT="0"
+IUSE="sqlcipher test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-editors/qhexedit2
+	dev-db/sqlite:3
+	dev-libs/qcustomplot
+	>=dev-qt/qtconcurrent-5.5:5
+	>=dev-qt/qtcore-5.5:5
+	>=dev-qt/qtgui-5.5:5
+	>=dev-qt/qtnetwork-5.5:5[ssl]
+	>=dev-qt/qtprintsupport-5.5:5
+	>=dev-qt/qtwidgets-5.5:5
+	>=dev-qt/qtxml-5.5:5
+	>=x11-libs/qscintilla-2.8.10:=
+	sqlcipher? ( dev-db/sqlcipher )
+"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.5:5
+	test? ( >=dev-qt/qttest-5.5:5 )
+"
+
+RDEPEND="
+	${DEPEND}
+	>=dev-qt/qtsvg-5.5:5
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	if ! use test; then
+		sed -i CMakeLists.txt \
+			-e "/find_package/ s/ Test//" \
+			-e "/set/ s/ Qt5::Test//" \
+			|| die "Cannot remove Qt Test from CMake dependencies"
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_TESTING=$(usex test)
+		-DFORCE_INTERNAL_QCUSTOMPLOT=OFF
+		-DFORCE_INTERNAL_QHEXEDIT=OFF
+		-Dsqlcipher=$(usex sqlcipher)
+	)
+
+	# https://bugs.gentoo.org/855254
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	cmake_src_configure
+}
diff --git a/dev-db/sqlitebrowser/sqlitebrowser-9999.ebuild b/dev-db/sqlitebrowser/sqlitebrowser-9999.ebuild
index d094723adf0a..cea98af250c9 100644
--- a/dev-db/sqlitebrowser/sqlitebrowser-9999.ebuild
+++ b/dev-db/sqlitebrowser/sqlitebrowser-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit cmake xdg
+inherit cmake flag-o-matic xdg
 
 DESCRIPTION="A light GUI editor for SQLite databases"
 HOMEPAGE="https://sqlitebrowser.org/"
@@ -18,7 +18,7 @@ fi
 
 LICENSE="GPL-3+ MPL-2.0"
 SLOT="0"
-IUSE="test"
+IUSE="sqlcipher test"
 RESTRICT="!test? ( test )"
 
 DEPEND="
@@ -33,6 +33,7 @@ DEPEND="
 	>=dev-qt/qtwidgets-5.5:5
 	>=dev-qt/qtxml-5.5:5
 	>=x11-libs/qscintilla-2.8.10:=
+	sqlcipher? ( dev-db/sqlcipher )
 "
 
 BDEPEND="
@@ -61,7 +62,12 @@ src_configure() {
 		-DENABLE_TESTING=$(usex test)
 		-DFORCE_INTERNAL_QCUSTOMPLOT=OFF
 		-DFORCE_INTERNAL_QHEXEDIT=OFF
+		-Dsqlcipher=$(usex sqlcipher)
 	)
 
+	# https://bugs.gentoo.org/855254
+	append-flags -fno-strict-aliasing
+	filter-lto
+
 	cmake_src_configure
 }