app-crypt/acme-sh: update RDEPEND

Update deps in RDEPEND, as some are not supported anymore and some where
put into 'optfeature' as the should't be installed unconditionally.

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 72 insertions, 22 deletions

diff --git a/app-crypt/acme-sh/acme-sh-2.8.8-r1.ebuild b/app-crypt/acme-sh/acme-sh-2.8.8-r1.ebuild
new file mode 100644
index 000000000000..5d51ca8d03b0
--- /dev/null
+++ b/app-crypt/acme-sh/acme-sh-2.8.8-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="${PN/-/.}"
+MY_P="${MY_PN}-${PV}"
+
+inherit optfeature
+
+DESCRIPTION="A pure Unix shell script implementing ACME client protocol"
+HOMEPAGE="https://github.com/acmesh-official/acme.sh"
+SRC_URI="https://github.com/acmesh-official/${MY_PN}/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-libs/openssl:0
+	net-misc/curl
+	net-misc/socat
+"
+
+src_install() {
+	newdoc deploy/README.md README-deploy.md
+	newdoc dnsapi/README.md README-dnsapi.md
+	rm {deploy,dnsapi}/README.md || die
+	einstalldocs
+
+	exeinto /usr/share/acme.sh
+	doexe acme.sh
+
+	insinto /usr/share/acme.sh
+	doins -r deploy dnsapi notify
+
+	keepdir /etc/acme-sh
+	doenvd "${FILESDIR}"/99acme-sh
+
+	insinto /etc/bash/bashrc.d
+	doins "${FILESDIR}"/acme.sh
+
+	dosym ../share/acme.sh/acme.sh usr/bin/acme.sh
+}
+
+pkg_postinst() {
+	einfo "If you wish to use the webserver mode,"
+	einfo "you need to install a supported web server."
+	optfeature "using apache2 webserver mode." www-servers/apache
+	optfeature "using nginx webserver mode." www-servers/nginx
+}
diff --git a/app-crypt/acme-sh/acme-sh-9999.ebuild b/app-crypt/acme-sh/acme-sh-9999.ebuild
index 3bd355e89826..1e6ca0155893 100644
--- a/app-crypt/acme-sh/acme-sh-9999.ebuild
+++ b/app-crypt/acme-sh/acme-sh-9999.ebuild
@@ -3,48 +3,46 @@
 
 EAPI=7
 
-EGIT_REPO_URI="https://github.com/Neilpang/${PN/-/.}.git"
-
-inherit git-r3
+inherit git-r3 optfeature
 
 DESCRIPTION="A pure Unix shell script implementing ACME client protocol"
 HOMEPAGE="https://github.com/acmesh-official/acme.sh"
-SRC_URI=""
+EGIT_REPO_URI="https://github.com/acmesh-official/${PN/-/.}.git"
 
 LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS=""
 
 RDEPEND="
+	dev-libs/openssl:0
 	net-misc/curl
-	|| ( dev-libs/libressl dev-libs/openssl:0 )
-	|| ( net-analyzer/netcat net-analyzer/openbsd-netcat )
-	|| ( net-misc/socat www-servers/apache:2 www-servers/nginx )
-	virtual/cron
+	net-misc/socat
 "
 
 src_install() {
-	einstalldocs
-	newdoc dnsapi/README.md README-dnsapi.md
 	newdoc deploy/README.md README-deploy.md
-
-	keepdir /etc/acme-sh
-	doenvd "${FILESDIR}"/99acme-sh
-
-	insinto /etc/bash/bashrc.d
-	doins "${FILESDIR}"/acme.sh
+	newdoc dnsapi/README.md README-dnsapi.md
+	rm {deploy,dnsapi}/README.md || die
+	einstalldocs
 
 	exeinto /usr/share/acme.sh
 	doexe acme.sh
 
-	insinto /usr/share/acme.sh/dnsapi
-	doins -r dnsapi/*.sh
+	insinto /usr/share/acme.sh
+	doins -r deploy dnsapi notify
 
-	insinto /usr/share/acme.sh/deploy
-	doins -r deploy/*.sh
+	keepdir /etc/acme-sh
+	doenvd "${FILESDIR}"/99acme-sh
 
-	insinto /usr/share/acme.sh/notify
-	doins -r notify/*.sh
+	insinto /etc/bash/bashrc.d
+	doins "${FILESDIR}"/acme.sh
 
 	dosym ../share/acme.sh/acme.sh usr/bin/acme.sh
 }
+
+pkg_postinst() {
+	einfo "If you wish to use the webserver mode,"
+	einfo "you need to install a supported web server."
+	optfeature "using apache2 webserver mode." www-servers/apache
+	optfeature "using nginx webserver mode." www-servers/nginx
+}