dev-db/pg_activity: version bump to 3.5.0

Signed-off-by: Agostino Sarubbo <ago@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-db/pg_activity/pg_activity-3.5.0.ebuild b/dev-db/pg_activity/pg_activity-3.5.0.ebuild
new file mode 100644
index 000000000000..778d01d26dde
--- /dev/null
+++ b/dev-db/pg_activity/pg_activity-3.5.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Realtime PostgreSQL database server monitoring tool"
+HOMEPAGE="https://github.com/dalibo/pg_activity"
+SRC_URI="https://github.com/dalibo/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+SLOT="0"
+LICENSE="POSTGRESQL"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/blessed[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/psycopg:0[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# https://github.com/dalibo/pg_activity/issues/201
+	export COLUMNS="80"
+	epytest -k 'not test_ui.txt and not test_data.py'
+}
+
+src_install() {
+	distutils-r1_src_install
+	doman docs/man/${PN}.1
+}