app-emulation/spice-vdagent: fix automagic dependency

Closes: https://bugs.gentoo.org/691028
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Matthias Maier <tamiko@gentoo.org>

1 files changed, 73 insertions, 0 deletions

diff --git a/app-emulation/spice-vdagent/spice-vdagent-0.19.0-r1.ebuild b/app-emulation/spice-vdagent/spice-vdagent-0.19.0-r1.ebuild
new file mode 100644
index 000000000000..de4e147bf833
--- /dev/null
+++ b/app-emulation/spice-vdagent/spice-vdagent-0.19.0-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools linux-info
+
+MY_P="${P/_*/}"
+PATCHSET="${P/*_p/}"
+
+DESCRIPTION="SPICE VD Linux Guest Agent"
+HOMEPAGE="https://www.spice-space.org/"
+SRC_URI="https://www.spice-space.org/download/releases/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="consolekit gtk selinux systemd"
+S="${WORKDIR}/${MY_P}"
+
+CDEPEND="
+	>=app-emulation/spice-protocol-0.14.0
+	media-libs/alsa-lib
+	>=x11-libs/libpciaccess-0.10
+	x11-libs/libdrm
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libX11
+	x11-libs/libXinerama
+	consolekit? ( sys-auth/consolekit sys-apps/dbus )
+	gtk? ( x11-libs/gtk+:3 )
+	systemd? ( sys-apps/systemd )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-vdagent )"
+
+CONFIG_CHECK="~INPUT_UINPUT ~VIRTIO_CONSOLE"
+ERROR_INPUT_UINPUT="User level input support (INPUT_UINPUT) is required"
+ERROR_VIRTIO_CONSOLE="VirtIO console/serial device support (VIRTIO_CONSOLE) is required"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local opt=()
+	if use consolekit; then
+		opt+=( --with-session-info=console-kit )
+	elif use systemd; then
+		opt+=( --with-session-info=systemd )
+	else
+		opt+=( --with-session-info=none )
+	fi
+
+	econf \
+		--with-init-script=systemd \
+		--localstatedir="${EPREFIX}"/var \
+		$(use_with gtk) \
+		"${opt[@]}"
+}
+
+src_install() {
+	default
+
+	cd "${ED}" && rmdir -p var/run/spice-vdagentd || die
+
+	keepdir /var/log/spice-vdagentd
+
+	newinitd "${FILESDIR}/${PN}.initd-4" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd-2" "${PN}"
+}