app-i18n/imhangul: tidy

Package-Manager: Portage-2.3.40, Repoman-2.3.9

3 files changed, 76 insertions, 105 deletions

diff --git a/app-i18n/imhangul/imhangul-2.1.0-r1.ebuild b/app-i18n/imhangul/imhangul-2.1.0-r1.ebuild
new file mode 100644
index 000000000000..5f32412487aa
--- /dev/null
+++ b/app-i18n/imhangul/imhangul-2.1.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit gnome2-utils
+
+DESCRIPTION="GTK+ 2 Hangul Input Modules"
+HOMEPAGE="https://code.google.com/p/imhangul/"
+SRC_URI="https://imhangul.googlecode.com/files/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+IUSE=""
+
+RDEPEND="app-i18n/libhangul
+	x11-libs/gtk+:2
+	virtual/libintl"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+src_prepare() {
+	default
+	gnome2_environment_reset
+	gnome2_disable_deprecation_warning
+}
+
+src_configure() {
+	econf --with-gtk-im-module-dir="${EPREFIX%/}"/usr/$(get_libdir)/gtk-2.0/$(pkg-config gtk+-2.0 --variable=gtk_binary_version)/immodules
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+	dodoc ${PN}.conf
+
+	local s
+	insinto /etc/X11/xinit/xinput.d
+	for s in 2{,y} 3{2,9,f,s,y} ahn ro; do
+		newins "${FILESDIR}"/xinput-${PN}${s} ${PN}${s}.conf
+	done
+}
+
+pkg_postinst() {
+	gnome2_query_immodules_gtk2
+	elog
+	elog "If you want to use one of the module as a default input method, "
+	elog
+	elog "export GTK_IM_MODULE=hangul2  # 2 input type"
+	elog "export GTK_IM_MODULE=hangul3f # 3 input type"
+	elog
+}
+
+pkg_postrm() {
+	gnome2_query_immodules_gtk2
+}
diff --git a/app-i18n/imhangul/imhangul-2.1.0.ebuild b/app-i18n/imhangul/imhangul-2.1.0.ebuild
deleted file mode 100644
index 5503848cb8b8..000000000000
--- a/app-i18n/imhangul/imhangul-2.1.0.ebuild
+++ /dev/null
@@ -1,82 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit gnome2-utils multilib readme.gentoo-r1
-
-DESCRIPTION="Gtk+-2.0 Hangul Input Modules"
-HOMEPAGE="https://code.google.com/p/imhangul/"
-SRC_URI="https://imhangul.googlecode.com/files/${P}.tar.bz2"
-
-SLOT="0"
-LICENSE="LGPL-2.1"
-KEYWORDS="amd64 ppc x86"
-IUSE=""
-
-RDEPEND="
-	>=app-i18n/libhangul-0.0.12
-	>=x11-libs/gtk+-2.2:2
-	virtual/libintl
-"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	sys-devel/gettext
-"
-
-DISABLE_AUTOFORMATTING="yes"
-DOC_CONTENTS="
-If you want to use one of the module as a default input method,
-
-export GTK_IM_MODULE=hangul2  # 2 input type
-export GTK_IM_MODULE=hangul3f # 3 input type
-"
-
-get_gtk_confdir() {
-	# bug #366889
-	if has_version '>=x11-libs/gtk+-2.22.1-r1:2' || has_multilib_profile ; then
-		GTK2_CONFDIR="${GTK2_CONFDIR:=${EPREFIX}/etc/gtk-2.0/$(get_abi_CHOST)}"
-	else
-		GTK2_CONFDIR="${GTK2_CONFDIR:=${EPREFIX}/etc/gtk-2.0}"
-	fi
-	echo ${GTK2_CONFDIR}
-}
-
-src_prepare() {
-	default
-	gnome2_environment_reset
-	gnome2_disable_deprecation_warning
-}
-
-src_configure() {
-	econf \
-		--with-gtk-im-module-dir="${EPREFIX}/usr/$(get_libdir)/gtk-2.0/immodules" \
-		--with-gtk-im-module-file="$(get_gtk_confdir)"
-}
-
-src_install() {
-	default
-	prune_libtool_files --modules
-
-	insinto /etc/X11/xinit/xinput.d
-	newins "${FILESDIR}/xinput-imhangul2" imhangul2.conf
-	newins "${FILESDIR}/xinput-imhangul2y" imhangul2y.conf
-	newins "${FILESDIR}/xinput-imhangul32" imhangul32.conf
-	newins "${FILESDIR}/xinput-imhangul39" imhangul39.conf
-	newins "${FILESDIR}/xinput-imhangul3f" imhangul3f.conf
-	newins "${FILESDIR}/xinput-imhangul3s" imhangul3s.conf
-	newins "${FILESDIR}/xinput-imhangul3y" imhangul3y.conf
-	newins "${FILESDIR}/xinput-imhangulahn" imhangulahn.conf
-	newins "${FILESDIR}/xinput-imhangulro" imhangulro.conf
-
-	dodoc imhangul.conf
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	gnome2_query_immodules_gtk2
-	readme.gentoo_print_elog
-}
-
-pkg_postrm() {
-	gnome2_query_immodules_gtk2
-}
diff --git a/app-i18n/imhangul/imhangul-3.1.1.ebuild b/app-i18n/imhangul/imhangul-3.1.1.ebuild
index 1cebdc2d5fc8..e99ca8ce861d 100644
--- a/app-i18n/imhangul/imhangul-3.1.1.ebuild
+++ b/app-i18n/imhangul/imhangul-3.1.1.ebuild
@@ -1,9 +1,11 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI="6"
 
