app-backup/dar: drop 2.7.8

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 0 insertions, 94 deletions

diff --git a/app-backup/dar/Manifest b/app-backup/dar/Manifest
index 53bf71aeb5cb..f6c536fc750a 100644
--- a/app-backup/dar/Manifest
+++ b/app-backup/dar/Manifest
@@ -1,2 +1 @@
-DIST dar-2.7.8.tar.gz 2414732 BLAKE2B a6756218b89bfe17869cdd630a712593d6a615f8bac7da71dfad7bb96c91ee8321b0f7ba4515faa91cbf4eee683b1373392084ba76004d971d0a5f492b4238b6 SHA512 af3942b164e8e4f54504a9c561e1a90b950d5afd8c10ab351fc9657626f4b6650a18ea1727c5684918d3067f3b4738285afb78150c850ce77ee8d4a6f5567f2e
 DIST dar-2.7.9.tar.gz 2418755 BLAKE2B c2874318c27d0ed2a045cf8a8547cba45966eae5f9d9682584d57fd034e94b2ce8390dc1a9330c9a96e8ed60fc27ee1f8a0ce2852e5084d0a3fbcc9ddefa8d85 SHA512 d9a4efae266d45eaae99d3f99268f3729992b9b5d01380ac01303705eb8dcf742c9b34b9cc2d1f053e07692438e014dcf417417578dc337f179bac149c98b3b5
diff --git a/app-backup/dar/dar-2.7.8.ebuild b/app-backup/dar/dar-2.7.8.ebuild
deleted file mode 100644
index 79a33866f32e..000000000000
--- a/app-backup/dar/dar-2.7.8.ebuild
+++ /dev/null
@@ -1,93 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit flag-o-matic
-
-DESCRIPTION="A full featured backup tool, aimed for disks"
-HOMEPAGE="http://dar.linux.free.fr/"
-SRC_URI="https://downloads.sourceforge.net/project/dar/dar/${PV}/${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 ppc sparc x86 ~amd64-linux"
-IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lz4 lzo nls rsync threads xattr"
-
-REQUIRED_USE="?? ( dar32 dar64 )
-		gpg? ( gcrypt )"
-
-RESTRICT="test" # need to be run as root
-
-RDEPEND="
-	app-arch/bzip2:=
-	app-arch/xz-utils
-	app-arch/zstd:=
-	sys-libs/libcap
-	>=sys-libs/zlib-1.2.3:=
-	argon2? ( app-crypt/argon2:= )
-	curl? ( net-misc/curl )
-	gcrypt? (
-		dev-libs/libgcrypt:0=
-		dev-libs/libgpg-error
-	)
-	gpg? ( app-crypt/gpgme:= )
-	lz4? ( app-arch/lz4:= )
-	lzo? ( dev-libs/lzo:2 )
-	nls? ( virtual/libintl )
-	rsync? ( net-libs/librsync:= )
-	threads? ( dev-libs/libthreadar )
-	xattr? ( sys-apps/attr )
-"
-
-DEPEND="${RDEPEND}"
-
-BDEPEND="
-	doc? ( app-doc/doxygen )
-	nls? ( sys-devel/gettext )
-"
-
-QA_PKGCONFIG_VERSION=""	#862025 - upstream has a different numbering scheme for libdar
-
-src_configure() {
-	# configure.ac is totally funked up regarding the AC_ARG_ENABLE
-	# logic.
-	# For example "--enable-dar-static" causes configure to DISABLE
-	# static builds of dar.
-	# Do _not_ use $(use_enable) until you have verified that the
-	# logic has been fixed by upstream.
-	local myconf=(
-		--disable-dar-static
-		--disable-python-binding
-		--disable-upx
-		$(usev !argon2 --disable-libargon2-linking)
-		$(usev !curl --disable-libcurl-linking)
-		$(usev dar32 --enable-mode=32)
-		$(usev dar64 --enable-mode=64)
-		$(usev !doc --disable-build-html)
-		$(usev !gcrypt --disable-libgcrypt-linking)
-		$(usev !gpg --disable-gpgme-linking)
-		$(usev !lz4 --disable-liblz4-linking)
-		$(usev !lzo --disable-liblzo2-linking)
-		$(usev !nls --disable-nls)
-		$(usev !rsync --disable-librsync-linking)
-		$(usev !threads --disable-threadar)
-		$(usev !xattr --disable-ea-support)
-	)
-
-	# Bug 103741
-	filter-flags -fomit-frame-pointer
-
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
-
-	einstalldocs
-
-	find "${ED}" -name "*.la" -delete || die
-
-	# Bug 729150
-	rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
-}