-DESCRIPTION="Gtk+-3.0 Hangul Input Modules"
+inherit gnome2-utils
+
+DESCRIPTION="GTK+ 3 Hangul Input Modules"
 HOMEPAGE="https://code.google.com/p/imhangul/"
 SRC_URI="https://imhangul.googlecode.com/files/${P}.tar.bz2"
 
@@ -12,7 +14,7 @@ SLOT="3"
 KEYWORDS="~amd64 ~ppc ~x86"
 IUSE=""
 
-RDEPEND=">=app-i18n/libhangul-0.0.12
+RDEPEND="app-i18n/libhangul
 	x11-libs/gtk+:3
 	virtual/libintl"
 DEPEND="${RDEPEND}
@@ -21,41 +23,34 @@ DEPEND="${RDEPEND}
 
 src_prepare() {
 	default
-
-	# Drop DEPRECATED flags, bug #387825
-	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' Makefile.am Makefile.in || die
+	gnome2_environment_reset
+	gnome2_disable_deprecation_warning
 }
 
 src_configure() {
-	econf --with-gtk-im-module-dir="${EPREFIX}/usr/$(get_libdir)/gtk-3.0/$(pkg-config gtk+-3.0 --variable=gtk_binary_version)/immodules"
+	econf --with-gtk-im-module-dir="${EPREFIX%/}"/usr/$(get_libdir)/gtk-3.0/$(pkg-config gtk+-3.0 --variable=gtk_binary_version)/immodules
 }
 
 src_install() {
 	default
-	dodoc imhangul.conf
+	find "${ED}" -name '*.la' -delete || die
+	dodoc ${PN}.conf
 
+	local s
 	insinto /etc/X11/xinit/xinput.d
-	newins "${FILESDIR}/xinput-imhangul2" imhangul2.conf
-	newins "${FILESDIR}/xinput-imhangul2y" imhangul2y.conf
-	newins "${FILESDIR}/xinput-imhangul32" imhangul32.conf
-	newins "${FILESDIR}/xinput-imhangul39" imhangul39.conf
-	newins "${FILESDIR}/xinput-imhangul3f" imhangul3f.conf
-	newins "${FILESDIR}/xinput-imhangul3s" imhangul3s.conf
-	newins "${FILESDIR}/xinput-imhangul3y" imhangul3y.conf
-	newins "${FILESDIR}/xinput-imhangulahn" imhangulahn.conf
-	newins "${FILESDIR}/xinput-imhangulro" imhangulro.conf
-
-	find "${D}" -name '*.la' -delete || die
+	for s in 2{,y} 3{2,9,f,s,y} ahn ro; do
+		newins "${FILESDIR}"/xinput-${PN}${s} ${PN}${s}.conf
+	done
 }
 
 pkg_postinst() {
 	gnome2_query_immodules_gtk3
-	elog ""
+	elog
 	elog "If you want to use one of the module as a default input method, "
-	elog ""
+	elog
 	elog "export GTK_IM_MODULE=hangul2  # 2 input type"
 	elog "export GTK_IM_MODULE=hangul3f # 3 input type"
-	elog ""
+	elog
 }
 
 pkg_postrm() {